p3_autoloot.inc

SUB p3_autoloot_init() {
	
	/declare looter bool outer FALSE
	/declare canLootDuringCombat bool outer FALSE
	/declare lootEntries[256,2] string outer -
	/declare lootCheckTimer timer outer 0
	/declare lootCheckTimerTime string outer 5s
	/declare skipCorpseIDs list outer
	/declare skipCorpseTrigger bool outer FALSE

	/varset looter ${getBotIniOption[Misc.Looter,${looter}]}
	/varset canLootDuringCombat ${getBotIniOption[Misc.CanLootDuringCombat,${canLootDuringCombat}]}

	/if (${looter}==TRUE) {
		/hidec looted
		/call loadLootIni
	}

	/RETURN
}


SUB autolootMaintenance() {
	/if (${looter}==FALSE) /RETURN
	/if (${lootCheckTimer}>0) /RETURN
	/if (${canLootDuringCombat}==FALSE && ${combatStateTimer}>0) /RETURN
	/if (${Stick.Active}==TRUE || ${Nav.Active}==TRUE) /return


	/if (${Me.FreeInventory}==0 && ${Cursor.ID} != NULL) {
		/beep
		/g Destroying ${Cursor}
		/keypress delete
		/delay 3
	}

	/call checkLoot

	/if (${Macro.Return}==FALSE) /RETURN FALSE

	/RETURN
}


SUB checkLoot() {
	/declare i int local 0
	/declare j int local 0
	/declare k int local 0
	/declare lootString string local
	/declare lootTries int local 0
	/declare needsLoot bool local FALSE
	/declare xCorpseID int local 0

	:BEGIN LOOT CYCLE
	/declare corpseIDs[128] int local
	/declare corpseCount int local ${SpawnCount[npccorpse LOS radius 100]}

	/if (${corpseCount}==0) /return

	/for k 1 to ${SpawnCount[npccorpse LOS radius 100]}
		/varset corpseIDs[${k}] ${NearestSpawn[${k},npccorpse LOS radius 100].ID}
	/next k

	| CHECK SKIP CORPSES FOR IDs THAT DONT EXIST
	/if (${skipCorpseIDs.Count}>0) {
		/for k ${Math.Calc[ ${skipCorpseIDs.Count}-1]} downto 0
			/if (${Spawn[id ${skipCorpseIDs.Item[${k}]}].ID}==NULL) {
				/bc Removing corpseID ${skipCorpseIDs.Item[${k}]} from skip-corpse list becaust it seems to have disappeared from the zone.
				/invoke ${skipCorpseIDs.Erase[${i}]}
			}
		/next k
	}

	/if (${corpseCount}==0) /RETURN

	/for k 1 to ${corpseCount}
		/doevents
		/if (${hardLoopReset}==TRUE) /RETURN FALSE

		/call ensureNoLootWindow
		/call ensureNoItemDisplayWindows

		/varset xCorpseID ${corpseIDs[${k}]}

		/if (${skipCorpseIDs.Contains[${xCorpseID}]}==TRUE) /continue

		/if (${Nav.PathExists[id ${xCorpseID}]}==FALSE) {
			/bc p3-loot: [+y+] Can't nav to corpse to loot. Abandoning. ID: ${xCorpseID}
			/invoke ${skipCorpseIDs.Append[${xCorpseID}]}
			/continue
		}

		:tryLoot
		/echo Trying to loot ${xCorpseID}...
		/nav id ${xCorpseID}

		| this needs to be distance3d
		/call waitForIntLTE "Spawn[id ${xCorpseID}].Distance" 13

		/call waitForIntLTE "Me.Speed" 1
		/tar id ${corpseIDs[${k}]}

		/if (${hardLoopReset}==TRUE) /RETURN FALSE

		/if (${Spawn[id ${xCorpseID}].ID}==NULL) /goto :loopnextk
		/tar id ${xCorpseID}
		/delay 2

		/doevents
		/if (${hardLoopReset}==TRUE) /RETURN FALSE

		/if (${stopWait}) {
			/goto :loopnextk
			/varset stopWait FALSE
		}

		/hidec looted
		/loot
		/delay 5
		/doevents

		/if (${skipCorpseTrigger}==TRUE) {
			/varset skipCorpseTrigger FALSE
			/invoke ${skipCorpseIDs.Append[${xCorpseID}]}
			/bc p3-loot: [+y+] Abandoning corpse ID ${xCorpseID} - I can't loot it for some reason.
			/continue
		}

		/if (${Spawn[id ${xCorpseID}].ID}==NULL) /goto :loopnextk
		/if (${Target.ID}==NULL) /tar id ${xCorpseID}
		/if (${Window[LootWnd]}==FALSE) /goto :tryLoot

		/varset lootString Loot on ${xCorpseID}:

		/for i 0 to 10
			/if (${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip.Length} == 0) /continue

			/varset lootString ${lootString}, ${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip}

			/for j 1 to 256
				/varset needsLoot FALSE

				/if (${lootEntries[${j},1].Equal[-]}) /continue

				/if (${lootEntries[${j},2].Equal[1]}) {
					/if (${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip.Find[${lootEntries[${j},1]}]}!=NULL) /varset needsLoot TRUE
				}

				/if (${lootEntries[${j},2].Equal[2]}) {
					/if (${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip.Equal[${lootEntries[${j},1]}]}!=NULL) /varset needsLoot TRUE
				}

				/if (${needsLoot}==FALSE) /continue

				/shift /notify LootWnd LW_LootSlot${i} rightmouseup
				/bc p3-loot: [+m+] Looting: ${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip}

				/delay 5
				/doevents

				/if (${skipCorpseTrigger}==TRUE) {
					/varset skipCorpseTrigger FALSE
					/invoke ${skipCorpseIDs.Append[${xCorpseID}]}
					/bc p3-loot: [+y+] Abandoning corpse ID ${xCorpseID} - there's a lore item on it I can't loot.
					/goto :loopnextk
				}

				/break
			/next j


		/next i

		/bc p3-loot: [+g+] ${lootString}
		/mqlog p3-loot: ${lootString}

		/varset lootString

		:loopnextk
	/next k
	:loopesck

	/call ensureNoLootWindow
	/call ensureNoItemDisplayWindows

	/RETURN
}


SUB loadLootIni() {
	/declare i int local 0
	/declare lootKeys string local ${Ini[loot,loot]}
	/declare entryName string local
	/declare entryValue string local
	/declare count int local 0

	/deletevar lootEntries
	/declare lootEntries[256,2] string outer -


	|/invoke ${lootEntries.Clear}

	| IMPORT LOOT ENTRIES INTO PERSISTENT ARRAY
	/for i 1 to 256
		/varset entryName ${lootKeys.Arg[${i},|]}
		/if (${entryName.Equal[NULL]}) {
			|/echo skip
			/goto :loopnext
		}
		/varset entryValue ${Ini[loot,loot,${entryName}]}
		/varset lootEntries[${i},1] ${entryName}
		/varset lootEntries[${i},2] ${entryValue}
		|/echo ${entryName} ${entryValue}
		/varset count ${Math.Calc[${count}+1]}
		:loopnext
	/next i

	/echo Loaded ${count} loot entries.

	/RETURN
}



SUB ensureNoItemDisplayWindows
	:again
	/if (${Window[ItemDisplayWindow]}==TRUE) {
		/keypress ESC
		/delay 2
		/goto :again
	}
/RETURN

SUB ensureNoLootWindow
	:again
	/if (${Window[LootWnd]}==TRUE) {
		/keypress ESC
		/delay 1
		/goto :again
	}
/RETURN