flash.net

# XMLSocket - AS3

Package | flash.net
Class | public class XMLSocket
Inheritance | XMLSocket EventDispatcher Object

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

The XMLSocket class implements client sockets that let the Flash Player or AIR application communicate with a server computer identified by an IP address or domain name. The XMLSocket class is useful for client-server applications that require low latency, such as real-time chat systems. A traditional HTTP-based chat solution frequently polls the server and downloads new messages using an HTTP request. In contrast, an XMLSocket chat solution maintains an open connection to the server, which lets the server immediately send incoming messages without a request from the client. To use the XMLSocket class, the server computer must run a daemon that understands the protocol used by the XMLSocket class. The protocol is described in the following list:

- XML messages are sent over a full-duplex TCP/IP stream socket connection.
- Each XML message is a complete XML document, terminated by a zero (0) byte.
- An unlimited number of XML messages can be sent and received over a single XMLSocket connection.

Setting up a server to communicate with the XMLSocket object can be challenging. If your application does not require real-time interactivity, use the URLLoader class instead of the XMLSocket class.

To use the methods of the XMLSocket class, first use the constructor, `new XMLSocket`, to create an XMLSocket object.

SWF files in the local-with-filesystem sandbox may not use sockets.

Socket policy files on the target host specify the hosts from which SWF files can make socket connections, and the ports to which those connections can be made. The security requirements with regard to socket policy files have become more stringent in the last several releases of Flash Player. In all versions of Flash Player, Adobe recommends the use of a socket policy file; in some circumstances, a socket policy file is required. Therefore, if you are using XMLSocket objects, make sure that the target host provides a socket policy file if necessary.

The following list summarizes the requirements for socket policy files in different versions of Flash Player:

- In Flash Player 9.0.124.0 and later, a socket policy file is required for any XMLSocket connection. That is, a socket policy file on the target host is required no matter what port you are connecting to, and is required even if you are connecting to a port on the same host that is serving the SWF file.
- In Flash Player versions 9.0.115.0 and earlier, if you want to connect to a port number below 1024, or if you want to connect to a host other than the one serving the SWF file, a socket policy file on the target host is required.
- In Flash Player 9.0.115.0, even if a socket policy file isn't required, a warning is displayed when using the Flash Debug Player if the target host doesn't serve a socket policy file.

However, in Adobe AIR, content in the `application` security sandbox (content installed with the AIR application) are not restricted by these security limitations.

For more information related to security, see the Flash Player Developer Center Topic: Security.

View the examples

More examples

Binary client sockets
Connecting to sockets

Related API Elements

flash.net.URLLoader.load()
flash.net.URLLoader

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | connected : Boolean [read-only] Indicates whether this XMLSocket object is currently connected. | XMLSocket
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | timeout : int Indicates the number of milliseconds to wait for a connection. | XMLSocket

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | XMLSocket(host:String = null, port:int = 0) Creates a new XMLSocket object. | XMLSocket
|  | addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registers an event listener object with an EventDispatcher object so that the listener receives notification of an event. | EventDispatcher
|  | close():void Closes the connection specified by the XMLSocket object. | XMLSocket
|  | connect(host:String, port:int):void Establishes a connection to the specified Internet host using the specified TCP port. | XMLSocket
|  | dispatchEvent(event:Event):Boolean Dispatches an event into the event flow. | EventDispatcher
|  | hasEventListener(type:String):Boolean Checks whether the EventDispatcher object has any listeners registered for a specific type of event. | EventDispatcher
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Removes a listener from the EventDispatcher object. | EventDispatcher
|  | send(object:*):void Converts the XML object or data specified in the object parameter to a string and transmits it to the server, followed by a zero (0) byte. | XMLSocket
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object
|  | willTrigger(type:String):Boolean Checks whether an event listener is registered with this EventDispatcher object or any of its ancestors for the specified event type. | EventDispatcher

Events
Click for more information on events
Hide Inherited Events
Show Inherited Events

| Event | Summary | Defined By
--- | --- | --- | ---
|  | activate | [broadcast event] Dispatched when the Flash Player or AIR application gains operating system focus and becomes active. | EventDispatcher
|  | close | Dispatched when the server closes the socket connection. | XMLSocket
|  | connect | Dispatched after a successful call to the XMLSocket.connect() method. | XMLSocket
|  | data | Dispatched after raw data is sent or received. | XMLSocket
|  | deactivate | [broadcast event] Dispatched when the Flash Player or AIR application operating loses system focus and is becoming inactive. | EventDispatcher
|  | ioError | Dispatched when an input/output error occurs that causes a send or receive operation to fail. | XMLSocket
|  | securityError | Dispatched if a call to the XMLSocket.connect() method attempts to connect either to a server outside the caller's security sandbox or to a port lower than 1024. | XMLSocket

