macOS: fn+alt+del doesn't delete next word although alt+del deletes previous word

[JakobEdding]

Congrats on the v1 launch and thanks for the great alternative to existing terminal emulators!

With command line input foo baz bar and the cursor positioned after z, alt+del will remove baz so that the input is now foo bar. This is what I would expect.

However, with same input and cursor position, fn+alt+del will not remove bar but instead insert ~ so that the input is now foo baz~ bar. Is it possible to configure the behavior of fn+alt+del somehow so that bar will be removed and the resulting input is foo baz? This is a behavior I'm used to from iTerm 2 and would love to see in ghostty as well. [Edit: Doesn't seem to have anything to do with iTerm 2 but rather with macOS system-wide emacs shortcuts.]

[ciiqr]

you probably just need to configure your shell with the correct keybindings. ie. in zsh/ghostty fn+alt+del translates to:

bindkey '\e[3;3~' kill-word

Each terminal/shell is a bit different though, easiest way to figure out the codes for your setup is to use showkey (ie. brew install showkey), just run it, and then press the keybinding you want:

$ showkey
Type any key to see the sequence it sends.
Terminate with your shell interrupt <CTL-C=ETX> or quit <FS> character.
<ESC>[3;3~

Ultimately I ended up with something like this in my ~/.zshrc (for all they keybindings I expected, as you noted, alt+backspace works by default):

if [[ "$OSTYPE" == darwin* ]]; then
    if [[ "$TERM_PROGRAM" == 'ghostty' ]]; then
        bindkey '\e[1;3A' beginning-of-line # alt + up
        bindkey '\e[1;3B' end-of-line # alt + down
        bindkey '\e[3;3~' kill-word # alt + delete
    elif [[ "$TERM_PROGRAM" == 'Apple_Terminal' ]]; then
        bindkey '\e^[OA' beginning-of-line # alt + up
        bindkey '\e^[OB' end-of-line # alt + down
        bindkey '\e(' kill-word # alt + delete
    fi
fi

[edrozenberg]

I see the same here, with cat by itself: ^[[3;3~ and with showkey: <ESC>[3;3~. The ^[ is equivalent to <ESC> and for reference equivalent to what Terminal.app uses which displays as \033 in Terminal.app Keyboard settings. BTW in my setup I only need to press Opt (Alt) + Del which generates this same key code, both in Terminal.app and in Ghostty - not sure the Fn is doing anything in your case either. My Ghostty config contains macos-option-as-alt = true
( EDIT - believe you mean Opt (Alt) + Fn + Backspace, since Fn + Backspace does Del on std Mac kbd's).

My bindings atm, references to Del/Delete would be Fn + Backspace on a std Mac kbd. Also Cmd + Left/Right work in Ghostty for beg/end of line, do not work in Terminal.app which uses them for prev/next term window.

# bindings section from my .zshrc

#~~~~~~~~~~~~~#
# Keybindings #
#~~~~~~~~~~~~~#

bindkey "^A"       beginning-of-line     # CTRL+A
bindkey "^[[H"     beginning-of-line     # HOME
bindkey "^[[1;7D"  beginning-of-line     # CTRL+ALT+left (Ghostty)
bindkey "^[^[[D"   beginning-of-line     # CTRL+ALT+left (Terminal)

bindkey "^E"       end-of-line           # CTRL+E
bindkey "^[[F"     end-of-line           # END
bindkey "^[[1;7C"  end-of-line           # CTRL+ALT+right (Ghostty)
bindkey "^[^[[C"   end-of-line           # CTRL+ALT+right (Terminal)

bindkey "^B"       backward-word         # CTRL+B
bindkey "^[[1;5D"  backward-word         # CTRL+left   
bindkey "^[b"      backward-word         # ALT+left
bindkey "^[[5~"    backward-word         # PGUP

bindkey "^F"       forward-word          # CTRL+F
bindkey "^[[1;5C"  forward-word          # CTRL+right   
bindkey "^[f"      forward-word          # ALT+right
bindkey "^[[6~"    forward-word          # PGDN

bindkey "^H"       backward-kill-word    # CTRL+backspace
bindkey "^[^?"     backward-kill-word    # ALT+backspace

bindkey "^[[3;5~"  kill-word             # CTRL+delete
bindkey "^[[3;3~"  kill-word             # ALT+delete

bindkey "^U"       backward-kill-line    # CTRL+U
bindkey "^[^H"     backward-kill-line    # CTRL+ALT+backspace

bindkey "^K"       kill-line             # CTRL+K
bindkey "^[[3;7~"  kill-line             # CTRL+ALT+delete
bindkey "^[[3;9~"  kill-line             # CMD+delete (Ghostty)

bindkey "^[[3;2~"  kill-whole-line       # SHIFT+delete

[edrozenberg]

elif [[ "$TERM_PROGRAM" == 'Apple_Terminal' ]]; then

Interesting, that's def a good way to do it, I didn't think of that so I just define multiple bindings without a clause, or alternately, I redefined several Terminal.app bindings in Keyboard settings to emit the "standard" codes (which Ghostty uses) instead of Terminal.app's defaults.