flash.net

# Socket - AS3

Package | flash.net
Class | public class Socket
Inheritance | Socket EventDispatcher Object
Implements | IDataInput, IDataOutput
Subclasses | SecureSocket

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

The Socket class enables code to establish Transport Control Protocol (TCP) socket connections for sending and receiving binary data.

The Socket class is useful for working with servers that use binary protocols.

To use the methods of the Socket class, first use the constructor, `new Socket`, to create a Socket object.

A socket transmits and receives data asynchronously.

On some operating systems, flush() is called automatically between execution frames, but on other operating systems, such as Windows, the data is never sent unless you call `flush()` explicitly. To ensure your application behaves reliably across all operating systems, it is a good practice to call the `flush()` method after writing each message (or related group of data) to the socket.

In Adobe AIR, Socket objects are also created when a listening ServerSocket receives a connection from an external process. The Socket representing the connection is dispatched in a ServerSocketConnectEvent. Your application is responsible for maintaining a reference to this Socket object. If you don't, the Socket object is eligible for garbage collection and may be destroyed by the runtime without warning.

SWF content running in the local-with-filesystem security sandbox cannot use sockets.

Socket policy files on the target host specify the hosts from which SWF files can make socket connections, and the ports to which those connections can be made. The security requirements with regard to socket policy files have become more stringent in the last several releases of Flash Player. In all versions of Flash Player, Adobe recommends the use of a socket policy file; in some circumstances, a socket policy file is required. Therefore, if you are using Socket objects, make sure that the target host provides a socket policy file if necessary.

The following list summarizes the requirements for socket policy files in different versions of Flash Player:

- In Flash Player 9.0.124.0 and later, a socket policy file is required for any socket connection. That is, a socket policy file on the target host is required no matter what port you are connecting to, and is required even if you are connecting to a port on the same host that is serving the SWF file.
- In Flash Player versions 9.0.115.0 and earlier, if you want to connect to a port number below 1024, or if you want to connect to a host other than the one serving the SWF file, a socket policy file on the target host is required.
- In Flash Player 9.0.115.0, even if a socket policy file isn't required, a warning is displayed when using the Flash Debug Player if the target host doesn't serve a socket policy file.
- In AIR, a socket policy file is not required for content running in the application security sandbox. Socket policy files are required for any socket connection established by content running outside the AIR application security sandbox.

For more information related to security, see the Flash Player Developer Center Topic: Security

View the examples

More examples

Binary client sockets
Connecting to sockets

Related API Elements

ServerSocket
DatagramSocket

Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties

| Property | Defined By
--- | --- | ---
|  | bytesAvailable : uint [read-only] The number of bytes of data available for reading in the input buffer. | Socket
|  | bytesPending : uint [read-only] Indicates the number of bytes remaining in the write buffer. | Socket
|  | connected : Boolean [read-only] Indicates whether this Socket object is currently connected. | Socket
|  | constructor : Object A reference to the class object or constructor function for a given object instance. | Object
|  | endian : String Indicates the byte order for the data. | Socket
|  | localAddress : String [read-only] The IP address this socket is bound to on the local machine. | Socket
|  | localPort : int [read-only] The port this socket is bound to on the local machine. | Socket
|  | objectEncoding : uint Controls the version of AMF used when writing or reading an object. | Socket
|  | remoteAddress : String [read-only] The IP address of the remote machine to which this socket is connected. | Socket
|  | remotePort : int [read-only] The port on the remote machine to which this socket is connected. | Socket
|  | timeout : uint Indicates the number of milliseconds to wait for a connection. | Socket

Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods

