-
Notifications
You must be signed in to change notification settings - Fork 2
/
stabilityAnalysis.m
156 lines (129 loc) · 4.41 KB
/
stabilityAnalysis.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
BeginPackage["stabilityAnalysis`", {"QM`", "QuantumWalks`"}];
Unprotect @@ Names["stabilityAnalysis`*"];
ClearAll @@ Names["stabilityAnalysis`*"];
plotFidelityVsParameters;
Begin["`Private`"];
texStyle = Directive[
GrayLevel @ 0,
{FontFamily -> "CMU Serif", FontSize -> 20, FontWeight -> Plain, FontSlant -> Plain}
];
(* Simple utility converting {1, i} into \[Theta]_i, and so on. *)
parIndicesToLabel[{row_, col_}] := (
Subscript[col /. {1 -> "\[Theta]", 2 -> "\[Xi]", 3 -> "\[Zeta]"}, row]
);
(* Expect as input a set of coin parameters, and a position in that list,
and return the same set of parameters with the specified element(s) perturbed
according to the value of `typeOfPerturbation`.
The output will contain the symbolic parameter `eps`, controlling the
perturbation.*)
injectEpsInPars[coinPars_, pos_, typeOfPerturbation_ : Times] := ReplacePart[
coinPars,
pos :> typeOfPerturbation[eps, coinPars[[Sequence @@ pos]]]
];
(* Starting from a given set of coin parameters, use `injectEpsInPairs` to
apply a perturbation (parametrized by `eps`), to the coin parameter given
with `changingPar`, then evolve a walker using these parameters,
project at the end according to the value of `projection`, and finally
compute the fidelity with the target state `targetState`. *)
Options @ fidelityWithEps = {"InitialCoinState" -> {1, 0}};
fidelityWithEps[
coinParameters_, changingPar_, targetState_, op_, projection_, OptionsPattern[]
] := QFidelity[
QWEvolve[OptionValue @ "InitialCoinState",
injectEpsInPars[coinParameters, changingPar, op]
] // QWProjectCoin @ projection,
targetState
];
Options @ makeLabelForLine = {"HighlightZeros" -> False};
makeLabelForLine[coinParameters_, changingPar_, OptionsPattern[]] := Labeled[
#,
Tooltip[
Style[parIndicesToLabel @ changingPar,
Bold, texStyle,
If[
And[
TrueQ @ OptionValue @ "HighlightZeros",
coinParameters[[Sequence @@ changingPar]] == 0
],
Red, {}
]
],
coinParameters[[Sequence @@ changingPar]]
]
]&;
Options[plotFidelityVsParameters] = {
"TypeOfPerturbation" -> Times,
"ParametersToPlot" -> {1, 3},
"Projection" -> {1, 1}
};
Options[plotFidelityVsParameters] = Normal @ Association @ Join[
Options @ Plot,
Options @ plotFidelityVsParameters,
Options @ makeLabelForLine
];
plotFidelityVsParameters[coinParameters_List,
targetState_List, {epsMin_, epsMax_}, opts : OptionsPattern[]
] := With[{
expressions = #[[;;]]& @ Table[
fidelityWithEps[
coinParameters, changingPar, targetState,
OptionValue @ "TypeOfPerturbation", OptionValue @ "Projection"
] // makeLabelForLine[coinParameters, changingPar,
"HighlightZeros" -> OptionValue @ "HighlightZeros"
],
{
changingPar,
Tuples[
{Range @ Length @ coinParameters, OptionValue @ "ParametersToPlot"}
]
}
] ~ Monitor ~ parIndicesToLabel @ changingPar
},
Plot[expressions,
{eps, epsMin, epsMax},
PlotRange -> All,
Evaluate @ FilterRules[{opts}, Options @ Plot],
AxesStyle -> texStyle
]
];
(* `nMaximize*` functions work on the `Association` given in output by
`searchCoinParameters`.
These `nMaximizeResults` have the following structure:
```
<| "FinalFidelity" -> 1., "CoinParameters" -> {...}, "TargetState" -> {...} |>
```
*)
nMaximizeResultsGetProjection[nMaximizeResults_Association] := With[{
coinParameters = nMaximizeResults["CoinParameters"]
},
If[MemberQ[coinParameters[[All, 1]], Global`\[Alpha]],
{Global`\[Alpha], Sqrt[1 - Global`\[Alpha]^2]} /. coinParameters,
Normalize @ {1, 1}
]
];
nMaximizeResultsFormatCoinPars[nMaximizeResults_Association] := With[{
coins = nMaximizeResults["CoinParameters"]
},
PadRight[#, 3]& /@
Partition[#, 2]& @ DeleteCases[coins, \[Alpha] -> _][[All, 2]]
];
plotFidelityVsParameters[
nMaximizeResults_Association,
{epsMin_, epsMax_},
opts : OptionsPattern[]
] /; (
KeyExistsQ[nMaximizeResults, "CoinParameters"]
) := plotFidelityVsParameters[
nMaximizeResultsFormatCoinPars @ nMaximizeResults,
nMaximizeResults["TargetState"],
{epsMin, epsMax},
"Projection" -> nMaximizeResultsGetProjection @ nMaximizeResults,
opts
];
plotFidelityVsParameters[
{epsMin_, epsMax_}, opts : OptionsPattern[]
][result_Association] := plotFidelityVsParameters[
result, {epsMin, epsMax}, opts
];
End[];
Block[{$ContextPath}, EndPackage[]];