fl.events

# ComponentEvent - AS3 Flash

Package | fl.events
Class | public class ComponentEvent
Inheritance | ComponentEvent Event Object

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

The ComponentEvent class defines events that are associated with the UIComponent class. These include the following events:

- `ComponentEvent.BUTTON_DOWN`: dispatched after a button is pressed.
- `ComponentEvent.ENTER`: dispatched after the Enter key is pressed.
- `ComponentEvent.HIDE`: dispatched after the visible property of a component is set to `false`.
- `ComponentEvent.LABEL_CHANGE`: dispatched after the Enter key is pressed.
- `ComponentEvent.MOVE`: dispatched after there is a change in the x or y properties that identify the component location.
- `ComponentEvent.RESIZE`: dispatched after a component is resized.
- `ComponentEvent.SHOW`: dispatched after the `visible` property of a component is set to `true`.

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bubbles : Boolean [read-only] Indicates whether an event is a bubbling event. | Event
|  | cancelable : Boolean [read-only] Indicates whether the behavior associated with the event can be prevented. | Event
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | currentTarget : Object [read-only] The object that is actively processing the Event object with an event listener. | Event
|  | eventPhase : uint [read-only] The current phase in the event flow. | Event
|  | target : Object [read-only] The event target. | Event
|  | type : String [read-only] The type of event. | Event

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Creates a new ComponentEvent object that contains information about a component event. | ComponentEvent
|  | clone():Event [override] Creates a copy of the ComponentEvent object and sets the value of each parameter to match the original. | ComponentEvent
|  | formatToString(className:String, ... arguments):String A utility function for implementing the toString() method in custom ActionScript 3.0 Event classes. | Event
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isDefaultPrevented():Boolean Checks whether the preventDefault() method has been called on the event. | Event
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | preventDefault():void Cancels an event's default behavior if that behavior can be canceled. | Event
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | stopImmediatePropagation():void Prevents processing of any event listeners in the current node and any subsequent nodes in the event flow. | Event
|  | stopPropagation():void Prevents processing of any event listeners in nodes subsequent to the current node in the event flow. | Event
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String [override] Returns a string that contains all the properties of the ComponentEvent object. | ComponentEvent
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Public Constants
Hide Inherited Public Constants
Show Inherited Public Constants

| Constant | Defined By
--- | --- | ---
|  | BUTTON_DOWN : String = "buttonDown" [static] Defines the value of the type property of a buttonDown event object. | ComponentEvent
|  | ENTER : String = "enter" [static] Defines the value of the type property of an enter event object. | ComponentEvent
|  | HIDE : String = "hide" [static] Defines the value of the type property of a hide event object. | ComponentEvent
|  | LABEL_CHANGE : String = "labelChange" [static] Defines the value of the type property of a labelChange event object. | ComponentEvent
|  | MOVE : String = "move" [static] Defines the value of the type property of a move event object. | ComponentEvent
|  | RESIZE : String = "resize" [static] Defines the value of the type property of a resize event object. | ComponentEvent
|  | SHOW : String = "show" [static] Defines the value of the type property of a show event object. | ComponentEvent

Constructor Detail

### ComponentEvent

()
Constructor

`public function ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false)`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Creates a new ComponentEvent object that contains information about a component event. A ComponentEvent object is passed as a parameter to an event listener.

Parameters

| `type:String` — The type of the event. Event listeners can access this information through the `type` property of the event object. A component can have the following types of events: `ComponentEvent.BUTTON_DOWN`, `ComponentEvent.ENTER`, `ComponentEvent.HIDE`, `ComponentEvent.LABEL_CHANGE`, `ComponentEvent.MOVE`, `ComponentEvent.RESIZE`, `ComponentEvent.SHOW`.
| `bubbles:Boolean` (default = `false`)`` — Determines whether the ComponentEvent object participates in the bubbling phase of the event flow. Event listeners can access this information through the `bubbles` property of the event object.
| `cancelable:Boolean` (default = `false`)`` — Determines whether the ComponentEvent object can be canceled. Event listeners can access this information through the `cancelable` property of the event object.

Method Detail

### clone

()
method

`override public function clone():Event`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Creates a copy of the ComponentEvent object and sets the value of each parameter to match the original.

Returns

| `Event` — A new ComponentEvent object with property values that match those of the original.

### toString

()
method

`override public function toString():String`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Returns a string that contains all the properties of the ComponentEvent object. The string is in the following format:

`[ComponentEvent type=value bubbles=value cancelable=value]`

Returns

| `String` — A string representation of the ComponentEvent object.

Constant Detail

### BUTTON_DOWN

Constant

`public static const BUTTON_DOWN:String = "buttonDown"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `buttonDown` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

### ENTER

Constant

`public static const ENTER:String = "enter"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of an `enter` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

### HIDE

Constant

