Export cmake config and add option to build unit tests

Author: Osyotr

Diff for: CMakeLists.txt

@@ -1,6 +1,7 @@
+cmake_minimum_required(VERSION 3.9)
 cmake_policy(SET CMP0048 NEW)
+
 project(fast_double_parser LANGUAGES CXX VERSION 0.0.0.0)
-cmake_minimum_required(VERSION 3.9)
 set(CMAKE_CXX_STANDARD 11)
 set(CMAKE_CXX_STANDARD_REQUIRED ON)
 if (NOT CMAKE_BUILD_TYPE)
@@ -18,31 +19,53 @@ set(rebogus_src tests/bogus.cpp)
 set(benchmark_src benchmarks/benchmark.cpp)
 
 
-add_library(fast_double_parser INTERFACE)
-target_include_directories(fast_double_parser INTERFACE include/)
-
+add_library(fast_double_parser INTERFACE ${headers})
+target_include_directories(fast_double_parser
+    INTERFACE
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>
+        $<INSTALL_INTERFACE:include>
+)
+
+include(GNUInstallDirs)
+install(FILES ${headers} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+install(TARGETS fast_double_parser EXPORT fast_double_parser-targets)
+install(
+    EXPORT fast_double_parser-targets
+    DESTINATION "share/fast_double_parser"
+    NAMESPACE fast_double_parser::
+)
+
+include(CMakePackageConfigHelpers)
+configure_package_config_file(
+  "${CMAKE_CURRENT_SOURCE_DIR}/fast_double_parser-config.cmake.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/fast_double_parser-config.cmake"
+  INSTALL_DESTINATION "share/fast_double_parser"
+)
+install(
+  FILES "${CMAKE_CURRENT_BINARY_DIR}/fast_double_parser-config.cmake"
+  DESTINATION "share/fast_double_parser"
+)
+
+option(BUILD_TESTING "Build unit tests" ON)
+if(BUILD_TESTING)
+    add_executable(unit ${unit_src} ${bogus_src} ${rebogus_src})
+
+    if(FAST_DOUBLE_PARSER_SANITIZE)
+      target_compile_options(unit PUBLIC -fsanitize=address -fno-omit-frame-pointer -fsanitize=undefined -fno-sanitize-recover=all)
+      target_link_options(unit PUBLIC -fsanitize=address -fno-omit-frame-pointer -fsanitize=undefined -fno-sanitize-recover=all)
+      # Ubuntu bug for GCC 5.0+ (safe for all versions)
+      if (CMAKE_COMPILER_IS_GNUCC AND NOT APPLE)
+        target_link_libraries(unit PUBLIC -fuse-ld=gold)
+      endif()
+    endif()
+    target_link_libraries(unit PRIVATE fast_double_parser)
 
-add_executable(unit ${unit_src} ${bogus_src} ${rebogus_src})
-if(FAST_DOUBLE_PARSER_SANITIZE)
-  target_compile_options(unit PUBLIC -fsanitize=address -fno-omit-frame-pointer -fsanitize=undefined -fno-sanitize-recover=all)
-  target_link_options(unit PUBLIC -fsanitize=address -fno-omit-frame-pointer -fsanitize=undefined -fno-sanitize-recover=all)
-  # Ubuntu bug for GCC 5.0+ (safe for all versions)
-  if (CMAKE_COMPILER_IS_GNUCC AND NOT APPLE)
-    target_link_libraries(unit PUBLIC -fuse-ld=gold)
-  endif()
+    enable_testing()
+    add_test(unit unit)
 endif()
 
-target_link_libraries(unit  PUBLIC fast_double_parser)
-
-
-
-enable_testing()
-add_test(unit unit)
-
 option(FAST_DOUBLE_BENCHMARKS "include benchmarks" OFF)
 
-
-
 function(initialize_submodule DIRECTORY)
   if(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${DIRECTORY}/.git)
     find_package(Git QUIET REQUIRED)
@@ -63,8 +86,6 @@ if(FAST_DOUBLE_BENCHMARKS)
   add_subdirectory(benchmarks/dependencies/abseil-cpp)
   add_subdirectory(benchmarks/dependencies/double-conversion)
 
-
-
   add_executable(benchmark ${benchmark_src})
   target_link_libraries(benchmark PUBLIC double-conversion absl_strings)
   target_include_directories(benchmark PUBLIC include)

Diff for: fast_double_parser-config.cmake.in

@@ -0,0 +1,3 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/fast_double_parser-targets.cmake")