Get object

Author: lpil

src/bucket/get_object.gleam

@@ -0,0 +1,41 @@
+//// <https://docs.aws.amazon.com/AmazonS3/latest/API/API_GetObject.html>
+
+import bucket.{type BucketError, type Credentials}
+import bucket/internal
+import gleam/http
+import gleam/http/request.{type Request, Request}
+import gleam/http/response.{type Response}
+
+pub type RequestBuilder {
+  RequestBuilder(bucket: String, key: String)
+}
+
+pub type Outcome(body) {
+  Found(body)
+  NotFound
+}
+
+pub fn request(bucket bucket: String, key key: String) -> RequestBuilder {
+  RequestBuilder(bucket:, key:)
+}
+
+pub fn build(builder: RequestBuilder, creds: Credentials) -> Request(BitArray) {
+  let headers = []
+  internal.request(
+    creds,
+    http.Get,
+    "/" <> builder.bucket <> "/" <> builder.key,
+    [],
+    headers,
+    <<>>,
+  )
+}
+
+pub fn response(response: Response(body)) -> Result(Outcome(body), BucketError) {
+  case response.status {
+    200 -> Ok(Found(response.body))
+    404 -> Ok(NotFound)
+    _ ->
+      Error(bucket.UnexpectedResponseError(response.set_body(response, <<>>)))
+  }
+}

test/bucket_test.gleam

@@ -2,6 +2,7 @@ import bucket.{ErrorObject, S3Error}
 import bucket/create_bucket
 import bucket/delete_bucket
 import bucket/delete_objects
+import bucket/get_object
 import bucket/head_bucket
 import bucket/head_object
 import bucket/list_buckets.{ListAllMyBucketsResult}
@@ -336,3 +337,36 @@ pub fn head_object_if_match_not_matching_test() {
     |> httpc.send_bits
   let assert Ok(head_object.PreconditionFailed) = head_object.response(res)
 }
+
+pub fn get_object_bucket_not_found_test() {
+  helpers.delete_existing_buckets()
+
+  let assert Ok(res) =
+    get_object.request("bucket", "key")
+    |> get_object.build(helpers.creds)
+    |> httpc.send_bits
+  let assert Ok(get_object.NotFound) = get_object.response(res)
+}
+
+pub fn get_object_object_not_found_test() {
+  helpers.delete_existing_buckets()
+  helpers.create_bucket("bucket")
+
+  let assert Ok(res) =
+    get_object.request("bucket", "key")
+    |> get_object.build(helpers.creds)
+    |> httpc.send_bits
+  let assert Ok(get_object.NotFound) = get_object.response(res)
+}
+
+pub fn get_object_found_test() {
+  helpers.delete_existing_buckets()
+  helpers.create_bucket("bucket")
+  helpers.create_object("bucket", "key", <<"yes":utf8>>)
+
+  let assert Ok(res) =
+    get_object.request("bucket", "key")
+    |> get_object.build(helpers.creds)
+    |> httpc.send_bits
+  let assert Ok(get_object.Found(<<"yes":utf8>>)) = get_object.response(res)
+}