flashx.textLayout.events

# TextLayoutEvent - AS3

Package | flashx.textLayout.events
Class | public class TextLayoutEvent
Inheritance | TextLayoutEvent Event Object
Subclasses | ScrollEvent

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 10, AIR 1.5

A TextLayoutEvent instance represents an event, such as the `TextLayoutEvent.SCROLL` event, that does not require custom properties.

A scroll event is represented by a TextLayoutEvent instance with its `type` property set to `TextLayoutEvent.SCROLL`. A class specifically for scroll events is not necessary because there are no custom properties for a scroll event, as there are for the other events that have specific event classes. If a new text layout event is needed, and the event does not require custom properties, the new event will also be represented by a TextLayoutEvent object, but with its `type` property set to a new static constant.

View the examples

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bubbles : Boolean [read-only] Indicates whether an event is a bubbling event. | Event
|  | cancelable : Boolean [read-only] Indicates whether the behavior associated with the event can be prevented. | Event
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | currentTarget : Object [read-only] The object that is actively processing the Event object with an event listener. | Event
|  | eventPhase : uint [read-only] The current phase in the event flow. | Event
|  | target : Object [read-only] The event target. | Event
|  | type : String [read-only] The type of event. | Event

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | TextLayoutEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false) The TextLayoutEvent class represents the event object passed to the event listener for many Text Layout events. | TextLayoutEvent
|  | clone():Event Duplicates an instance of an Event subclass. | Event
|  | formatToString(className:String, ... arguments):String A utility function for implementing the toString() method in custom ActionScript 3.0 Event classes. | Event
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isDefaultPrevented():Boolean Checks whether the preventDefault() method has been called on the event. | Event
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | preventDefault():void Cancels an event's default behavior if that behavior can be canceled. | Event
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | stopImmediatePropagation():void Prevents processing of any event listeners in the current node and any subsequent nodes in the event flow. | Event
|  | stopPropagation():void Prevents processing of any event listeners in nodes subsequent to the current node in the event flow. | Event
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String Returns a string containing all the properties of the Event object. | Event
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Public Constants
Hide Inherited Public Constants
Show Inherited Public Constants

| Constant | Defined By
--- | --- | ---
|  | SCROLL : String = "scroll" [static] The TextLayoutEvent.SCROLL constant defines the value of the type property of the event object for a scroll event. | TextLayoutEvent

Constructor Detail

### TextLayoutEvent

()
Constructor

`public function TextLayoutEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false)`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 10, AIR 1.5

The TextLayoutEvent class represents the event object passed to the event listener for many Text Layout events.

Parameters

| `type:String`
| `bubbles:Boolean` (default = `false`)``
| `cancelable:Boolean` (default = `false`)``

Constant Detail

### SCROLL

Constant

`public static const SCROLL:String = "scroll"`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 10, AIR 1.5

The `TextLayoutEvent.SCROLL` constant defines the value of the `type` property of the event object for a `scroll` event.

Examples How to use this example
TextLayoutEvent_example.as
This example shows how to create an event handler that listens for a scroll event. The two key steps are to call the `addEventListener()` method on the text flow and to create an event handler function.

Call the `addEventListener()` method on the TextFlow instance. You can use the simple string `"text"`, but it is safer to use the static constant `TextLayoutEvent.SCROLL`

The event handler function in this example is named `scrollEventHandler()`. The event handler executes a `trace()` statement whenever a scroll event is detected. This example does not include a scroll bar, but the text scrolls when a user highlights text and drags the cursor down past the bottom of the container.

Copy

    package flashx.textLayout.events.examples {
        import flash.display.Sprite;
        import flash.events.Event;

        import flashx.textLayout.compose.StandardFlowComposer;
        import flashx.textLayout.container.ContainerController;
        import flashx.textLayout.conversion.TextConverter;
        import flashx.textLayout.edit.EditManager;
        import flashx.textLayout.elements.TextFlow;
        import flashx.textLayout.events.TextLayoutEvent;
        import flashx.undo.UndoManager;

        public class TextLayoutEvent_example extends Sprite
        {
            private const textMarkup:String = "<flow:TextFlow xmlns:flow='http://ns.adobe.com/textLayout/2008' fontSize='14' " +
                "textIndent='10' paragraphSpaceBefore='6' paddingTop='8' paddingLeft='8' paddingRight='8'>" +
                "<flow:p paragraphSpaceBefore='inherit'>" +
                    "<flow:span>There are many </flow:span>" +
                    "<flow:span fontStyle='italic'>such</flow:span>" +
                    "<flow:span> lime-kilns in that tract of country, for the purpose of burning the white" +
                        " marble which composes a large part of the substance of the hills. Some of them, built " +
                        "years ago, and long deserted, with weeds growing in the vacant round of the interior, " +
                        "which is open to the sky, and grass and wild-flowers rooting themselves into the chinks" +
                        "of the stones, look already like relics of antiquity, and may yet be overspread with the" +
                        " lichens of centuries to come. Others, where the lime-burner still feeds his daily and " +
                        "nightlong fire, afford points of interest to the wanderer among the hills, who seats " +
                        "himself on a log of wood or a fragment of marble, to hold a chat with the solitary man. " +
                        "It is a lonesome, and, when the character is inclined to thought, may be an intensely " +
                        "thoughtful occupation; as it proved in the case of Ethan Brand, who had mused to such " +
                        "strange purpose, in days gone by, while the fire in this very kiln was burning.</flow:span>" +
                "</flow:p>" +
                "</flow:TextFlow>";

            public function TextLayoutEvent_example()
            {
                // create the TextFlow, container, and container controller
                var textFlow:TextFlow;
                var container:Sprite = new Sprite();
                var _controller:ContainerController = new ContainerController(container, 200, 100);

                // import the text flow from markup using TextFilter and assign a StandardFlowComposer
                textFlow = TextConverter.importToFlow(textMarkup, TextConverter.TEXT_LAYOUT_FORMAT);
                textFlow.flowComposer = new StandardFlowComposer();

                // create undo, edit and interaction managers
                var _undoManager:UndoManager = new UndoManager();
                var _editManager:EditManager = new EditManager(_undoManager);
                textFlow.interactionManager = _editManager;

                // Add container to display list
                addChild(container);
                container.x = 25;
                container.y = 100;

                // Add an event listener for the TextLayoutEvent.SCROLL event
                textFlow.addEventListener(TextLayoutEvent.SCROLL, scrollEventHandler);

                // add the controller to the text flow and update it to display the text
                textFlow.flowComposer.addController(_controller);
                textFlow.flowComposer.updateAllControllers();
            }

            private function scrollEventHandler(evt:Event):void {
                trace ("scroll event occurred");
            }
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00