| Method | Defined By
--- | --- | ---
|  | Socket(host:String = null, port:int = 0) Creates a new Socket object. | Socket
|  | addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registers an event listener object with an EventDispatcher object so that the listener receives notification of an event. | EventDispatcher
|  | close():void Closes the socket. | Socket
|  | connect(host:String, port:int):void Connects the socket to the specified host and port. | Socket
|  | dispatchEvent(event:Event):Boolean Dispatches an event into the event flow. | EventDispatcher
|  | flush():void Flushes any accumulated data in the socket's output buffer. | Socket
|  | hasEventListener(type:String):Boolean Checks whether the EventDispatcher object has any listeners registered for a specific type of event. | EventDispatcher
|  | hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined. | Object
|  | isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter. | Object
|  | propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable. | Object
|  | readBoolean():Boolean Reads a Boolean value from the socket. | Socket
|  | readByte():int Reads a signed byte from the socket. | Socket
|  | readBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void Reads the number of data bytes specified by the length parameter from the socket. | Socket
|  | readDouble():Number Reads an IEEE 754 double-precision floating-point number from the socket. | Socket
|  | readFloat():Number Reads an IEEE 754 single-precision floating-point number from the socket. | Socket
|  | readInt():int Reads a signed 32-bit integer from the socket. | Socket
|  | readMultiByte(length:uint, charSet:String):String Reads a multibyte string from the byte stream, using the specified character set. | Socket
|  | readObject():* Reads an object from the socket, encoded in AMF serialized format. | Socket
|  | readShort():int Reads a signed 16-bit integer from the socket. | Socket
|  | readUnsignedByte():uint Reads an unsigned byte from the socket. | Socket
|  | readUnsignedInt():uint Reads an unsigned 32-bit integer from the socket. | Socket
|  | readUnsignedShort():uint Reads an unsigned 16-bit integer from the socket. | Socket
|  | readUTF():String Reads a UTF-8 string from the socket. | Socket
|  | readUTFBytes(length:uint):String Reads the number of UTF-8 data bytes specified by the length parameter from the socket, and returns a string. | Socket
|  | removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Removes a listener from the EventDispatcher object. | EventDispatcher
|  | setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations. | Object
|  | toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions. | Object
|  | toString():String Returns the string representation of the specified object. | Object
|  | valueOf():Object Returns the primitive value of the specified object. | Object
|  | willTrigger(type:String):Boolean Checks whether an event listener is registered with this EventDispatcher object or any of its ancestors for the specified event type. | EventDispatcher
|  | writeBoolean(value:Boolean):void Writes a Boolean value to the socket. | Socket
|  | writeByte(value:int):void Writes a byte to the socket. | Socket
|  | writeBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void Writes a sequence of bytes from the specified byte array. | Socket
|  | writeDouble(value:Number):void Writes an IEEE 754 double-precision floating-point number to the socket. | Socket
|  | writeFloat(value:Number):void Writes an IEEE 754 single-precision floating-point number to the socket. | Socket
|  | writeInt(value:int):void Writes a 32-bit signed integer to the socket. | Socket
|  | writeMultiByte(value:String, charSet:String):void Writes a multibyte string from the byte stream, using the specified character set. | Socket
|  | writeObject(object:*):void Write an object to the socket in AMF serialized format. | Socket
|  | writeShort(value:int):void Writes a 16-bit integer to the socket. | Socket
|  | writeUnsignedInt(value:uint):void Writes a 32-bit unsigned integer to the socket. | Socket
|  | writeUTF(value:String):void Writes the following data to the socket: a 16-bit unsigned integer, which indicates the length of the specified UTF-8 string in bytes, followed by the string itself. | Socket
|  | writeUTFBytes(value:String):void Writes a UTF-8 string to the socket. | Socket

Events
Click for more information on events
Hide Inherited Events
Show Inherited Events

| Event | Summary | Defined By
--- | --- | --- | ---
|  | activate | [broadcast event] Dispatched when the Flash Player or AIR application gains operating system focus and becomes active. | EventDispatcher
|  | close | Dispatched when the server closes the socket connection. | Socket
|  | connect | Dispatched when a network connection has been established. | Socket
|  | deactivate | [broadcast event] Dispatched when the Flash Player or AIR application operating loses system focus and is becoming inactive. | EventDispatcher
|  | ioError | Dispatched when an input/output error occurs that causes a send or load operation to fail. | Socket
|  | outputProgress | Dispatched when a socket moves data from its write buffer to the networking transport layer | Socket
|  | securityError | Dispatched if a call to Socket.connect() attempts to connect to a server prohibited by the caller's security sandbox or to a port lower than 1024 and no socket policy file exists to permit such a connection. | Socket
|  | socketData | Dispatched when a socket has received data. | Socket

