-
Notifications
You must be signed in to change notification settings - Fork 2
/
aors_n.asm
125 lines (107 loc) · 2.84 KB
/
aors_n.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
dnl ARM64 mpn_add_n and mpn_sub_n
dnl Contributed to the GNU project by Torbjörn Granlund.
dnl Copyright 2013, 2017 Free Software Foundation, Inc.
dnl This file is part of the GNU MP Library.
dnl
dnl The GNU MP Library is free software; you can redistribute it and/or modify
dnl it under the terms of either:
dnl
dnl * the GNU Lesser General Public License as published by the Free
dnl Software Foundation; either version 3 of the License, or (at your
dnl option) any later version.
dnl
dnl or
dnl
dnl * the GNU General Public License as published by the Free Software
dnl Foundation; either version 2 of the License, or (at your option) any
dnl later version.
dnl
dnl or both in parallel, as here.
dnl
dnl The GNU MP Library is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
dnl for more details.
dnl
dnl You should have received copies of the GNU General Public License and the
dnl GNU Lesser General Public License along with the GNU MP Library. If not,
dnl see https://www.gnu.org/licenses/.
include(`../config.m4')
C cycles/limb
C Cortex-A53 2.75-3.25
C Cortex-A57 1.5
C X-Gene 2.0
changecom(blah)
define(`rp', `x0')
define(`up', `x1')
define(`vp', `x2')
define(`n', `x3')
ifdef(`OPERATION_add_n', `
define(`ADDSUBC', adcs)
define(`CLRCY', `cmn xzr, xzr')
define(`SETCY', `cmp $1, #1')
define(`RETVAL', `cset x0, cs')
define(`func_n', mpn_add_n)
define(`func_nc', mpn_add_nc)')
ifdef(`OPERATION_sub_n', `
define(`ADDSUBC', sbcs)
define(`CLRCY', `cmp xzr, xzr')
define(`SETCY', `cmp xzr, $1')
define(`RETVAL', `cset x0, cc')
define(`func_n', mpn_sub_n)
define(`func_nc', mpn_sub_nc)')
MULFUNC_PROLOGUE(mpn_add_n mpn_add_nc mpn_sub_n mpn_sub_nc)
ASM_START()
PROLOGUE(func_nc)
SETCY( x4)
b L(ent)
EPILOGUE()
PROLOGUE(func_n)
CLRCY
L(ent): lsr x17, n, #2
tbz n, #0, L(bx0)
L(bx1): ldr x7, [up]
ldr x11, [vp]
ADDSUBC x13, x7, x11
str x13, [rp],#8
tbnz n, #1, L(b11)
L(b01): cbz x17, L(ret)
ldp x4, x5, [up,#8]
ldp x8, x9, [vp,#8]
sub up, up, #8
sub vp, vp, #8
b L(mid)
L(b11): ldp x6, x7, [up,#8]
ldp x10, x11, [vp,#8]
add up, up, #8
add vp, vp, #8
cbz x17, L(end)
b L(top)
L(bx0): tbnz n, #1, L(b10)
L(b00): ldp x4, x5, [up]
ldp x8, x9, [vp]
sub up, up, #16
sub vp, vp, #16
b L(mid)
L(b10): ldp x6, x7, [up]
ldp x10, x11, [vp]
cbz x17, L(end)
ALIGN(16)
L(top): ldp x4, x5, [up,#16]
ldp x8, x9, [vp,#16]
ADDSUBC x12, x6, x10
ADDSUBC x13, x7, x11
stp x12, x13, [rp],#16
L(mid): ldp x6, x7, [up,#32]!
ldp x10, x11, [vp,#32]!
ADDSUBC x12, x4, x8
ADDSUBC x13, x5, x9
stp x12, x13, [rp],#16
sub x17, x17, #1
cbnz x17, L(top)
L(end): ADDSUBC x12, x6, x10
ADDSUBC x13, x7, x11
stp x12, x13, [rp]
L(ret): RETVAL
ret
EPILOGUE()