Property Detail

### connected

property

`connected:Boolean` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Indicates whether this XMLSocket object is currently connected. You can also check whether the connection succeeded by registering for the `connect` event and `ioError` event.

Implementation
`public function get connected():Boolean`

Related API Elements

connect
ioError

### timeout

property

`timeout:int`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 10, AIR 1.5, Flash Lite 4

Indicates the number of milliseconds to wait for a connection.

If the connection doesn't succeed within the specified time, the connection fails. The default value is 20,000 (twenty seconds).

Implementation
`public function get timeout():int`
`public function set timeout(value:int):void`
Constructor Detail

### XMLSocket

()
Constructor

`public function XMLSocket(host:String = null, port:int = 0)`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Creates a new XMLSocket object. If no parameters are specified, an initially disconnected socket is created. If parameters are specified, a connection is attempted to the specified host and port.

Note: It is strongly advised to use the constructor form without parameters, then add any event listeners, then call the `connect` method with `host` and `port` parameters. This sequence guarantees that all event listeners will work properly.

Parameters

| `host:String` (default = `null`)`` — A fully qualified DNS domain name or an IP address in the form .222.333.444. In Flash Player 9.0.115.0 and AIR 1.0 and later, you can specify IPv6 addresses, such as rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]. You can also specify `null` to connect to the host server on which the SWF file resides. If the SWF file issuing this call is running in a web browser, `host` must be in the same domain as the SWF file.
| `port:int` (default = `0`)`` — The TCP port number on the target host used to establish a connection. In Flash Player 9.0.124.0 and later, the target host must serve a socket policy file specifying that socket connections are permitted from the host serving the SWF file to the specified port. In earlier versions of Flash Player, a socket policy file is required only if you want to connect to a port number below 1024, or if you want to connect to a host other than the one serving the SWF file.

Related API Elements

connect()
Method Detail

### close

()
method

`public function close():void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Closes the connection specified by the XMLSocket object. The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `close()` method.

More examples

Binary client sockets

Related API Elements

connect()

### connect

()
method

`public function connect(host:String, port:int):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Establishes a connection to the specified Internet host using the specified TCP port.

If you specify `null` for the `host` parameter, the host contacted is the one where the file calling `XMLSocket.connect()` resides. For example, if the calling file was downloaded from www.adobe.com, specifying `null` for the host parameter means you are connecting to www.adobe.com.

You can prevent a file from using this method by setting the `allowNetworking` parameter of the the `object` and `embed` tags in the HTML page that contains the SWF content.

For more information, see the Flash Player Developer Center Topic: Security.

Parameters

| `host:String` — A fully qualified DNS domain name or an IP address in the form 111.222.333.444. You can also specify `null` to connect to the host server on which the SWF file resides. If the calling file is a SWF file running in a web browser, `host` must be in the same domain as the file.
| `port:int` — The TCP port number on the target host used to establish a connection. In Flash Player 9.0.124.0 and later, the target host must serve a socket policy file specifying that socket connections are permitted from the host serving the SWF file to the specified port. In earlier versions of Flash Player, a socket policy file is required only if you want to connect to a port number below 1024, or if you want to connect to a host other than the one serving the SWF file.

Events

| `securityError:`SecurityErrorEvent`` — A connect operation attempted to connect to a host outside the caller's security sandbox, or to a port that requires a socket policy file. Work around either problem by using a socket policy file on the target host.
| `data:`DataEvent`` — Dispatched when raw data has been received.
| `connect:`Event`` — Dispatched when network connection has been established.

Throws

| `SecurityError` — Local untrusted files may not communicate with the Internet. Work around this limitation by reclassifying the file as local-with-networking or trusted.
| `SecurityError` — You may not specify a socket port higher than 65535.

More examples

Binary client sockets
Connecting to sockets

Related API Elements

flash.events.Event.CONNECT

### send

()
method

