Mypy support

[fergusq]

To kill time, I experimented modifying Mypy to allow type-checking of Hy.

I came up with the following code that monkey-patches mypy. It can be used for type-checking singular Hy f, but it cannot find imports since patching Mypy's module finding algorithm is significantly more complicated. Particularly, Mypy expects that all Python files have the .py extension and all other files are compiled files.

(import sys)

(import hy.reader [read-many :as hy-read-many])
(import hy.compiler [hy-compile])

(import mypy.api
        mypy.fastparse)

(defn my-parse [source filename mode [feature-version (. sys version-info [1])]]
  (if (filename.endswith ".hy")
    (hy-compile (hy-read-many source) "<input>" :filename filename)
    (mypy.fastparse.ast3.parse source filename mode :type-comments True :feature-version feature-version)))

; Monkey-patch Mypy to support hy
(setv mypy.fastparse.ast3-parse my-parse)

(defn main []
  (let [result (mypy.api.run (cut sys.argv 1 None))]
    (when (get result 0)
      (print (get result 0)))
    (when (get result 1)
      (print (get result 1) :file sys.stderr))))

(when (= __name__ "__main__")
  (main))

To make monkey-patching possible, Mypy must be installed as interpreted version instead of compiler:

python3 -m pip install --no-binary mypy -U mypy

In principle there is nothing preventing forking Mypy and changing the file extension related code. That should be a fine project for someone interested. I'm not interested in maintaining such a fork. Even better would be to lobby the Mypy team to change their api so that adding support for new languages is easier, but I'm not sure if they are interested.

[Kodiologist]

Even better would be to lobby the Mypy team to change their api so that adding support for new languages is easier

Yeah, if type-checking Hy with Mypy is something you're interested in, I'd suggest filing an issue with them to not require the extension .py. We had to get a simliar change made to pytest at one point.