flash.events

# ErrorEvent - AS3

Package | flash.events
Class | public class ErrorEvent
Inheritance | ErrorEvent TextEvent Event Object
Subclasses | AsyncErrorEvent, AugmentedErrorEvent, DownloadErrorEvent, DRMAuthenticationErrorEvent, DRMDeviceGroupErrorEvent, DRMErrorEvent, DRMReturnVoucherErrorEvent, IOErrorEvent, RSLErrorEvent, SecurityErrorEvent, SkinErrorEvent, SQLErrorEvent, StatusFileUpdateErrorEvent, StatusUpdateErrorEvent, UncaughtErrorEvent

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 9, AIR 1.0, Flash Lite 4

An object dispatches an ErrorEvent object when an error causes an asynchronous operation to fail.

The ErrorEvent class defines only one type of `error` event: `ErrorEvent.ERROR`. The ErrorEvent class also serves as the base class for several other error event classes, including the AsyncErrorEvent, IOErrorEvent, SecurityErrorEvent, SQLErrorEvent, and UncaughtErrorEvent classes.

You can check for `error` events that do not have any listeners by registering a listener for the `uncaughtError` (UncaughtErrorEvent.UNCAUGHT_ERROR) event.

An uncaught error also causes an error dialog box displaying the error event to appear when content is running in the debugger version of Flash Player or the AIR Debug Launcher (ADL) application.

View the examples

Related API Elements

UncaughtErrorEvent

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bubbles : Boolean [read-only] Indicates whether an event is a bubbling event. | Event
|  | cancelable : Boolean [read-only] Indicates whether the behavior associated with the event can be prevented. | Event
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | currentTarget : Object [read-only] The object that is actively processing the Event object with an event listener. | Event
|  | errorID : int [read-only] Contains the reference number associated with the specific error. | ErrorEvent
|  | eventPhase : uint [read-only] The current phase in the event flow. | Event
|  | target : Object [read-only] The event target. | Event
|  | text : String For a textInput event, the character or sequence of characters entered by the user. | TextEvent
|  | type : String [read-only] The type of event. | Event

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | ErrorEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "", id:int = 0) Creates an Event object that contains information about error events. | ErrorEvent
|  | clone():Event [override] Creates a copy of the ErrorEvent object and sets the value of each property to match that of the original. | ErrorEvent
|  | formatToString(className:String, ... arguments):String A utility function for implementing the toString() method in custom ActionScript 3.0 Event classes. | Event
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isDefaultPrevented():Boolean Checks whether the preventDefault() method has been called on the event. | Event
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | preventDefault():void Cancels an event's default behavior if that behavior can be canceled. | Event
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | stopImmediatePropagation():void Prevents processing of any event listeners in the current node and any subsequent nodes in the event flow. | Event
|  | stopPropagation():void Prevents processing of any event listeners in nodes subsequent to the current node in the event flow. | Event
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String [override] Returns a string that contains all the properties of the ErrorEvent object. | ErrorEvent
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Public Constants
Hide Inherited Public Constants
Show Inherited Public Constants

| Constant | Defined By
--- | --- | ---
|  | ERROR : String = "error" [static] Defines the value of the type property of an error event object. | ErrorEvent

Property Detail

### errorID

property

`errorID:int` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 10.1

Contains the reference number associated with the specific error. For a custom ErrorEvent object, this number is the value from the `id` parameter supplied in the constructor.

Implementation
`public function get errorID():int`
Constructor Detail

### ErrorEvent

()
Constructor

`public function ErrorEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "", id:int = 0)`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 9, AIR 1.0, Flash Lite 4

Creates an Event object that contains information about error events. Event objects are passed as parameters to event listeners.

Parameters

| `type:String` — The type of the event. Event listeners can access this information through the inherited `type` property. There is only one type of error event: `ErrorEvent.ERROR`.
| `bubbles:Boolean` (default = `false`)`` — Determines whether the Event object bubbles. Event listeners can access this information through the inherited `bubbles` property.
| `cancelable:Boolean` (default = `false`)`` — Determines whether the Event object can be canceled. Event listeners can access this information through the inherited `cancelable` property.
| `text:String` (default = "``")`` — Text to be displayed as an error message. Event listeners can access this information through the `text` property.
| `id:int` (default = `0`)`` — A reference number to associate with the specific error (supported in Adobe AIR only).

Method Detail

### clone

()
method

`override public function clone():Event`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 9, AIR 1.0, Flash Lite 4

Creates a copy of the ErrorEvent object and sets the value of each property to match that of the original.

Returns

| `Event` — A new ErrorEvent object with property values that match those of the original.

### toString

()
method

`override public function toString():String`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 9, AIR 1.0, Flash Lite 4

Returns a string that contains all the properties of the ErrorEvent object. The string is in the following format:

`[ErrorEvent type=value bubbles=value cancelable=value text=value errorID=value]`

Note: The `errorId` value returned by the `toString()` method is only available for Adobe AIR. While Flash Player 10.1 supports the `errorID` property, calling `toString()` on the ErrorEvent object does not provide the `errorId` value in Flash Player.

Returns

| `String` — A string that contains all the properties of the ErrorEvent object.

Constant Detail

### ERROR

Constant

`public static const ERROR:String = "error"`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 9, AIR 1.0, Flash Lite 4

Defines the value of the `type` property of an `error` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object experiencing a network operation failure.
`text` | Text to be displayed as an error message.

Examples How to use this example
ErrorEventExample.as
The following example demonstrates the use of a single error handler (`errorHandler()`) that captures multiple types of error events. If there is an `ioError` event, the handler attempts to load from the network, which then throws a `securityError`.

Note: This example does not work if you have a file named MissingFile.xml in the same directory as your SWF file.

Copy

    package {
        import flash.display.Sprite;
        import flash.net.URLLoader;
        import flash.net.URLRequest;
        import flash.events.*;

        public class ErrorEventExample extends Sprite {
            private var loader:URLLoader;
            private var request:URLRequest;

            public function ErrorEventExample() {
                loader = new URLLoader();
                loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
                loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, errorHandler);

                request = new URLRequest();
                loadFromFileSystem();
            }

            private function loadFromFileSystem():void {
                request.url = "MissingFile.xml";
                loader.load(request);
            }

            private function loadFromNetwork():void {
                request.url = "http://www.[yourDomain].com/MissingFile.xml";
                loader.load(request);
            }

            private function errorHandler(event:ErrorEvent):void {
                trace("errorHandler: " + event);
                if(event is IOErrorEvent) {
                    loadFromNetwork();
                }
            }
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00