Property Detail

### bytesAvailable

property

`bytesAvailable:uint` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

The number of bytes of data available for reading in the input buffer.

Your code must access `bytesAvailable` to ensure that sufficient data is available before trying to read it with one of the `read` methods.

Implementation
`public function get bytesAvailable():uint`

### bytesPending

property

`bytesPending:uint` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 11, AIR 3.0

Indicates the number of bytes remaining in the write buffer.

Use this property in combination with with the OutputProgressEvent. An OutputProgressEvent is thrown whenever data is written from the write buffer to the network. In the event handler, you can check `bytesPending` to see how much data is still left in the buffer waiting to be written. When `bytesPending` returns 0, it means that all the data has been transferred from the write buffer to the network, and it is safe to do things like remove event handlers, null out socket references,start the next upload in a queue, etc.

Implementation
`public function get bytesPending():uint`

Related API Elements

flash.events.OutputProgressEvent

### connected

property

`connected:Boolean` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Indicates whether this Socket object is currently connected. A call to this property returns a value of `true` if the socket is currently connected, or `false` otherwise.

Implementation
`public function get connected():Boolean`

### endian

property

`endian:String`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Indicates the byte order for the data. Possible values are constants from the flash.utils.Endian class, `Endian.BIG_ENDIAN` or `Endian.LITTLE_ENDIAN`.

The default value is `Endian.BIG_ENDIAN.`

Implementation
`public function get endian():String`
`public function set endian(value:String):void`

Related API Elements

flash.utils.Endian

### localAddress

property

`localAddress:String` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 2

The IP address this socket is bound to on the local machine.

Implementation
`public function get localAddress():String`

Related API Elements

ServerSocket.html#bind()

### localPort

property

`localPort:int` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 2

The port this socket is bound to on the local machine.

Implementation
`public function get localPort():int`

Related API Elements

ServerSocket.html#bind()

### objectEncoding

property

`objectEncoding:uint`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Controls the version of AMF used when writing or reading an object.

Implementation
`public function get objectEncoding():uint`
`public function set objectEncoding(value:uint):void`

Related API Elements

ObjectEncoding class
readObject()
writeObject()

### remoteAddress

property

`remoteAddress:String` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 2

The IP address of the remote machine to which this socket is connected.

You can use this property to determine the IP address of a client socket dispatched in a ServerSocketConnectEvent by a ServerSocket object. Use the DNSResolver class to convert an IP address to a domain name, if desired.

Implementation
`public function get remoteAddress():String`

Related API Elements

connect()
ServerSocket
ServerSocketConnectEvent
DNSResolver

### remotePort

property

`remotePort:int` [read-only]

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 2

The port on the remote machine to which this socket is connected.

You can use this property to determine the port number of a client socket dispatched in a ServerSocketConnectEvent by a ServerSocket object.

Implementation
`public function get remotePort():int`

Related API Elements

connect()
ServerSocket
ServerSocketConnectEvent

### timeout

property

`timeout:uint`

Language Version: | ActionScript 3.0

Runtime Versions: | Flash Player 10, AIR 1.5, Flash Lite 4

Indicates the number of milliseconds to wait for a connection.

If the connection doesn't succeed within the specified time, the connection fails. The default value is 20,000 (twenty seconds).

Implementation
`public function get timeout():uint`
`public function set timeout(value:uint):void`
Constructor Detail

### Socket

()
Constructor

`public function Socket(host:String = null, port:int = 0)`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Creates a new Socket object. If no parameters are specified, an initially disconnected socket is created. If parameters are specified, a connection is attempted to the specified host and port.

Note: It is strongly advised to use the constructor form without parameters, then add any event listeners, then call the `connect` method with `host` and `port` parameters. This sequence guarantees that all event listeners will work properly.

Parameters

