flash.filters

# GlowFilter - AS3

Package | flash.filters
Class | public final class GlowFilter
Inheritance | GlowFilter BitmapFilter Object

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The GlowFilter class lets you apply a glow effect to display objects. You have several options for the style of the glow, including inner or outer glow and knockout mode. The glow filter is similar to the drop shadow filter with the `distance` and `angle` properties of the drop shadow filter set to 0. You can apply the filter to any display object (that is, objects that inherit from the DisplayObject class), such as MovieClip, SimpleButton, TextField, and Video objects, as well as to BitmapData objects.

The use of filters depends on the object to which you apply the filter:

- To apply filters to display objects, use the `filters` property (inherited from DisplayObject). Setting the `filters` property of an object does not modify the object, and you can remove the filter by clearing the `filters` property.
- To apply filters to BitmapData objects, use the `BitmapData.applyFilter()` method. Calling `applyFilter()` on a BitmapData object takes the source BitmapData object and the filter object and generates a filtered image as a result.

If you apply a filter to a display object, the `cacheAsBitmap` property of the display object is set to `true`. If you clear all filters, the original value of `cacheAsBitmap` is restored.

This filter supports Stage scaling. However, it does not support general scaling, rotation, and skewing. If the object itself is scaled (if `scaleX` and `scaleY` are set to a value other than 1.0), the filter is not scaled. It is scaled only when the user zooms in on the Stage.

A filter is not applied if the resulting image exceeds the maximum dimensions. In AIR 1.5 and Flash Player 10, the maximum is 8,191 pixels in width or height, and the total number of pixels cannot exceed 16,777,215 pixels. (So, if an image is 8,191 pixels wide, it can only be 2,048 pixels high.) In Flash Player 9 and earlier and AIR 1.1 and earlier, the limitation is 2,880 pixels in height and 2,880 pixels in width. For example, if you zoom in on a large movie clip with a filter applied, the filter is turned off if the resulting image exceeds the maximum dimensions.

View the examples

Related API Elements

flash.display.BitmapData.applyFilter()
flash.display.DisplayObject.filters
flash.display.DisplayObject.cacheAsBitmap
flash.display.DisplayObject.scaleX
flash.display.DisplayObject.scaleY
flash.filters.DropShadowFilter.distance
flash.filters.DropShadowFilter.angle

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | alpha : Number The alpha transparency value for the color. | GlowFilter
|  | blurX : Number The amount of horizontal blur. | GlowFilter
|  | blurY : Number The amount of vertical blur. | GlowFilter
|  | color : uint The color of the glow. | GlowFilter
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | inner : Boolean Specifies whether the glow is an inner glow. | GlowFilter
|  | knockout : Boolean Specifies whether the object has a knockout effect. | GlowFilter
|  | quality : int The number of times to apply the filter. | GlowFilter
|  | strength : Number The strength of the imprint or spread. | GlowFilter

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | GlowFilter(color:uint = 0xFF0000, alpha:Number = 1.0, blurX:Number = 6.0, blurY:Number = 6.0, strength:Number = 2, quality:int = 1, inner:Boolean = false, knockout:Boolean = false) Initializes a new GlowFilter instance with the specified parameters. | GlowFilter
|  | clone():BitmapFilter [override] Returns a copy of this filter object. | GlowFilter
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object

Property Detail

### alpha

property

`alpha:Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The alpha transparency value for the color. Valid values are 0 to 1. For example, .25 sets a transparency value of 25%. The default value is 1.

Implementation
`public function get alpha():Number`
`public function set alpha(value:Number):void`

### blurX

property

`blurX:Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The amount of horizontal blur. Valid values are 0 to 255 (floating point). The default value is 6. Values that are a power of 2 (such as 2, 4, 8, 16, and 32) are optimized to render more quickly than other values.

Implementation
`public function get blurX():Number`
`public function set blurX(value:Number):void`

### blurY

property

`blurY:Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The amount of vertical blur. Valid values are 0 to 255 (floating point). The default value is 6. Values that are a power of 2 (such as 2, 4, 8, 16, and 32) are optimized to render more quickly than other values.

Implementation
`public function get blurY():Number`
`public function set blurY(value:Number):void`

### color

property

`color:uint`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The color of the glow. Valid values are in the hexadecimal format 0xRRGGBB. The default value is 0xFF0000.

Implementation
`public function get color():uint`
`public function set color(value:uint):void`

### inner

property

`inner:Boolean`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

Specifies whether the glow is an inner glow. The value `true` indicates an inner glow. The default is `false`, an outer glow (a glow around the outer edges of the object).

Implementation
`public function get inner():Boolean`
`public function set inner(value:Boolean):void`

### knockout

property

`knockout:Boolean`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

Specifies whether the object has a knockout effect. A value of `true` makes the object's fill transparent and reveals the background color of the document. The default value is `false` (no knockout effect).

Implementation
`public function get knockout():Boolean`
`public function set knockout(value:Boolean):void`

### quality

property

`quality:int`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The number of times to apply the filter. The default value is `BitmapFilterQuality.LOW`, which is equivalent to applying the filter once. The value `BitmapFilterQuality.MEDIUM` applies the filter twice; the value `BitmapFilterQuality.HIGH` applies it three times. Filters with lower values are rendered more quickly.

For most applications, a `quality` value of low, medium, or high is sufficient. Although you can use additional numeric values up to 15 to achieve different effects, higher values are rendered more slowly. Instead of increasing the value of `quality`, you can often get a similar effect, and with faster rendering, by simply increasing the values of the `blurX` and `blurY` properties.

Implementation
`public function get quality():int`
`public function set quality(value:int):void`

Related API Elements

flash.filters.BitmapFilterQuality

### strength

property

`strength:Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

