build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.


buildscript {
    ext.kotlinVersion = '1.5.31'
    ext.dokkaVersion = '1.5.31'

    repositories {
        google()
        // For com.hiya:jacoco-android
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        mavenCentral()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:$androidGradlePluginVersion"
        classpath('com.hiya:jacoco-android:0.2')
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokkaVersion"
        classpath "org.jetbrains.dokka:kotlin-as-java-plugin:$dokkaVersion"
        classpath 'com.google.gms:google-services:4.3.10'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        maven {
            // For Commons Imaging
            url 'https://repo.gini.net/nexus/content/repositories/open'
        }
        maven {
            url 'https://repo.gini.net/nexus/content/repositories/snapshots'
        }
        mavenCentral()
        // For bolts-android 1.5.0 used by gini-android-sdk
        //noinspection JcenterRepositoryObsolete
        jcenter()
        // For bolts-tasks and bolts-applinks 1.4.1-SNAPSHOT (which they should have released as version 1.5.0)
        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

apply from: rootProject.file('gradle/git_utils.gradle')

def libVersionCode = gitTagCount()
def libVersionName = "${gitDescribe()} (${libVersionCode})"

task printLibraryVersion {
    doLast {
        println "${libVersionName}"
    }
}

ext {
    compileSdkVersion = 31
    minSdkVersion = 19
    targetSdkVersion = 31
    versionCode = libVersionCode
    versionName = libVersionName
}

ext.deps = [
        // Android
        androidxCore               : '1.7.0',
        androidxAppCompat          : '1.3.1',
        androidxFragment           : '1.3.6',
        androidxViewPager          : '1.0.0',
        androidxLegacySupportV13   : '1.0.0',
        materialDesign             : '1.4.0',
        androidxCoordinatorLayout  : '1.1.0',
        androidxConstraintLayout   : '2.1.1',
        androidxRecyclerView       : '1.2.1',
        androidxCardView           : '1.0.0',
        androidxAnnotations        : '1.3.0',

        // Google ML Kit for QR code scanning
        mlKitBarcodeScanning       : '18.0.0',
        // Exif editing library. IMPORTANT: notify backend when the version is changed
        commonsImaging             : '1.0-alpha2',
        // Logging
        slf4j                      : '1.7.30',
        // Backport/standalone version of CompletableFuture
        completableFuture          : '2.23.1',
        // Test dependencies
        junit                      : 'junit:junit:4.13',
        truth                      : 'com.google.truth:truth:0.28',
        mockito                    : 'org.mockito:mockito-core:2.24.5',
        mockitoAndroid             : 'org.mockito:mockito-android:2.24.5',
        mockitoKotlin              : 'com.nhaarman.mockitokotlin2:mockito-kotlin:2.2.0',
        androidxTestCore           : 'androidx.test:core:1.4.0',
        androidxTestJUnit          : 'androidx.test.ext:junit:1.1.3',
        androidxTestRunner         : 'androidx.test:runner:1.4.0',
        androidxTestRules          : 'androidx.test:rules:1.4.0',
        androidxTestOrchestrator   : 'androidx.test:orchestrator:1.4.0',
        androidxTestEspressoCore   : 'androidx.test.espresso:espresso-core:3.4.0',
        androidxTestEspressoIntents: 'androidx.test.espresso:espresso-intents:3.4.0',
        androidxTestUiAutomator    : 'androidx.test.uiautomator:uiautomator:2.2.0',
        androidxMultidex           : 'androidx.multidex:multidex:2.0.1',
        robolectric                : 'org.robolectric:robolectric:4.5-alpha-3',
        androidxFragmentTesting    : '1.3.6'

]