| `host:String` (default = `null`)`` — A fully qualified DNS domain name or an IP address. IPv4 addresses are specified in dot-decimal notation, such as 192.0.2.0. In Flash Player 9.0.115.0 and AIR 1.0 and later, you can specify IPv6 addresses using hexadecimal-colon notation, such as 2001:db8:ccc3:ffff:0:444d:555e:666f. You can also specify `null` to connect to the host server on which the SWF file resides. If the SWF file issuing this call is running in a web browser, `host` must be in the domain from which the SWF file originated.
| `port:int` (default = `0`)`` — The TCP port number on the target host used to establish a connection. In Flash Player 9.0.124.0 and later, the target host must serve a socket policy file specifying that socket connections are permitted from the host serving the SWF file to the specified port. In earlier versions of Flash Player, a socket policy file is required only if you want to connect to a port number below 1024, or if you want to connect to a host other than the one serving the SWF file.

Events

| `connect:`Event`` — Dispatched when a network connection has been established.
| `ioError:`IOErrorEvent`` — Dispatched when an input/output error occurs that causes the connection to fail.
| `securityError:`SecurityErrorEvent`` — Dispatched if a call to `Socket.connect()` attempts to connect either to a server that doesn't serve a socket policy file, or to a server whose policy file doesn't grant the calling host access to the specified port. For more information on policy files, see "Website controls (policy files)" in the ActionScript 3.0 Developer's Guide and the Flash Player Developer Center Topic: Security.

Throws

| `SecurityError` — This error occurs in SWF content for the following reasons:

- Local-with-filesystem files cannot communicate with the Internet. You can work around this problem by reclassifying this SWF file as local-with-networking or trusted. This limitation is not set for AIR application content in the application security sandbox.
- You cannot specify a socket port higher than 65535.

Method Detail

### close

()
method

`public function close():void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Closes the socket. You cannot read or write any data after the `close()` method has been called.

The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `close()` method.

You can reuse the Socket object by calling the `connect()` method on it again.

Throws

| `IOError` — The socket could not be closed, or the socket was not open.

### connect

()
method

`public function connect(host:String, port:int):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Connects the socket to the specified host and port.

If the connection fails immediately, either an event is dispatched or an exception is thrown: an error event is dispatched if a host was specified, and an exception is thrown if no host was specified. Otherwise, the status of the connection is reported by an event. If the socket is already connected, the existing connection is closed first.

Parameters

| `host:String` — The name or IP address of the host to connect to. If no host is specified, the host that is contacted is the host where the calling file resides. If you do not specify a host, use an event listener to determine whether the connection was successful.
| `port:int` — The port number to connect to.

Events

| `connect:`Event`` — Dispatched when a network connection has been established.
| `ioError:`IOErrorEvent`` — Dispatched if a host is specified and an input/output error occurs that causes the connection to fail.
| `securityError:`SecurityErrorEvent`` — Dispatched if a call to `Socket.connect()` attempts to connect either to a server that doesn't serve a socket policy file, or to a server whose policy file doesn't grant the calling host access to the specified port. For more information on policy files, see "Website controls (policy files)" in the ActionScript 3.0 Developer's Guide and the Flash Player Developer Center Topic: Security.

Throws

| `IOError` — No host was specified and the connection failed.
| `SecurityError` — This error occurs in SWF content for the following reasons:

- Local untrusted SWF files may not communicate with the Internet. You can work around this limitation by reclassifying the file as local-with-networking or as trusted.
- You cannot specify a socket port higher than 65535.
- In the HTML page that contains the SWF content, the `allowNetworking` parameter of the `object` and `embed` tags is set to `"none"`.

More examples

Connecting to sockets

### flush

()
method

