feat(tika): init

Author: drupol

doc/tika.md

@@ -0,0 +1,17 @@
+# Tika
+
+[Tika](https://tika.apache.org/) is a content analysis toolkit as a service that can detect and extract metadata and
+text from over a thousand different file types.
+
+## Getting Started
+
+```nix
+# In `perSystem.process-compose.<name>`
+{
+  services.tika."instance-name" = {
+    enable = true;
+    port = 9998;
+    host = "127.0.0.1";
+  };
+}
+```

nix/services/default.nix

@@ -21,5 +21,6 @@ in
     ./tempo.nix
     ./weaviate.nix
     ./searxng.nix
+    ./tika.nix
   ];
 }

nix/services/tika.nix

@@ -0,0 +1,55 @@
+{ pkgs, lib, name, config, ... }:
+let
+  inherit (lib) types literalExpression;
+in
+{
+  options = {
+    package = lib.mkPackageOption pkgs "tika" { };
+
+    host = lib.mkOption {
+      description = "Apache Tika bind address";
+      default = "127.0.0.1";
+      example = "0.0.0.0";
+      type = types.str;
+    };
+
+    port = lib.mkOption {
+      description = "Apache Tika port to listen on";
+      default = 9998;
+      type = types.port;
+    };
+
+    configFile = lib.mkOption {
+      type = types.nullOr types.path;
+      default = null;
+      description = ''
+        The Apache Tika configuration (XML) file to use.
+      '';
+      example = literalExpression "./tika/tika-config.xml";
+    };
+  };
+
+  config = {
+    outputs = {
+      settings = {
+        processes = {
+          "${name}" = {
+            command = "${lib.getExe config.package} --host ${config.host} --port ${toString config.port} ${lib.optionalString (config.configFile != null) "--config ${config.configFile}"}";
+            availability.restart = "on_failure";
+            readiness_probe = {
+              http_get = {
+                host = config.host;
+                port = config.port;
+              };
+              initial_delay_seconds = 2;
+              period_seconds = 10;
+              timeout_seconds = 4;
+              success_threshold = 1;
+              failure_threshold = 5;
+            };
+          };
+        };
+      };
+    };
+  };
+}

nix/services/tika_test.nix

@@ -0,0 +1,17 @@
+{ pkgs, ... }:
+{
+  services.tika."tika1" = {
+    enable = true;
+  };
+
+  settings.processes.test = {
+    command = pkgs.writeShellApplication {
+      runtimeInputs = [ pkgs.curl ];
+      text = ''
+        curl http://127.0.0.1:9998
+      '';
+      name = "tika-test";
+    };
+    depends_on."tika1".condition = "process_healthy";
+  };
+}

test/flake.nix

@@ -49,6 +49,7 @@
             "${inputs.services-flake}/nix/services/pgadmin_test.nix"
             "${inputs.services-flake}/nix/services/tempo_test.nix"
             "${inputs.services-flake}/nix/services/weaviate_test.nix"
+            "${inputs.services-flake}/nix/services/tika_test.nix"
           ]));
       };
     };