The strength of the imprint or spread. The higher the value, the more color is imprinted and the stronger the contrast between the glow and the background. Valid values are 0 to 255. The default is 2.

Implementation
`public function get strength():Number`
`public function set strength(value:Number):void`
Constructor Detail

### GlowFilter

()
Constructor

`public function GlowFilter(color:uint = 0xFF0000, alpha:Number = 1.0, blurX:Number = 6.0, blurY:Number = 6.0, strength:Number = 2, quality:int = 1, inner:Boolean = false, knockout:Boolean = false)`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

Initializes a new GlowFilter instance with the specified parameters.

Parameters

| `color:uint` (default = `0xFF0000`)`` — The color of the glow, in the hexadecimal format 0xRRGGBB. The default value is 0xFF0000.
| `alpha:Number` (default = `1.0`)`` — The alpha transparency value for the color. Valid values are 0 to 1. For example, .25 sets a transparency value of 25%.
| `blurX:Number` (default = `6.0`)`` — The amount of horizontal blur. Valid values are 0 to 255 (floating point). Values that are a power of 2 (such as 2, 4, 8, 16 and 32) are optimized to render more quickly than other values.
| `blurY:Number` (default = `6.0`)`` — The amount of vertical blur. Valid values are 0 to 255 (floating point). Values that are a power of 2 (such as 2, 4, 8, 16 and 32) are optimized to render more quickly than other values.
| `strength:Number` (default = `2`)`` — The strength of the imprint or spread. The higher the value, the more color is imprinted and the stronger the contrast between the glow and the background. Valid values are 0 to 255.
| `quality:int` (default = `1`)`` — The number of times to apply the filter. Use the BitmapFilterQuality constants:

- `BitmapFilterQuality.LOW`
- `BitmapFilterQuality.MEDIUM`
- `BitmapFilterQuality.HIGH`

For more information, see the description of the `quality` property.

| `inner:Boolean` (default = `false`)`` — Specifies whether the glow is an inner glow. The value `true` specifies an inner glow. The value `false` specifies an outer glow (a glow around the outer edges of the object).
| `knockout:Boolean` (default = `false`)`` — Specifies whether the object has a knockout effect. The value `true` makes the object's fill transparent and reveals the background color of the document.

Related API Elements

BitmapFilterQuality
GlowFilter.quality
Method Detail

### clone

()
method

`override public function clone():BitmapFilter`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9

Returns a copy of this filter object.

Returns

| `BitmapFilter` — A new GlowFilter instance with all the properties of the original GlowFilter instance.

Examples How to use this example
GlowFilterExample.as
The following example draws a square and applies a blur filter to it. The general workflow of the example is as follows:

1. Import the required classes.
2. Declare three properties used in the `draw` method, which uses methods of the Graphics class accessed through the `graphics` property of Sprite to draw an orange square.
3. Create the constructor function, which does the following:
   - Calls the `draw` function to create a rectangle.
   - Creates a BitmapFilter object `glowFilter` and assigns it the return values from the `getBitmapFilter()` function.
   - Assigns the array of values from the `glowFilter` object to the `filters` property of the root display object. In this case, all display object children of the root display object inherit the glow filter properties. So, the rectangle created in the the `draw()` function displays the glow filter properties.

Copy

    package {
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;
        import flash.filters.BitmapFilter;
        import flash.filters.BitmapFilterQuality;
        import flash.filters.GlowFilter;

        public class GlowFilterExample extends Sprite {
            private var bgColor:uint = 0xFFCC00;
            private var size:uint    = 80;
            private var offset:uint  = 50;

            public function GlowFilterExample() {
            //draw the rectangle using the draw() function below
                draw();

            //assign the values from getBitmapFilter function below
            //to a BitmapFilter object "glowFilter"
                var glowFilter:BitmapFilter = getBitmapFilter();

            //populate the filters property of the root display object with the array of values
            //from the glowFilter object.
                filters = [ glowFilter ];
            }

            private function getBitmapFilter():BitmapFilter {
                var color:Number = 0x33CCFF;
                var alpha:Number = 0.8;
                var blurX:Number = 35;
                var blurY:Number = 35;
                var strength:Number = 2;
                var inner:Boolean = false;
                var knockout:Boolean = false;
                var quality:Number = BitmapFilterQuality.HIGH;

                return new GlowFilter(color,
                                      alpha,
                                      blurX,
                                      blurY,
                                      strength,
                                      quality,
                                      inner,
                                      knockout);
            }

            private function draw():void {
                graphics.beginFill(bgColor);
                graphics.drawRect(offset, offset, size, size);
                graphics.endFill();
            }
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00