flash.net

# URLRequestMethod - AS3

Package | flash.net
Class | public final class URLRequestMethod
Inheritance | URLRequestMethod Object

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

The URLRequestMethod class provides values that specify whether the URLRequest object should use the `POST` method or the `GET` method when sending data to a server.

View the examples

Related API Elements

URLRequest
URLVariables

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Public Constants

| Constant | Defined By
--- | --- | ---
|  | DELETE : String = "DELETE" [static] Specifies that the URLRequest object is a DELETE. | URLRequestMethod
|  | GET : String = "GET" [static] Specifies that the URLRequest object is a GET. | URLRequestMethod
|  | HEAD : String = "HEAD" [static] Specifies that the URLRequest object is a HEAD. | URLRequestMethod
|  | OPTIONS : String = "OPTIONS" [static] Specifies that the URLRequest object is OPTIONS. | URLRequestMethod
|  | POST : String = "POST" [static] Specifies that the URLRequest object is a POST. | URLRequestMethod
|  | PUT : String = "PUT" [static] Specifies that the URLRequest object is a PUT. | URLRequestMethod

Constant Detail

### DELETE

Constant

`public static const DELETE:String = "DELETE"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0

Specifies that the URLRequest object is a `DELETE`.

### GET

Constant

`public static const GET:String = "GET"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Specifies that the URLRequest object is a `GET`.

### HEAD

Constant

`public static const HEAD:String = "HEAD"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0

Specifies that the URLRequest object is a `HEAD`.

### OPTIONS

Constant

`public static const OPTIONS:String = "OPTIONS"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0

Specifies that the URLRequest object is `OPTIONS`.

### POST

Constant

`public static const POST:String = "POST"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Specifies that the URLRequest object is a `POST`.

Note: For content running in Adobe AIR, when using the `navigateToURL()` function, the runtime treats a URLRequest that uses the POST method (one that has its `method` property set to `URLRequestMethod.POST`) as using the GET method.

### PUT

Constant

`public static const PUT:String = "PUT"`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0

Specifies that the URLRequest object is a `PUT`.

Examples How to use this example
URLRequestMethodExample.as
The following example loads and displays the data found in a local text file. It also traces event handling information.

Note:To run this example, put a file named example.txt in the same directory as your SWF file. That file should be a simple text file containing a few words or lines of text.

The example code does the following:

1. The constructor function creates a URLLoader instance named `loader`.
2. The `loader` object is passed to the `configureListeners()` method, which adds listeners for each of the supported URLLoader events.
3. A URLRequest instance named `request` is created, which specifies name of the file to be loaded.
4. The `method` property of the request is set to `URLRequestMethod.POST`.
5. The `request` object is then passed to `loader.load()`, which loads the text file.
6. When the URLLoader has finished loading the text file the `Event.COMPLETE` event fires, triggering the `completeHandler()` method. The `completeHandler()` method simply traces the `data` property, the contents of the text file.

Copy

    package {
        import flash.display.Sprite;
        import flash.events.*;
        import flash.net.*;

        public class URLRequestMethodExample extends Sprite {
            private var loader:URLLoader;

            public function URLRequestMethodExample() {
                loader = new URLLoader();
                configureListeners(loader);

                var request:URLRequest = new URLRequest("example.txt");

                request.method = URLRequestMethod.POST;
                loader.load(request);
            }

            private function configureListeners(dispatcher:IEventDispatcher):void {
                dispatcher.addEventListener(Event.COMPLETE, completeHandler);
                dispatcher.addEventListener(Event.OPEN, openHandler);
                dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
                dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
                dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            }

            private function completeHandler(event:Event):void {
                var loader:URLLoader = URLLoader(event.target);
                trace("completeHandler: " + loader.data);
            }

            private function openHandler(event:Event):void {
                trace("openHandler: " + event);
            }

            private function progressHandler(event:ProgressEvent):void {
                trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
            }

            private function securityErrorHandler(event:SecurityErrorEvent):void {
                trace("securityErrorHandler: " + event);
            }

            private function httpStatusHandler(event:HTTPStatusEvent):void {
                trace("httpStatusHandler: " + event);
            }

            private function ioErrorHandler(event:IOErrorEvent):void {
                trace("ioErrorHandler: " + event);
            }
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00