build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    apply from: 'dependencies.gradle'

    repositories {
        google()
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        mavenCentral()
    }
    dependencies {
        classpath libs.gradle.gradlePlugin
        classpath libs.gradle.kotlinPlugin
        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.18.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        // For olm library. This has to be declared first, to ensure that Olm library is not downloaded from another repo
        maven {
            url 'https://jitpack.io'
            content {
                // Use this repo only for olm library
                includeGroupByRegex "org\\.matrix\\.gitlab\\.matrix-org"
                // And monarchy
                includeGroupByRegex "com\\.github\\.Zhuinden"
            }
        }
        google()
        jcenter()
    }

    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
        // Warnings are potential errors, so stop ignoring them
        // Ignore on the SDK for the moment
        kotlinOptions.allWarningsAsErrors = false
    }

    plugins.withId("com.vanniktech.maven.publish") {
        // Publish on s01.oss.sonatype.org
        //https://github.com/vanniktech/gradle-maven-publish-plugin#where-to-upload-to
        mavenPublish {
            sonatypeHost = "S01"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}