`public function flush():void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Flushes any accumulated data in the socket's output buffer.

On some operating systems, flush() is called automatically between execution frames, but on other operating systems, such as Windows, the data is never sent unless you call `flush()` explicitly. To ensure your application behaves reliably across all operating systems, it is a good practice to call the `flush()` method after writing each message (or related group of data) to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readBoolean

()
method

`public function readBoolean():Boolean`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a Boolean value from the socket. After reading a single byte, the method returns `true` if the byte is nonzero, and `false` otherwise.

Returns

| `Boolean` — A value of `true` if the byte read is nonzero, otherwise `false`.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readByte

()
method

`public function readByte():int`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a signed byte from the socket.

Returns

| `int` — A value from -128 to 127.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readBytes

()
method

`public function readBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads the number of data bytes specified by the length parameter from the socket. The bytes are read into the specified byte array, starting at the position indicated by `offset`.

Parameters

| `bytes:ByteArray` — The ByteArray object to read data into.
| `offset:uint` (default = `0`)`` — The offset at which data reading should begin in the byte array.
| `length:uint` (default = `0`)`` — The number of bytes to read. The default value of 0 causes all available data to be read.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readDouble

()
method

`public function readDouble():Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an IEEE 754 double-precision floating-point number from the socket.

Returns

| `Number` — An IEEE 754 double-precision floating-point number.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readFloat

()
method

`public function readFloat():Number`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an IEEE 754 single-precision floating-point number from the socket.

Returns

| `Number` — An IEEE 754 single-precision floating-point number.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readInt

()
method

`public function readInt():int`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a signed 32-bit integer from the socket.

Returns

| `int` — A value from -2147483648 to 2147483647.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readMultiByte

()
method

`public function readMultiByte(length:uint, charSet:String):String`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a multibyte string from the byte stream, using the specified character set.

Parameters

| `length:uint` — The number of bytes from the byte stream to read.
| `charSet:String` — The string denoting the character set to use to interpret the bytes. Possible character set strings include `"shift_jis"`, `"CN-GB"`, and `"iso-8859-1"`. For a complete list, see Supported Character Sets. Note: If the value for the `charSet` parameter is not recognized by the current system, then the application uses the system's default code page as the character set. For example, a value for the `charSet` parameter, as in `myTest.readMultiByte(22, "iso-8859-01")` that uses `01` instead of `1` might work on your development machine, but not on another machine. On the other machine, the application will use the system's default code page.

Returns

| `String` — A UTF-8 encoded string.

Throws

| `EOFError` — There is insufficient data available to read.

### readObject

()
method

`public function readObject():*`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an object from the socket, encoded in AMF serialized format.

Returns

| `*` — The deserialized object

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

ObjectEncoding
flash.net.registerClassAlias()

### readShort

()
method

`public function readShort():int`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a signed 16-bit integer from the socket.

Returns

| `int` — A value from -32768 to 32767.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readUnsignedByte

()
method

`public function readUnsignedByte():uint`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an unsigned byte from the socket.

Returns

| `uint` — A value from 0 to 255.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readUnsignedInt

()
method

`public function readUnsignedInt():uint`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an unsigned 32-bit integer from the socket.

Returns

| `uint` — A value from 0 to 4294967295.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readUnsignedShort

()
method

`public function readUnsignedShort():uint`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads an unsigned 16-bit integer from the socket.

Returns

| `uint` — A value from 0 to 65535.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readUTF

()
method

`public function readUTF():String`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads a UTF-8 string from the socket. The string is assumed to be prefixed with an unsigned short integer that indicates the length in bytes.

Returns

| `String` — A UTF-8 string.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### readUTFBytes

()
method

`public function readUTFBytes(length:uint):String`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Reads the number of UTF-8 data bytes specified by the `length` parameter from the socket, and returns a string.

Parameters

| `length:uint` — The number of bytes to read.

Returns

| `String` — A UTF-8 string.

Throws

| `EOFError` — There is insufficient data available to read.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

### writeBoolean

()
method

`public function writeBoolean(value:Boolean):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a Boolean value to the socket. This method writes a single byte, with either a value of 1 (`true`) or 0 (`false`).

Parameters

| `value:Boolean` — The value to write to the socket: 1 (`true`) or 0 (`false`).

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeByte

()
method