`public function send(object:*):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Converts the XML object or data specified in the `object` parameter to a string and transmits it to the server, followed by a zero (0) byte. If `object` is an XML object, the string is the XML textual representation of the XML object. The send operation is asynchronous; it returns immediately, but the data may be transmitted at a later time. The `XMLSocket.send()` method does not return a value indicating whether the data was successfully transmitted.

If you do not connect the XMLSocket object to the server using `XMLSocket.connect()`), the `XMLSocket.send()` operation fails.

Parameters

| `object:*` — An XML object or other data to transmit to the server.

Throws

| `IOError` — The XMLSocket object is not connected to the server.

More examples

Binary client sockets

Related API Elements

connect()
Event Detail

### close

Event

Event Object Type: `flash.events.Event`
property Event.type = `flash.events.Event.CLOSE`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when the server closes the socket connection. The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `XMLSocket.close()` method.

The `Event.CLOSE` constant defines the value of the `type` property of a `close` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose connection has been closed.

### connect

Event

Event Object Type: `flash.events.Event`
property Event.type = `flash.events.Event.CONNECT`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched after a successful call to the `XMLSocket.connect()` method.

The `Event.CONNECT` constant defines the value of the `type` property of a `connect` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Socket or XMLSocket object that has established a network connection.

### data

Event

Event Object Type: `flash.events.DataEvent`
property DataEvent.type = `flash.events.DataEvent.DATA`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched after raw data is sent or received.

Defines the value of the `type` property of a `data` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`data` | The raw data loaded into Flash Player or Adobe AIR.
`target` | The XMLSocket object receiving data.

### ioError

Event

Event Object Type: `flash.events.IOErrorEvent`
property IOErrorEvent.type = `flash.events.IOErrorEvent.IO_ERROR`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when an input/output error occurs that causes a send or receive operation to fail.

Defines the value of the `type` property of an `ioError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`errorID` | A reference number associated with the specific error (AIR only).
`target` | The network object experiencing the input/output error.
`text` | Text to be displayed as an error message.

### securityError

Event

Event Object Type: `flash.events.SecurityErrorEvent`
property SecurityErrorEvent.type = `flash.events.SecurityErrorEvent.SECURITY_ERROR`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched if a call to the `XMLSocket.connect()` method attempts to connect either to a server outside the caller's security sandbox or to a port lower than 1024.

The `SecurityErrorEvent.SECURITY_ERROR` constant defines the value of the `type` property of a `securityError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object reporting the security error.
`text` | Text to be displayed as an error message.

Related API Elements

XMLSocket.connect()
Examples How to use this example
XMLSocketExample.as
The following example uses the class XMLSocketExample class to send data using an XMLSocket and print information during XMLSocket events. This is accomplished using the following steps:

1. The XMLSocketExample constructor creates a XMLSocket instance named `socket` and passes `socket` to `ConfigureListeners()` (described below) and then calls the `connect()` method of XMLSocket using the host name "localhost" and port number of `8080`.
2. The `configureListeners()` method is then called, which adds listeners for each of the supported XMLSocket events:
   - `closeHandler()`: listens for the `close` event, which is dispatched after the network connection has been closed.
   - `connectHandler()`: listens for the `connect` event, dispatched when the network connection has been established.
   - `dataHandler()`: listens for the `data` events, dispatched every time the XMLSocket receives new data.
   - `progressHandler()`: listens for the `progress` events, dispatched when a call to `send()` has been made and while the send is ongoing.
   - `securityErrorHandler()`: listens for `securityError` events, which would be dispatched if an attempt was made to access the XMLSocket with the wrong local playback security setting or using a port lower than 1024.
   - `ioErrorHandler()`: listens for `ioError` events, which would happen only if an operation to send or receive data failed.

Notes:

- You need to compile the SWF file with "Local playback security" set to "Access network only".
- You need a server running on your domain using port 8080 for this example to work.
- If you are running Flash Player 9.0.124.0 or later, you need to place a socket policy file on your server that permits socket connections from your domain to port 8080. For information on serving socket policy files, see the Flash Player Developer Center Topic: Setting up a socket policy file server.

Copy

    package {
        import flash.display.Sprite;
        import flash.events.*;
        import flash.net.XMLSocket;

        public class XMLSocketExample extends Sprite {
            private var hostName:String = "localhost";
            private var port:uint = 8080;
            private var socket:XMLSocket;

            public function XMLSocketExample() {
                socket = new XMLSocket();
                configureListeners(socket);
                if (hostName && port) {
                    socket.connect(hostName, port);
                }
            }

            public function send(data:Object):void {
                socket.send(data);
            }

            private function configureListeners(dispatcher:IEventDispatcher):void {
                dispatcher.addEventListener(Event.CLOSE, closeHandler);
                dispatcher.addEventListener(Event.CONNECT, connectHandler);
                dispatcher.addEventListener(DataEvent.DATA, dataHandler);
                dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
                dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            }

            private function closeHandler(event:Event):void {
                trace("closeHandler: " + event);
            }

            private function connectHandler(event:Event):void {
                trace("connectHandler: " + event);
            }

            private function dataHandler(event:DataEvent):void {
                trace("dataHandler: " + event);
            }

            private function ioErrorHandler(event:IOErrorEvent):void {
                trace("ioErrorHandler: " + event);
            }

            private function progressHandler(event:ProgressEvent):void {
                trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
            }

            private function securityErrorHandler(event:SecurityErrorEvent):void {
                trace("securityErrorHandler: " + event);
            }
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00