build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.2'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'jacoco'
}

group = 'softeer'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

jacoco {
    toolVersion = "0.8.8"
}

jacocoTestReport {
    dependsOn test // test 작업 후 jacocoTestReport 실행
    reports {
        xml.required.set(false)
        csv.required.set(false)
        html.required.set(true)
    }
    classDirectories.setFrom(files(sourceSets.main.output.classesDirs.asFileTree.matching {
        exclude '**/config/**'
        exclude '**/response/**'
        exclude '**/request/**'
        exclude '**/domain/**/domain/**'
        exclude '**/softeer/team_pineapple_be/*.class'
        exclude '**/enum/**'
        exclude '**/global/**/domain/**'
        exclude '**/softeer/team_pineapple_be/global/**/exception'
        exclude '**/softeer/team_pineapple_be/global/cloud/**'
        exclude '**/softeer/team_pineapple_be/domain/draw/service/DrawService$ImageUrls*'
        exclude '**/softeer/team_pineapple_be/global/auth/interceptor/**'
        exclude '**/softeer/team_pineapple_be/global/message/**'
        exclude '**/softeer/team_pineapple_be/domain/admin/controller/**'
    }))
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-cache'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    //retry
    implementation 'org.springframework.retry:spring-retry'
    implementation 'org.springframework:spring-aspects'

    //redisson
    implementation 'org.redisson:redisson-spring-boot-starter:3.18.0'

    //swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.2.0'

    //jwt
    implementation 'io.jsonwebtoken:jjwt-api:0.12.3'
    implementation 'io.jsonwebtoken:jjwt-impl:0.12.3'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.12.3'

    //redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    //cloud
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'
    implementation 'com.amazonaws:aws-java-sdk-s3:1.12.503'

    //cool sms
    implementation 'net.nurigo:sdk:4.3.0'

    //QueryDsl
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    //caffeine
    implementation 'com.github.ben-manes.caffeine:caffeine:3.1.1'
}

tasks.named('test') {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

clean {
    delete file('src/main/generated')
}