`public function writeByte(value:int):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a byte to the socket.

Parameters

| `value:int` — The value to write to the socket. The low 8 bits of the value are used; the high 24 bits are ignored.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeBytes

()
method

`public function writeBytes(bytes:ByteArray, offset:uint = 0, length:uint = 0):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a sequence of bytes from the specified byte array. The write operation starts at the position specified by `offset`.

If you omit the `length` parameter the default length of 0 causes the method to write the entire buffer starting at `offset`.

If you also omit the `offset` parameter, the entire buffer is written.

Parameters

| `bytes:ByteArray` — The ByteArray object to write data from.
| `offset:uint` (default = `0`)`` — The zero-based offset into the `bytes` ByteArray object at which data writing should begin.
| `length:uint` (default = `0`)`` — The number of bytes to write. The default value of 0 causes the entire buffer to be written, starting at the value specified by the `offset` parameter.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.
| `RangeError` — If `offset` is greater than the length of the ByteArray specified in `bytes` or if the amount of data specified to be written by `offset` plus `length` exceeds the data available.

Related API Elements

flush()

### writeDouble

()
method

`public function writeDouble(value:Number):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes an IEEE 754 double-precision floating-point number to the socket.

Parameters

| `value:Number` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeFloat

()
method

`public function writeFloat(value:Number):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes an IEEE 754 single-precision floating-point number to the socket.

Parameters

| `value:Number` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeInt

()
method

`public function writeInt(value:int):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a 32-bit signed integer to the socket.

Parameters

| `value:int` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeMultiByte

()
method

`public function writeMultiByte(value:String, charSet:String):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a multibyte string from the byte stream, using the specified character set.

Parameters

| `value:String` — The string value to be written.
| `charSet:String` — The string denoting the character set to use to interpret the bytes. Possible character set strings include `"shift_jis"`, `"CN-GB"`, and `"iso-8859-1"`. For a complete list, see Supported Character Sets.

Related API Elements

flush()

### writeObject

()
method

`public function writeObject(object:*):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Write an object to the socket in AMF serialized format.

Parameters

| `object:*` — The object to be serialized.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()
ObjectEncoding
flash.net.registerClassAlias()

### writeShort

()
method

`public function writeShort(value:int):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a 16-bit integer to the socket. The bytes written are as follows:

    (v >> 8) & 0xff v & 0xff

The low 16 bits of the parameter are used; the high 16 bits are ignored.

Parameters

| `value:int` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeUnsignedInt

()
method

`public function writeUnsignedInt(value:uint):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a 32-bit unsigned integer to the socket.

Parameters

| `value:uint` — The value to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeUTF

()
method

`public function writeUTF(value:String):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes the following data to the socket: a 16-bit unsigned integer, which indicates the length of the specified UTF-8 string in bytes, followed by the string itself.

Before writing the string, the method calculates the number of bytes that are needed to represent all characters of the string.

Parameters

| `value:String` — The string to write to the socket.

Throws

| `RangeError` — The length is larger than 65535.
| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()

### writeUTFBytes

()
method

`public function writeUTFBytes(value:String):void`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Writes a UTF-8 string to the socket.

Parameters

| `value:String` — The string to write to the socket.

Throws

| `IOError` — An I/O error occurred on the socket, or the socket is not open.

Related API Elements

flush()
Event Detail

### close

Event

Event Object Type: `flash.events.Event`
property Event.type = `flash.events.Event.CLOSE`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when the server closes the socket connection.

The `close` event is dispatched only when the server closes the connection; it is not dispatched when you call the `Socket.close()` method.

The `Event.CLOSE` constant defines the value of the `type` property of a `close` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The object whose connection has been closed.

### connect

Event

Event Object Type: `flash.events.Event`
property Event.type = `flash.events.Event.CONNECT`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when a network connection has been established.

The `Event.CONNECT` constant defines the value of the `type` property of a `connect` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The Socket or XMLSocket object that has established a network connection.

### ioError

Event

Event Object Type: `flash.events.IOErrorEvent`
property IOErrorEvent.type = `flash.events.IOErrorEvent.IO_ERROR`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when an input/output error occurs that causes a send or load operation to fail.

