-
Notifications
You must be signed in to change notification settings - Fork 36
/
Copy pathConvSpec-ControlSubfields.xsl
429 lines (417 loc) · 18.7 KB
/
ConvSpec-ControlSubfields.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
<?xml version='1.0'?>
<xsl:stylesheet version="1.0"
xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
xmlns:marc="http://www.loc.gov/MARC21/slim"
xmlns:bf="http://id.loc.gov/ontologies/bibframe/"
xmlns:bflc="http://id.loc.gov/ontologies/bflc/"
xmlns:madsrdf="http://www.loc.gov/mads/rdf/v1#"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="xsl marc">
<!-- Templates for processing MARC control subfields -->
<!--
generate agent or work URI from 1XX, 6XX, 7XX, or 8XX, taking $0 or $w into account
generated URI will come from the first URI in a $0 or $w
-->
<xsl:template match="marc:datafield" mode="generateUri">
<xsl:param name="pDefaultUri"/>
<xsl:param name="pEntity"/>
<xsl:variable name="vGeneratedUri">
<xsl:choose>
<xsl:when test="marc:subfield[@code='t']">
<xsl:variable name="vIdentifier">
<xsl:choose>
<xsl:when test="$pEntity='bf:Agent'">
<xsl:value-of select="marc:subfield[@code='t']/preceding-sibling::marc:subfield[@code='0' or @code='w'][starts-with(text(),'(uri)') or starts-with(text(),'http')][1]"/>
</xsl:when>
<xsl:when test="$pEntity='bf:Work' or $pEntity = 'bf:Hub'">
<xsl:value-of select="marc:subfield[@code='t']/following-sibling::marc:subfield[@code='0' or @code='w'][starts-with(text(),'(uri)') or starts-with(text(),'http')][1]"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="starts-with($vIdentifier,'(uri)')">
<xsl:value-of select="substring-after($vIdentifier,'(uri)')"/>
</xsl:when>
<xsl:when test="starts-with($vIdentifier,'http')">
<xsl:value-of select="$vIdentifier"/>
</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:when test="marc:subfield[@code='1'][starts-with(text(),'http')]">
<xsl:value-of select="marc:subfield[@code='1'][starts-with(text(),'http')][1]" />
</xsl:when>
<xsl:when test="marc:subfield[@code='0'][starts-with(text(),'(OCoLC)fst')]">
<!-- http://id.worldcat.org/fast/1919741 -->
<xsl:variable name="vIdentifier" select="marc:subfield[@code='0'][starts-with(text(),'(OCoLC)fst')]" />
<xsl:value-of select="concat('http://id.worldcat.org/fast/', substring-after($vIdentifier,'(OCoLC)fst'))" />
</xsl:when>
<xsl:otherwise>
<xsl:variable name="vIdentifier">
<xsl:value-of select="marc:subfield[@code='0' or @code='w'][starts-with(text(),'(uri)') or starts-with(text(),'http')][1]"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="starts-with($vIdentifier,'(uri)')">
<xsl:value-of select="substring-after($vIdentifier,'(uri)')"/>
</xsl:when>
<xsl:when test="starts-with($vIdentifier,'http')">
<xsl:value-of select="$vIdentifier"/>
</xsl:when>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$vGeneratedUri != ''"><xsl:value-of select="$vGeneratedUri"/></xsl:when>
<xsl:otherwise><xsl:value-of select="$pDefaultUri"/></xsl:otherwise>
</xsl:choose>
</xsl:template>
<!--
generate URI from Dollar 0
-->
<xsl:template match="marc:datafield" mode="generateUriFrom0">
<xsl:param name="pDefaultUri"/>
<xsl:variable name="vGeneratedUri">
<xsl:choose>
<xsl:when test="marc:subfield[@code='0'][contains(text(),'id.loc.gov/authorities/')]">
<xsl:variable name="vIdentifier">
<xsl:value-of select="marc:subfield[@code='0'][contains(text(),'id.loc.gov/authorities/')][1]"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="starts-with($vIdentifier,'(uri)')">
<xsl:value-of select="substring-after($vIdentifier,'(uri)')"/>
</xsl:when>
<xsl:when test="starts-with($vIdentifier,'http')">
<xsl:value-of select="$vIdentifier"/>
</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:when test="marc:subfield[@code='1'][contains(text(),'id.loc.gov/rwo/agents/')]">
<xsl:variable name="sf1" select="marc:subfield[@code='1']"/>
<xsl:value-of select="concat(substring-before($sf1,'rwo/agents'), 'authorities/names/', substring-after($sf1,'rwo/agents/'))"/>
</xsl:when>
<xsl:when test="marc:subfield[@code='0'][starts-with(text(),'(OCoLC)fst')]">
<!-- http://id.worldcat.org/fast/1919741 -->
<xsl:variable name="vIdentifier" select="marc:subfield[@code='0'][starts-with(text(),'(OCoLC)fst')]" />
<xsl:value-of select="concat('http://id.worldcat.org/fast/', substring-after($vIdentifier,'(OCoLC)fst'))" />
</xsl:when>
<xsl:when test="marc:subfield[@code='0' or @code='w'][starts-with(text(),'(uri)') or starts-with(text(),'http')][1]">
<xsl:variable name="vIdentifier">
<xsl:value-of select="marc:subfield[@code='0' or @code='w'][starts-with(text(),'(uri)') or starts-with(text(),'http')][1]"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="starts-with($vIdentifier,'(uri)')">
<xsl:value-of select="substring-after($vIdentifier,'(uri)')"/>
</xsl:when>
<xsl:when test="starts-with($vIdentifier,'http')">
<xsl:value-of select="$vIdentifier"/>
</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:when test="marc:subfield[@code='0'][starts-with(text(),'(DE-588)')]">
<xsl:variable name="vIdentifier">
<xsl:value-of select="marc:subfield[@code='0'][starts-with(text(),'(DE-588)')][1]"/>
</xsl:variable>
<xsl:value-of select="concat('https://d-nb.info/gnd/', substring-after($vIdentifier,'(DE-588)'))"/>
</xsl:when>
<xsl:when test="marc:subfield[@code='1'][contains(text(),'homosaurus.org/v')]">
<xsl:value-of select="marc:subfield[@code='1'][contains(text(),'homosaurus.org/v')]"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$vGeneratedUri != ''"><xsl:value-of select="$vGeneratedUri"/></xsl:when>
<xsl:otherwise><xsl:value-of select="$pDefaultUri"/></xsl:otherwise>
</xsl:choose>
</xsl:template>
<!--
generate URI from Dollar 1
-->
<xsl:template match="marc:datafield" mode="generateUriFrom1">
<xsl:param name="pDefaultUri"/>
<xsl:variable name="vGeneratedUri">
<xsl:choose>
<xsl:when test="marc:subfield[@code='1'][contains(text(),'id.loc.gov/rwo/agents/')]">
<xsl:variable name="sf" select="marc:subfield[@code='1'][contains(text(),'id.loc.gov/rwo/agents/')]"/>
<xsl:value-of select="$sf"/>
</xsl:when>
<xsl:when test="marc:subfield[@code='0'][contains(text(),'id.loc.gov/authorities/names/')]">
<xsl:variable name="sf0" select="marc:subfield[@code='0'][contains(text(),'id.loc.gov/authorities/names/')]"/>
<xsl:value-of select="concat(substring-before($sf0,'authorities/names'), 'rwo/agents/', substring-after($sf0,'authorities/names/'))"/>
</xsl:when>
<xsl:when test="marc:subfield[@code='1'][contains(text(),'isni.org/isni/')]">
<xsl:variable name="vIdentifier">
<xsl:value-of select="marc:subfield[@code='1'][contains(text(),'isni.org/isni/')][1]"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="substring($vIdentifier, string-length($vIdentifier)) = '.'">
<xsl:value-of select="substring($vIdentifier, 1, string-length($vIdentifier) - 1)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$vIdentifier"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:when test="marc:subfield[@code='1'][starts-with(text(),'http')]">
<xsl:value-of select="marc:subfield[@code='1'][starts-with(text(),'http')][1]" />
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$vGeneratedUri != ''"><xsl:value-of select="$vGeneratedUri"/></xsl:when>
<xsl:otherwise><xsl:value-of select="$pDefaultUri"/></xsl:otherwise>
</xsl:choose>
</xsl:template>
<!--
create a bf:identifiedBy property from a subfield $0 or $w
-->
<xsl:template match="marc:subfield" mode="subfield0orw">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:param name="pIdClass" select="'bf:Identifier'"/>
<xsl:variable name="source" select="substring(substring-after(text(),'('),1,string-length(substring-before(text(),')'))-1)"/>
<xsl:variable name="value">
<xsl:choose>
<xsl:when test="$source != ''"><xsl:value-of select="substring-after(text(),')')"/></xsl:when>
<xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<xsl:choose>
<xsl:when test="starts-with(text(),'http')">
<madsrdf:isIdentifiedByAuthority>
<xsl:attribute name="rdf:resource">
<xsl:value-of select="text()" />
</xsl:attribute>
</madsrdf:isIdentifiedByAuthority>
</xsl:when>
<xsl:when test="starts-with(text(),'(uri)')">
<madsrdf:isIdentifiedByAuthority>
<xsl:attribute name="rdf:resource">
<xsl:value-of select="substring-after(text(),'(uri)')" />
</xsl:attribute>
</madsrdf:isIdentifiedByAuthority>
</xsl:when>
<xsl:when test="starts-with(text(),'(OCoLC)fst')">
<!-- http://id.worldcat.org/fast/1919741 -->
<madsrdf:isIdentifiedByAuthority>
<xsl:attribute name="rdf:resource">
<xsl:value-of select="concat('http://id.worldcat.org/fast/', substring-after(text(),'(OCoLC)fst'))" />
</xsl:attribute>
</madsrdf:isIdentifiedByAuthority>
</xsl:when>
<xsl:otherwise>
<bf:identifiedBy>
<xsl:element name="{$pIdClass}">
<rdf:value>
<xsl:choose>
<xsl:when test="contains($value,'://')">
<xsl:attribute name="rdf:resource"><xsl:value-of select="$value"/></xsl:attribute>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$value"/>
</xsl:otherwise>
</xsl:choose>
</rdf:value>
<xsl:if test="$source != '' and $source != 'uri'">
<xsl:choose>
<xsl:when test="@code='w'">
<bf:assigner>
<bf:Agent>
<xsl:if test="$source='DLC'">
<xsl:attribute name="rdf:about"><xsl:value-of select="concat($organizations,'dlc')"/></xsl:attribute>
</xsl:if>
<bf:code><xsl:value-of select="$source"/></bf:code>
</bf:Agent>
</bf:assigner>
</xsl:when>
<xsl:otherwise>
<bf:source>
<bf:Source>
<xsl:if test="$source='DLC'">
<xsl:attribute name="rdf:about"><xsl:value-of select="concat($organizations,'dlc')"/></xsl:attribute>
</xsl:if>
<bf:code><xsl:value-of select="$source"/></bf:code>
</bf:Source>
</bf:source>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
</xsl:element>
</bf:identifiedBy>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
</xsl:choose>
</xsl:template>
<!-- create a bf:source property from a subfield $2 -->
<xsl:template match="marc:subfield" mode="subfield2">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:param name="pVocabStem"/>
<xsl:param name="pStripPunct" select="false()"/>
<xsl:variable name="vURI">
<xsl:if test="$pVocabStem != ''">
<xsl:variable name="vNormCode">
<xsl:call-template name="tNormalizeCode">
<xsl:with-param name="pCode" select="."/>
<xsl:with-param name="pStripPunct" select="$pStripPunct"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat($pVocabStem,$vNormCode)" />
</xsl:if>
</xsl:variable>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<xsl:choose>
<xsl:when test="contains($vURI, '/fast')">
<bf:source>
<xsl:attribute name="rdf:resource"><xsl:value-of select="$vURI"/></xsl:attribute>
</bf:source>
</xsl:when>
<xsl:otherwise>
<bf:source>
<bf:Source>
<xsl:if test="$vURI != ''">
<xsl:attribute name="rdf:about"><xsl:value-of select="$vURI"/></xsl:attribute>
</xsl:if>
<bf:code>
<xsl:value-of select="."/>
</bf:code>
</bf:Source>
</bf:source>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
</xsl:choose>
</xsl:template>
<!--
create a bflc:appliesTo property from a subfield $3
-->
<xsl:template match="marc:subfield|marc:sf" mode="subfield3">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:variable name="vXmlLang"><xsl:apply-templates select="parent::*" mode="xmllang"/></xsl:variable>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<bflc:appliesTo>
<bflc:AppliesTo>
<rdfs:label>
<xsl:if test="$vXmlLang != ''">
<xsl:attribute name="xml:lang"><xsl:value-of select="$vXmlLang"/></xsl:attribute>
</xsl:if>
<xsl:call-template name="tChopPunct">
<xsl:with-param name="pString" select="."/>
</xsl:call-template>
</rdfs:label>
</bflc:AppliesTo>
</bflc:appliesTo>
</xsl:when>
</xsl:choose>
</xsl:template>
<!--
create a bf:role property from a subfield $4
-->
<xsl:template match="marc:subfield" mode="subfield4">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<bf:role>
<bf:Role>
<xsl:choose>
<xsl:when test="contains(.,'://')">
<xsl:attribute name="rdf:about"><xsl:value-of select="."/></xsl:attribute>
</xsl:when>
<xsl:otherwise>
<rdfs:label><xsl:value-of select="."/></rdfs:label>
</xsl:otherwise>
</xsl:choose>
</bf:Role>
</bf:role>
</xsl:when>
</xsl:choose>
</xsl:template>
<!--
create a bflc:applicableInstitution property from a subfield $5
-->
<xsl:template match="marc:subfield" mode="subfield5">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:variable name="vNormCode">
<xsl:call-template name="tNormalizeCode">
<xsl:with-param name="pCode" select="."/>
<xsl:with-param name="pStripPunct" select="true()"/>
</xsl:call-template>
</xsl:variable>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<bflc:applicableInstitution>
<bf:Agent>
<xsl:attribute name="rdf:about"><xsl:value-of select="concat($organizations,$vNormCode)"/></xsl:attribute>
<bf:code><xsl:value-of select="."/></bf:code>
</bf:Agent>
</bflc:applicableInstitution>
</xsl:when>
</xsl:choose>
</xsl:template>
<!--
create rdf:type and bf:issuance properties from a subfield $7
-->
<xsl:template match="marc:subfield" mode="subfield7">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:variable name="type">
<xsl:choose>
<xsl:when test="substring(.,1,1) = 'a'">Text</xsl:when>
<xsl:when test="substring(.,1,1) = 'c'">NotatedMusic</xsl:when>
<xsl:when test="substring(.,1,1) = 'd'">NotatedMusic</xsl:when>
<xsl:when test="substring(.,1,1) = 'e'">Cartography</xsl:when>
<xsl:when test="substring(.,1,1) = 'f'">Cartography</xsl:when>
<xsl:when test="substring(.,1,1) = 'g'">MovingImage</xsl:when>
<xsl:when test="substring(.,1,1) = 'i'">Audio</xsl:when>
<xsl:when test="substring(.,1,1) = 'j'">Audio</xsl:when>
<xsl:when test="substring(.,1,1) = 'k'">StillImage</xsl:when>
<xsl:when test="substring(.,1,1) = 'o'">MixedMaterial</xsl:when>
<xsl:when test="substring(.,1,1) = 'p'">MixedMaterial</xsl:when>
<xsl:when test="substring(.,1,1) = 'r'">Object</xsl:when>
<xsl:when test="substring(.,1,1) = 't'">Text</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:variable name="issuance">
<xsl:choose>
<xsl:when test="substring(.,2,1) = 'a'">m</xsl:when>
<xsl:when test="substring(.,2,1) = 'b'">s</xsl:when>
<xsl:when test="substring(.,2,1) = 'd'">d</xsl:when>
<xsl:when test="substring(.,2,1) = 'i'">i</xsl:when>
<xsl:when test="substring(.,2,1) = 'm'">m</xsl:when>
<xsl:when test="substring(.,2,1) = 's'">s</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$serialization='rdfxml'">
<xsl:if test="$type != ''">
<rdf:type>
<xsl:attribute name="rdf:resource"><xsl:value-of select="$bf"/><xsl:value-of select="$type"/></xsl:attribute>
</rdf:type>
</xsl:if>
<xsl:if test="$issuance != ''">
<bf:issuance>
<bf:Issuance>
<bf:code><xsl:value-of select="$issuance"/></bf:code>
</bf:Issuance>
</bf:issuance>
</xsl:if>
</xsl:when>
</xsl:choose>
</xsl:template>
<!--
create an rdfs:label property with datatype xs:anyURI from a
subfield u
-->
<xsl:template match="marc:subfield" mode="subfieldu">
<xsl:param name="serialization" select="'rdfxml'"/>
<xsl:choose>
<xsl:when test="$serialization = 'rdfxml'">
<bf:electronicLocator>
<xsl:attribute name="rdf:resource"><xsl:value-of select="."/></xsl:attribute>
</bf:electronicLocator>
</xsl:when>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>