`public static const HIDE:String = "hide"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `hide` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

Related API Elements

SHOW
Example ( How to use this example )
The following example creates a Button component that toggles a List component's visibility:
Copy

    import fl.controls.Button;
    import fl.controls.List;
    import fl.events.ComponentEvent;
    import fl.events.ListEvent;

    var toggleButton:Button = new Button();
    toggleButton.label = "toggle visibility";
    toggleButton.toggle = true;
    toggleButton.selected = true;
    toggleButton.emphasized = toggleButton.selected;
    toggleButton.addEventListener(Event.CHANGE, changeHandler);
    toggleButton.width = 150;
    toggleButton.move(10, 10);
    addChild(toggleButton);

    var myList:List = new List();
    myList.addItem({label:"Item 1"});
    myList.addItem({label:"Item 2"});
    myList.addItem({label:"Item 3"});
    myList.addItem({label:"Item 4"});
    myList.addItem({label:"Item 5"});
    myList.move(10, 40);
    myList.addEventListener(ComponentEvent.HIDE, hideHandler);
    myList.addEventListener(ComponentEvent.SHOW, showHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    addChild(myList);

    function changeHandler(event:Event):void {
        toggleButton.emphasized = toggleButton.selected;
        myList.visible = toggleButton.selected;
    }

    function hideHandler(event:ComponentEvent):void {
        trace("hiding list");
        myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
        myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    }

    function showHandler(event:ComponentEvent):void {
        trace("showing list");
        myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
        myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    }

    function itemRollOverHandler(event:ListEvent):void {
        trace(event.type + ":", event.item.label);
    }

    function itemRollOutHandler(event:ListEvent):void {
        trace(event.type + ":", event.item.label);
    }

### LABEL_CHANGE

Constant

`public static const LABEL_CHANGE:String = "labelChange"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `labelChange` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

### MOVE

Constant

`public static const MOVE:String = "move"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `move` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

Example ( How to use this example )
The following example repositions a UILoader component instance on the Stage based on the value of a Slider component:
Copy

    import fl.controls.Slider;
    import fl.containers.UILoader;
    import fl.events.ComponentEvent;
    import fl.events.SliderEvent;

    var myUILoader:UILoader = new UILoader();
    myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
    myUILoader.move(10, 20);
    myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
    addChild(myUILoader);

    var mySlider:Slider = new Slider();
    mySlider.liveDragging = true;
    mySlider.minimum = myUILoader.x;
    mySlider.maximum = myUILoader.x + 200;
    mySlider.snapInterval = 1;
    mySlider.tickInterval = 10;
    mySlider.move(10, 10);
    mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
    addChild(mySlider);

    function changeHandler(event:SliderEvent):void {
        myUILoader.x = event.value;
    }

    function moveHandler(event:ComponentEvent):void {
        trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
    }

### RESIZE

Constant

`public static const RESIZE:String = "resize"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `resize` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

Example ( How to use this example )
The following example loads an external image into a UILoader component instance and centers it on the Stage using the `resize` event and `move()` method:
Copy

    import fl.containers.UILoader;
    import fl.events.ComponentEvent;

    var myUILoader:UILoader = new UILoader();
    myUILoader.scaleContent = false;
    myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
    myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
    addChild(myUILoader);

    function resizeHandler(event:ComponentEvent):void {
        var myImg:UILoader = event.currentTarget as UILoader;
        var newX:uint = (stage.stageWidth - myImg.width) / 2;
        var newY:uint = (stage.stageHeight - myImg.height) / 2;
        myImg.move(newX, newY);
    }

### SHOW

Constant

`public static const SHOW:String = "show"`

Language Version: | ActionScript 3.0

Product Version: | Flash CS3

Runtime Versions: | Flash Player 9.0.28.0, AIR 1.0

Defines the value of the `type` property of a `show` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the event object with an event listener.
`target` | The object that dispatched the event. The target is not always the object listening for the event. Use the `currentTarget` property to access the object that is listening for the event.

Related API Elements

HIDE
Example ( How to use this example )
The following example creates a Button component that toggles a List component's visibility:
Copy

    import fl.controls.Button;
    import fl.controls.List;
    import fl.events.ComponentEvent;
    import fl.events.ListEvent;

    var toggleButton:Button = new Button();
    toggleButton.label = "toggle visibility";
    toggleButton.toggle = true;
    toggleButton.selected = true;
    toggleButton.emphasized = toggleButton.selected;
    toggleButton.addEventListener(Event.CHANGE, changeHandler);
    toggleButton.width = 150;
    toggleButton.move(10, 10);
    addChild(toggleButton);

    var myList:List = new List();
    myList.addItem({label:"Item 1"});
    myList.addItem({label:"Item 2"});
    myList.addItem({label:"Item 3"});
    myList.addItem({label:"Item 4"});
    myList.addItem({label:"Item 5"});
    myList.move(10, 40);
    myList.addEventListener(ComponentEvent.HIDE, hideHandler);
    myList.addEventListener(ComponentEvent.SHOW, showHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    addChild(myList);

    function changeHandler(event:Event):void {
        toggleButton.emphasized = toggleButton.selected;
        myList.visible = toggleButton.selected;
    }

    function hideHandler(event:ComponentEvent):void {
        trace("hiding list");
        myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
        myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    }

    function showHandler(event:ComponentEvent):void {
        trace("showing list");
        myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
        myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
    }

    function itemRollOverHandler(event:ListEvent):void {
        trace(event.type + ":", event.item.label);
    }

    function itemRollOutHandler(event:ListEvent):void {
        trace(event.type + ":", event.item.label);
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00