Defines the value of the `type` property of an `ioError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`errorID` | A reference number associated with the specific error (AIR only).
`target` | The network object experiencing the input/output error.
`text` | Text to be displayed as an error message.

### outputProgress

Event

Event Object Type: `flash.events.OutputProgressEvent`

Dispatched when a socket moves data from its write buffer to the networking transport layer

### securityError

Event

Event Object Type: `flash.events.SecurityErrorEvent`
property SecurityErrorEvent.type = `flash.events.SecurityErrorEvent.SECURITY_ERROR`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched if a call to `Socket.connect()` attempts to connect to a server prohibited by the caller's security sandbox or to a port lower than 1024 and no socket policy file exists to permit such a connection.

Note: In an AIR application, content running in the application security sandbox is permitted to connect to any server and port number without a socket policy file.

The `SecurityErrorEvent.SECURITY_ERROR` constant defines the value of the `type` property of a `securityError` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event object with an event listener.
`target` | The network object reporting the security error.
`text` | Text to be displayed as an error message.

Related API Elements

Socket.connect()

### socketData

Event

Event Object Type: `flash.events.ProgressEvent`
property ProgressEvent.type = `flash.events.ProgressEvent.SOCKET_DATA`

Language Version: | ActionScript 3.0

Runtime Versions: | AIR 1.0, Flash Player 9, Flash Lite 4

Dispatched when a socket has received data.

The data received by the socket remains in the socket until it is read. You do not have to read all the available data during the handler for this event.

Events of type `socketData` do not use the `ProgressEvent.bytesTotal` property.

Defines the value of the `type` property of a `socketData` event object.

This event has the following properties:

Property | Value
--- | ---
`bubbles` | `false`
`cancelable` | `false`; there is no default behavior to cancel.
`currentTarget` | The object that is actively processing the Event.
`bytesLoaded` | The number of items or bytes loaded at the time the listener processes the event.
`bytesTotal` | 0; this property is not used by `socketData` event objects.
`target` | The socket reporting progress.

Examples How to use this example
SocketExample.as
The following example reads from and writes to a socket and outputs information transmitted during socket events. Highlights of the example follow:

1. The constructor creates a `CustomSocket` instance named `socket` and passes the host name `localhost` and port 80 as arguments. Since `CustomSocket` extends Socket, a call to `super()` calls Socket's constructor.
2. The example then calls the `configureListeners()` method, which adds listeners for Socket events.
3. Finally, the socket `connect()` method is called with `localhost` as the host name and 80 as the port number.

Note: To run the example, you need a server running on the same domain where the SWF resides (in the example, `localhost`) and listening on port 80.

Copy

    package {
        import flash.display.Sprite;

        public class SocketExample extends Sprite {
            private var socket:CustomSocket;

            public function SocketExample() {
                socket = new CustomSocket("localhost", 80);
            }
        }
    }

    import flash.errors.*;
    import flash.events.*;
    import flash.net.Socket;

    class CustomSocket extends Socket {
        private var response:String;

        public function CustomSocket(host:String = null, port:uint = 0) {
            super();
            configureListeners();
            if (host && port)  {
                super.connect(host, port);
            }
        }

        private function configureListeners():void {
            addEventListener(Event.CLOSE, closeHandler);
            addEventListener(Event.CONNECT, connectHandler);
            addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
        }

        private function writeln(str:String):void {
            str += "\n";
            try {
                writeUTFBytes(str);
            }
            catch(e:IOError) {
                trace(e);
            }
        }

        private function sendRequest():void {
            trace("sendRequest");
            response = "";
            writeln("GET /");
            flush();
        }

        private function readResponse():void {
            var str:String = readUTFBytes(bytesAvailable);
            response += str;
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
            trace(response.toString());
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
            sendRequest();
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function socketDataHandler(event:ProgressEvent):void {
            trace("socketDataHandler: " + event);
            readResponse();
        }
    }

© 2015 Adobe Systems Incorporated. All rights reserved.
Mon Apr 10 2017, 12:28 PM -07:00