-
Notifications
You must be signed in to change notification settings - Fork 160
/
Copy pathComet.sol
1358 lines (1163 loc) · 52.5 KB
/
Comet.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.13;
import "./CometMainInterface.sol";
import "./ERC20.sol";
import "./vendor/@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
/**
* @title Compound's Comet Contract
* @notice An efficient monolithic money market protocol
* @author Compound
*/
contract Comet is CometMainInterface {
/** Custom errors **/
error Absurd();
error AlreadyInitialized();
error BadAsset();
error BadDecimals();
error BadDiscount();
error BadKink();
error BadMinimum();
error BadPrice();
error BadReserveRate();
error BorrowTooSmall();
error BorrowCFTooLarge();
error InsufficientReserves();
error LiquidateCFTooLarge();
error NoSelfTransfer();
error NotCollateralized();
error NotForSale();
error NotLiquidatable();
error Paused();
error SupplyCapExceeded();
error TimestampTooLarge();
error TooManyAssets();
error TooMuchSlippage();
error TransferInFailed();
error TransferOutFailed();
error Unauthorized();
/** General configuration constants **/
/// @notice The admin of the protocol
address public override immutable governor;
/// @notice The account which may trigger pauses
address public override immutable pauseGuardian;
/// @notice The address of the base token contract
address public override immutable baseToken;
/// @notice The address of the price feed for the base token
address public override immutable baseTokenPriceFeed;
/// @notice The address of the extension contract delegate
address public override immutable extensionDelegate;
/// @notice The point in the supply and borrow rates separating the low interest rate slope and the high interest rate slope (factor)
/// @dev uint64
uint public override immutable kink;
/// @notice Per second interest rate slope applied when utilization is below kink (factor)
/// @dev uint64
uint public override immutable perSecondInterestRateSlopeLow;
/// @notice Per second interest rate slope applied when utilization is above kink (factor)
/// @dev uint64
uint public override immutable perSecondInterestRateSlopeHigh;
/// @notice Per second base interest rate (factor)
/// @dev uint64
uint public override immutable perSecondInterestRateBase;
/// @notice The rate of total interest paid that goes into reserves (factor)
/// @dev uint64
uint public override immutable reserveRate;
/// @notice The fraction of the liquidation penalty that goes to buyers of collateral instead of the protocol
/// @dev uint64
uint public override immutable storeFrontPriceFactor;
/// @notice The scale for base token (must be less than 18 decimals)
/// @dev uint64
uint public override immutable baseScale;
/// @notice The scale for reward tracking
/// @dev uint64
uint public override immutable trackingIndexScale;
/// @notice The speed at which supply rewards are tracked (in trackingIndexScale)
/// @dev uint64
uint public override immutable baseTrackingSupplySpeed;
/// @notice The speed at which borrow rewards are tracked (in trackingIndexScale)
/// @dev uint64
uint public override immutable baseTrackingBorrowSpeed;
/// @notice The minimum amount of base wei for rewards to accrue
/// @dev This must be large enough so as to prevent division by base wei from overflowing the 64 bit indices
/// @dev uint104
uint public override immutable baseMinForRewards;
/// @notice The minimum base amount required to initiate a borrow
/// @dev uint104
uint public override immutable baseBorrowMin;
/// @notice The minimum base token reserves which must be held before collateral is hodled
/// @dev uint104
uint public override immutable targetReserves;
/// @notice The number of decimals for wrapped base token
uint8 public override immutable decimals;
/// @notice The number of assets this contract actually supports
uint8 public override immutable numAssets;
/// @notice Factor to divide by when accruing rewards in order to preserve 6 decimals (i.e. baseScale / 1e6)
uint internal immutable accrualDescaleFactor;
/** Collateral asset configuration (packed) **/
uint256 internal immutable asset00_a;
uint256 internal immutable asset00_b;
uint256 internal immutable asset01_a;
uint256 internal immutable asset01_b;
uint256 internal immutable asset02_a;
uint256 internal immutable asset02_b;
uint256 internal immutable asset03_a;
uint256 internal immutable asset03_b;
uint256 internal immutable asset04_a;
uint256 internal immutable asset04_b;
uint256 internal immutable asset05_a;
uint256 internal immutable asset05_b;
uint256 internal immutable asset06_a;
uint256 internal immutable asset06_b;
uint256 internal immutable asset07_a;
uint256 internal immutable asset07_b;
uint256 internal immutable asset08_a;
uint256 internal immutable asset08_b;
uint256 internal immutable asset09_a;
uint256 internal immutable asset09_b;
uint256 internal immutable asset10_a;
uint256 internal immutable asset10_b;
uint256 internal immutable asset11_a;
uint256 internal immutable asset11_b;
uint256 internal immutable asset12_a;
uint256 internal immutable asset12_b;
uint256 internal immutable asset13_a;
uint256 internal immutable asset13_b;
uint256 internal immutable asset14_a;
uint256 internal immutable asset14_b;
/**
* @notice Construct a new protocol instance
* @param config The mapping of initial/constant parameters
**/
constructor(Configuration memory config) {
// Sanity checks
uint8 decimals_ = ERC20(config.baseToken).decimals();
if (decimals_ > MAX_BASE_DECIMALS) revert BadDecimals();
if (config.storeFrontPriceFactor > FACTOR_SCALE) revert BadDiscount();
if (config.assetConfigs.length > MAX_ASSETS) revert TooManyAssets();
if (config.baseMinForRewards == 0) revert BadMinimum();
if (AggregatorV3Interface(config.baseTokenPriceFeed).decimals() != PRICE_FEED_DECIMALS) revert BadDecimals();
if (config.reserveRate > FACTOR_SCALE) revert BadReserveRate();
if (config.kink > FACTOR_SCALE) revert BadKink();
// Copy configuration
unchecked {
governor = config.governor;
pauseGuardian = config.pauseGuardian;
baseToken = config.baseToken;
baseTokenPriceFeed = config.baseTokenPriceFeed;
extensionDelegate = config.extensionDelegate;
storeFrontPriceFactor = config.storeFrontPriceFactor;
decimals = decimals_;
baseScale = uint64(10 ** decimals_);
trackingIndexScale = config.trackingIndexScale;
if (baseScale < BASE_ACCRUAL_SCALE) revert BadDecimals();
accrualDescaleFactor = baseScale / BASE_ACCRUAL_SCALE;
baseMinForRewards = config.baseMinForRewards;
baseTrackingSupplySpeed = config.baseTrackingSupplySpeed;
baseTrackingBorrowSpeed = config.baseTrackingBorrowSpeed;
baseBorrowMin = config.baseBorrowMin;
targetReserves = config.targetReserves;
}
// Set interest rate model configs
unchecked {
kink = config.kink;
perSecondInterestRateSlopeLow = config.perYearInterestRateSlopeLow / SECONDS_PER_YEAR;
perSecondInterestRateSlopeHigh = config.perYearInterestRateSlopeHigh / SECONDS_PER_YEAR;
perSecondInterestRateBase = config.perYearInterestRateBase / SECONDS_PER_YEAR;
reserveRate = config.reserveRate;
}
// Set asset info
numAssets = uint8(config.assetConfigs.length);
(asset00_a, asset00_b) = _getPackedAsset(config.assetConfigs, 0);
(asset01_a, asset01_b) = _getPackedAsset(config.assetConfigs, 1);
(asset02_a, asset02_b) = _getPackedAsset(config.assetConfigs, 2);
(asset03_a, asset03_b) = _getPackedAsset(config.assetConfigs, 3);
(asset04_a, asset04_b) = _getPackedAsset(config.assetConfigs, 4);
(asset05_a, asset05_b) = _getPackedAsset(config.assetConfigs, 5);
(asset06_a, asset06_b) = _getPackedAsset(config.assetConfigs, 6);
(asset07_a, asset07_b) = _getPackedAsset(config.assetConfigs, 7);
(asset08_a, asset08_b) = _getPackedAsset(config.assetConfigs, 8);
(asset09_a, asset09_b) = _getPackedAsset(config.assetConfigs, 9);
(asset10_a, asset10_b) = _getPackedAsset(config.assetConfigs, 10);
(asset11_a, asset11_b) = _getPackedAsset(config.assetConfigs, 11);
(asset12_a, asset12_b) = _getPackedAsset(config.assetConfigs, 12);
(asset13_a, asset13_b) = _getPackedAsset(config.assetConfigs, 13);
(asset14_a, asset14_b) = _getPackedAsset(config.assetConfigs, 14);
}
/**
* @notice Initialize storage for the contract
* @dev Can be used from constructor or proxy
*/
function initializeStorage() override external {
if (lastAccrualTime != 0) revert AlreadyInitialized();
// Initialize aggregates
lastAccrualTime = getNowInternal();
baseSupplyIndex = BASE_INDEX_SCALE;
baseBorrowIndex = BASE_INDEX_SCALE;
// Implicit initialization (not worth increasing contract size)
// trackingSupplyIndex = 0;
// trackingBorrowIndex = 0;
}
/**
* @dev Checks and gets the packed asset info for storage
*/
function _getPackedAsset(AssetConfig[] memory assetConfigs, uint i) internal view returns (uint256, uint256) {
AssetConfig memory assetConfig;
if (i < assetConfigs.length) {
assembly {
assetConfig := mload(add(add(assetConfigs, 0x20), mul(i, 0x20)))
}
} else {
return (0, 0);
}
address asset = assetConfig.asset;
address priceFeed = assetConfig.priceFeed;
uint8 decimals_ = assetConfig.decimals;
// Short-circuit if asset is nil
if (asset == address(0)) {
return (0, 0);
}
// Sanity check price feed and asset decimals
if (AggregatorV3Interface(priceFeed).decimals() != PRICE_FEED_DECIMALS) revert BadDecimals();
if (ERC20(asset).decimals() != decimals_) revert BadDecimals();
// Ensure collateral factors are within range
if (assetConfig.borrowCollateralFactor >= assetConfig.liquidateCollateralFactor) revert BorrowCFTooLarge();
if (assetConfig.liquidateCollateralFactor > MAX_COLLATERAL_FACTOR) revert LiquidateCFTooLarge();
unchecked {
// Keep 4 decimals for each factor
uint descale = FACTOR_SCALE / 1e4;
uint16 borrowCollateralFactor = uint16(assetConfig.borrowCollateralFactor / descale);
uint16 liquidateCollateralFactor = uint16(assetConfig.liquidateCollateralFactor / descale);
uint16 liquidationFactor = uint16(assetConfig.liquidationFactor / descale);
// Be nice and check descaled values are still within range
if (borrowCollateralFactor >= liquidateCollateralFactor) revert BorrowCFTooLarge();
// Keep whole units of asset for supply cap
uint64 supplyCap = uint64(assetConfig.supplyCap / (10 ** decimals_));
uint256 word_a = (uint160(asset) << 0 |
uint256(borrowCollateralFactor) << 160 |
uint256(liquidateCollateralFactor) << 176 |
uint256(liquidationFactor) << 192);
uint256 word_b = (uint160(priceFeed) << 0 |
uint256(decimals_) << 160 |
uint256(supplyCap) << 168);
return (word_a, word_b);
}
}
/**
* @notice Get the i-th asset info, according to the order they were passed in originally
* @param i The index of the asset info to get
* @return The asset info object
*/
function getAssetInfo(uint8 i) override public view returns (AssetInfo memory) {
if (i >= numAssets) revert BadAsset();
uint256 word_a;
uint256 word_b;
if (i == 0) {
word_a = asset00_a;
word_b = asset00_b;
} else if (i == 1) {
word_a = asset01_a;
word_b = asset01_b;
} else if (i == 2) {
word_a = asset02_a;
word_b = asset02_b;
} else if (i == 3) {
word_a = asset03_a;
word_b = asset03_b;
} else if (i == 4) {
word_a = asset04_a;
word_b = asset04_b;
} else if (i == 5) {
word_a = asset05_a;
word_b = asset05_b;
} else if (i == 6) {
word_a = asset06_a;
word_b = asset06_b;
} else if (i == 7) {
word_a = asset07_a;
word_b = asset07_b;
} else if (i == 8) {
word_a = asset08_a;
word_b = asset08_b;
} else if (i == 9) {
word_a = asset09_a;
word_b = asset09_b;
} else if (i == 10) {
word_a = asset10_a;
word_b = asset10_b;
} else if (i == 11) {
word_a = asset11_a;
word_b = asset11_b;
} else if (i == 12) {
word_a = asset12_a;
word_b = asset12_b;
} else if (i == 13) {
word_a = asset13_a;
word_b = asset13_b;
} else if (i == 14) {
word_a = asset14_a;
word_b = asset14_b;
} else {
revert Absurd();
}
address asset = address(uint160(word_a & type(uint160).max));
uint rescale = FACTOR_SCALE / 1e4;
uint64 borrowCollateralFactor = uint64(((word_a >> 160) & type(uint16).max) * rescale);
uint64 liquidateCollateralFactor = uint64(((word_a >> 176) & type(uint16).max) * rescale);
uint64 liquidationFactor = uint64(((word_a >> 192) & type(uint16).max) * rescale);
address priceFeed = address(uint160(word_b & type(uint160).max));
uint8 decimals_ = uint8(((word_b >> 160) & type(uint8).max));
uint64 scale = uint64(10 ** decimals_);
uint128 supplyCap = uint128(((word_b >> 168) & type(uint64).max) * scale);
return AssetInfo({
offset: i,
asset: asset,
priceFeed: priceFeed,
scale: scale,
borrowCollateralFactor: borrowCollateralFactor,
liquidateCollateralFactor: liquidateCollateralFactor,
liquidationFactor: liquidationFactor,
supplyCap: supplyCap
});
}
/**
* @dev Determine index of asset that matches given address
*/
function getAssetInfoByAddress(address asset) override public view returns (AssetInfo memory) {
for (uint8 i = 0; i < numAssets; i++) {
AssetInfo memory assetInfo = getAssetInfo(i);
if (assetInfo.asset == asset) {
return assetInfo;
}
}
revert BadAsset();
}
/**
* @return The current timestamp
**/
function getNowInternal() virtual internal view returns (uint40) {
if (block.timestamp >= 2**40) revert TimestampTooLarge();
return uint40(block.timestamp);
}
/**
* @dev Calculate accrued interest indices for base token supply and borrows
**/
function accruedInterestIndices(uint timeElapsed) internal view returns (uint64, uint64) {
uint64 baseSupplyIndex_ = baseSupplyIndex;
uint64 baseBorrowIndex_ = baseBorrowIndex;
if (timeElapsed > 0) {
uint supplyRate = getSupplyRate();
uint borrowRate = getBorrowRate();
baseSupplyIndex_ += safe64(mulFactor(baseSupplyIndex_, supplyRate * timeElapsed));
baseBorrowIndex_ += safe64(mulFactor(baseBorrowIndex_, borrowRate * timeElapsed));
}
return (baseSupplyIndex_, baseBorrowIndex_);
}
/**
* @dev Accrue interest (and rewards) in base token supply and borrows
**/
function accrueInternal() internal {
uint40 now_ = getNowInternal();
uint timeElapsed = now_ - lastAccrualTime;
if (timeElapsed > 0) {
(baseSupplyIndex, baseBorrowIndex) = accruedInterestIndices(timeElapsed);
if (totalSupplyBase >= baseMinForRewards) {
uint supplySpeed = baseTrackingSupplySpeed;
trackingSupplyIndex += safe64(divBaseWei(supplySpeed * timeElapsed, totalSupplyBase));
}
if (totalBorrowBase >= baseMinForRewards) {
uint borrowSpeed = baseTrackingBorrowSpeed;
trackingBorrowIndex += safe64(divBaseWei(borrowSpeed * timeElapsed, totalBorrowBase));
}
lastAccrualTime = now_;
}
}
/**
* @notice Accrue interest and rewards for an account
**/
function accrueAccount(address account) override external {
accrueInternal();
UserBasic memory basic = userBasic[account];
updateBasePrincipal(account, basic, basic.principal);
}
/**
* @dev Note: Does not accrue interest first
* @return The current per second supply rate
*/
function getSupplyRate() override public view returns (uint64) {
uint utilization = getUtilization();
uint reserveScalingFactor = utilization * (FACTOR_SCALE - reserveRate) / FACTOR_SCALE;
if (utilization <= kink) {
// (interestRateBase + interestRateSlopeLow * utilization) * utilization * (1 - reserveRate)
return safe64(mulFactor(reserveScalingFactor, (perSecondInterestRateBase + mulFactor(perSecondInterestRateSlopeLow, utilization))));
} else {
// (interestRateBase + interestRateSlopeLow * kink + interestRateSlopeHigh * (utilization - kink)) * utilization * (1 - reserveRate)
return safe64(mulFactor(reserveScalingFactor, (perSecondInterestRateBase + mulFactor(perSecondInterestRateSlopeLow, kink) + mulFactor(perSecondInterestRateSlopeHigh, (utilization - kink)))));
}
}
/**
* @dev Note: Does not accrue interest first
* @return The current per second borrow rate
*/
function getBorrowRate() override public view returns (uint64) {
uint utilization = getUtilization();
if (utilization <= kink) {
// interestRateBase + interestRateSlopeLow * utilization
return safe64(perSecondInterestRateBase + mulFactor(perSecondInterestRateSlopeLow, utilization));
} else {
// interestRateBase + interestRateSlopeLow * kink + interestRateSlopeHigh * (utilization - kink)
return safe64(perSecondInterestRateBase + mulFactor(perSecondInterestRateSlopeLow, kink) + mulFactor(perSecondInterestRateSlopeHigh, (utilization - kink)));
}
}
/**
* @dev Note: Does not accrue interest first
* @return The utilization rate of the base asset
*/
function getUtilization() override public view returns (uint) {
uint totalSupply = presentValueSupply(baseSupplyIndex, totalSupplyBase);
uint totalBorrow = presentValueBorrow(baseBorrowIndex, totalBorrowBase);
if (totalSupply == 0) {
return 0;
} else {
return totalBorrow * FACTOR_SCALE / totalSupply;
}
}
/**
* @notice Get the current price from a feed
* @param priceFeed The address of a price feed
* @return The price, scaled by `PRICE_SCALE`
*/
function getPrice(address priceFeed) override public view returns (uint128) {
(, int price, , , ) = AggregatorV3Interface(priceFeed).latestRoundData();
if (price <= 0 || price > type(int128).max) revert BadPrice();
return uint128(int128(price));
}
/**
* @notice Gets the total amount of protocol reserves, denominated in the number of base tokens
*/
function getReserves() override public view returns (int) {
(uint64 baseSupplyIndex_, uint64 baseBorrowIndex_) = accruedInterestIndices(getNowInternal() - lastAccrualTime);
uint balance = ERC20(baseToken).balanceOf(address(this));
uint104 totalSupply = presentValueSupply(baseSupplyIndex_, totalSupplyBase);
uint104 totalBorrow = presentValueBorrow(baseBorrowIndex_, totalBorrowBase);
return signed256(balance) - signed104(totalSupply) + signed104(totalBorrow);
}
/**
* @notice Check whether an account has enough collateral to borrow
* @param account The address to check
* @return Whether the account is minimally collateralized enough to borrow
*/
function isBorrowCollateralized(address account) override public view returns (bool) {
int104 principal = userBasic[account].principal;
if (principal >= 0) {
return true;
}
uint16 assetsIn = userBasic[account].assetsIn;
int liquidity = signedMulPrice(
presentValue(principal),
getPrice(baseTokenPriceFeed),
uint64(baseScale)
);
for (uint8 i = 0; i < numAssets; i++) {
if (isInAsset(assetsIn, i)) {
if (liquidity >= 0) {
return true;
}
AssetInfo memory asset = getAssetInfo(i);
uint newAmount = mulPrice(
userCollateral[account][asset.asset].balance,
getPrice(asset.priceFeed),
asset.scale
);
liquidity += signed256(mulFactor(
newAmount,
asset.borrowCollateralFactor
));
}
}
return liquidity >= 0;
}
/**
* @notice Calculate the amount of borrow liquidity for account
* @param account The address to check liquidity for
* @return The common price quantity of borrow liquidity
*/
function getBorrowLiquidity(address account) override external view returns (int) {
uint16 assetsIn = userBasic[account].assetsIn;
int liquidity = signedMulPrice(
presentValue(userBasic[account].principal),
getPrice(baseTokenPriceFeed),
uint64(baseScale)
);
for (uint8 i = 0; i < numAssets; i++) {
if (isInAsset(assetsIn, i)) {
AssetInfo memory asset = getAssetInfo(i);
uint newAmount = mulPrice(
userCollateral[account][asset.asset].balance,
getPrice(asset.priceFeed),
asset.scale
);
liquidity += signed256(mulFactor(
newAmount,
asset.borrowCollateralFactor
));
}
}
return liquidity;
}
/**
* @notice Check whether an account has enough collateral to not be liquidated
* @param account The address to check
* @return Whether the account is minimally collateralized enough to not be liquidated
*/
function isLiquidatable(address account) override public view returns (bool) {
int104 principal = userBasic[account].principal;
if (principal >= 0) {
return false;
}
uint16 assetsIn = userBasic[account].assetsIn;
int liquidity = signedMulPrice(
presentValue(principal),
getPrice(baseTokenPriceFeed),
uint64(baseScale)
);
for (uint8 i = 0; i < numAssets; i++) {
if (isInAsset(assetsIn, i)) {
if (liquidity >= 0) {
return false;
}
AssetInfo memory asset = getAssetInfo(i);
uint newAmount = mulPrice(
userCollateral[account][asset.asset].balance,
getPrice(asset.priceFeed),
asset.scale
);
liquidity += signed256(mulFactor(
newAmount,
asset.liquidateCollateralFactor
));
}
}
return liquidity < 0;
}
/**
* @notice Calculate the amount of liquidation margin for account
* @param account The address to check margin for
* @return The common price quantity of liquidation margin
*/
function getLiquidationMargin(address account) override external view returns (int) {
uint16 assetsIn = userBasic[account].assetsIn;
int liquidity = signedMulPrice(
presentValue(userBasic[account].principal),
getPrice(baseTokenPriceFeed),
uint64(baseScale)
);
for (uint8 i = 0; i < numAssets; i++) {
if (isInAsset(assetsIn, i)) {
AssetInfo memory asset = getAssetInfo(i);
uint newAmount = mulPrice(
userCollateral[account][asset.asset].balance,
getPrice(asset.priceFeed),
asset.scale
);
liquidity += signed256(mulFactor(
newAmount,
asset.liquidateCollateralFactor
));
}
}
return liquidity;
}
/**
* @dev The change in principal broken into repay and supply amounts
* @dev Note: The assumption `newPrincipal >= oldPrincipal` MUST be true
*/
function repayAndSupplyAmount(int104 oldPrincipal, int104 newPrincipal) internal pure returns (uint104, uint104) {
if (newPrincipal <= 0) {
return (uint104(newPrincipal - oldPrincipal), 0);
} else if (oldPrincipal >= 0) {
return (0, uint104(newPrincipal - oldPrincipal));
} else {
return (uint104(-oldPrincipal), uint104(newPrincipal));
}
}
/**
* @dev The change in principal broken into withdraw and borrow amounts
* @dev Note: The assumption `oldPrincipal >= newPrincipal` MUST be true
*/
function withdrawAndBorrowAmount(int104 oldPrincipal, int104 newPrincipal) internal view returns (uint104, uint104) {
if (newPrincipal >= 0) {
return (uint104(oldPrincipal - newPrincipal), 0);
} else if (oldPrincipal <= 0) {
return (0, uint104(oldPrincipal - newPrincipal));
} else {
return (uint104(oldPrincipal), uint104(-newPrincipal));
}
}
/**
* @notice Pauses different actions within Comet
* @param supplyPaused Boolean for pausing supply actions
* @param transferPaused Boolean for pausing transfer actions
* @param withdrawPaused Boolean for pausing withdraw actions
* @param absorbPaused Boolean for pausing absorb actions
* @param buyPaused Boolean for pausing buy actions
*/
function pause(
bool supplyPaused,
bool transferPaused,
bool withdrawPaused,
bool absorbPaused,
bool buyPaused
) override external {
if (msg.sender != governor && msg.sender != pauseGuardian) revert Unauthorized();
pauseFlags =
uint8(0) |
(toUInt8(supplyPaused) << PAUSE_SUPPLY_OFFSET) |
(toUInt8(transferPaused) << PAUSE_TRANSFER_OFFSET) |
(toUInt8(withdrawPaused) << PAUSE_WITHDRAW_OFFSET) |
(toUInt8(absorbPaused) << PAUSE_ABSORB_OFFSET) |
(toUInt8(buyPaused) << PAUSE_BUY_OFFSET);
emit PauseAction(supplyPaused, transferPaused, withdrawPaused, absorbPaused, buyPaused);
}
/**
* @return Whether or not supply actions are paused
*/
function isSupplyPaused() override public view returns (bool) {
return toBool(pauseFlags & (uint8(1) << PAUSE_SUPPLY_OFFSET));
}
/**
* @return Whether or not transfer actions are paused
*/
function isTransferPaused() override public view returns (bool) {
return toBool(pauseFlags & (uint8(1) << PAUSE_TRANSFER_OFFSET));
}
/**
* @return Whether or not withdraw actions are paused
*/
function isWithdrawPaused() override public view returns (bool) {
return toBool(pauseFlags & (uint8(1) << PAUSE_WITHDRAW_OFFSET));
}
/**
* @return Whether or not absorb actions are paused
*/
function isAbsorbPaused() override public view returns (bool) {
return toBool(pauseFlags & (uint8(1) << PAUSE_ABSORB_OFFSET));
}
/**
* @return Whether or not buy actions are paused
*/
function isBuyPaused() override public view returns (bool) {
return toBool(pauseFlags & (uint8(1) << PAUSE_BUY_OFFSET));
}
/**
* @dev Multiply a number by a factor
*/
function mulFactor(uint n, uint factor) internal pure returns (uint) {
return n * factor / FACTOR_SCALE;
}
/**
* @dev Divide a number by an amount of base
*/
function divBaseWei(uint n, uint baseWei) internal view returns (uint) {
return n * baseScale / baseWei;
}
/**
* @dev Multiply a `fromScale` quantity by a price, returning a common price quantity
*/
function mulPrice(uint128 n, uint128 price, uint64 fromScale) internal pure returns (uint) {
unchecked {
return uint256(n) * price / fromScale;
}
}
/**
* @dev Multiply a signed `fromScale` quantity by a price, returning a common price quantity
*/
function signedMulPrice(int128 n, uint128 price, uint64 fromScale) internal pure returns (int) {
unchecked {
return n * signed256(price) / signed256(fromScale);
}
}
/**
* @dev Divide a common price quantity by a price, returning a `toScale` quantity
*/
function divPrice(uint n, uint price, uint64 toScale) internal pure returns (uint) {
return n * toScale / price;
}
/**
* @dev Whether user has a non-zero balance of an asset, given assetsIn flags
*/
function isInAsset(uint16 assetsIn, uint8 assetOffset) internal pure returns (bool) {
return (assetsIn & (uint16(1) << assetOffset) != 0);
}
/**
* @dev Update assetsIn bit vector if user has entered or exited an asset
*/
function updateAssetsIn(
address account,
AssetInfo memory assetInfo,
uint128 initialUserBalance,
uint128 finalUserBalance
) internal {
if (initialUserBalance == 0 && finalUserBalance != 0) {
// set bit for asset
userBasic[account].assetsIn |= (uint16(1) << assetInfo.offset);
} else if (initialUserBalance != 0 && finalUserBalance == 0) {
// clear bit for asset
userBasic[account].assetsIn &= ~(uint16(1) << assetInfo.offset);
}
}
/**
* @dev Write updated principal to store and tracking participation
*/
function updateBasePrincipal(address account, UserBasic memory basic, int104 principalNew) internal {
int104 principal = basic.principal;
basic.principal = principalNew;
if (principal >= 0) {
uint indexDelta = trackingSupplyIndex - basic.baseTrackingIndex;
basic.baseTrackingAccrued += safe64(uint104(principal) * indexDelta / trackingIndexScale / accrualDescaleFactor);
} else {
uint indexDelta = trackingBorrowIndex - basic.baseTrackingIndex;
basic.baseTrackingAccrued += safe64(uint104(-principal) * indexDelta / trackingIndexScale / accrualDescaleFactor);
}
if (principalNew >= 0) {
basic.baseTrackingIndex = trackingSupplyIndex;
} else {
basic.baseTrackingIndex = trackingBorrowIndex;
}
userBasic[account] = basic;
}
/**
* @dev Safe ERC20 transfer in, assumes no fee is charged and amount is transferred
*/
function doTransferIn(address asset, address from, uint amount) internal {
bool success = ERC20(asset).transferFrom(from, address(this), amount);
if (!success) revert TransferInFailed();
}
/**
* @dev Safe ERC20 transfer out
*/
function doTransferOut(address asset, address to, uint amount) internal {
bool success = ERC20(asset).transfer(to, amount);
if (!success) revert TransferOutFailed();
}
/**
* @notice Supply an amount of asset to the protocol
* @param asset The asset to supply
* @param amount The quantity to supply
*/
function supply(address asset, uint amount) override external {
return supplyInternal(msg.sender, msg.sender, msg.sender, asset, amount);
}
/**
* @notice Supply an amount of asset to dst
* @param dst The address which will hold the balance
* @param asset The asset to supply
* @param amount The quantity to supply
*/
function supplyTo(address dst, address asset, uint amount) override external {
return supplyInternal(msg.sender, msg.sender, dst, asset, amount);
}
/**
* @notice Supply an amount of asset from `from` to dst, if allowed
* @param from The supplier address
* @param dst The address which will hold the balance
* @param asset The asset to supply
* @param amount The quantity to supply
*/
function supplyFrom(address from, address dst, address asset, uint amount) override external {
return supplyInternal(msg.sender, from, dst, asset, amount);
}
/**
* @dev Supply either collateral or base asset, depending on the asset, if operator is allowed
*/
function supplyInternal(address operator, address from, address dst, address asset, uint amount) internal {
if (isSupplyPaused()) revert Paused();
if (!hasPermission(from, operator)) revert Unauthorized();
if (asset == baseToken) {
return supplyBase(from, dst, safe104(amount));
} else {
return supplyCollateral(from, dst, asset, safe128(amount));
}
}
/**
* @dev Supply an amount of base asset from `from` to dst
*/
function supplyBase(address from, address dst, uint104 amount) internal {
doTransferIn(baseToken, from, amount);
accrueInternal();
UserBasic memory dstUser = userBasic[dst];
int104 dstPrincipal = dstUser.principal;
int104 dstBalance = presentValue(dstPrincipal) + signed104(amount);
int104 dstPrincipalNew = principalValue(dstBalance);
(uint104 repayAmount, uint104 supplyAmount) = repayAndSupplyAmount(dstPrincipal, dstPrincipalNew);
totalSupplyBase += supplyAmount;
totalBorrowBase -= repayAmount;
updateBasePrincipal(dst, dstUser, dstPrincipalNew);
emit Supply(from, dst, amount);
emit Transfer(address(0), dst, amount);
}
/**
* @dev Supply an amount of collateral asset from `from` to dst
*/
function supplyCollateral(address from, address dst, address asset, uint128 amount) internal {
doTransferIn(asset, from, amount);
AssetInfo memory assetInfo = getAssetInfoByAddress(asset);
TotalsCollateral memory totals = totalsCollateral[asset];
totals.totalSupplyAsset += amount;
if (totals.totalSupplyAsset > assetInfo.supplyCap) revert SupplyCapExceeded();
uint128 dstCollateral = userCollateral[dst][asset].balance;
uint128 dstCollateralNew = dstCollateral + amount;
totalsCollateral[asset] = totals;
userCollateral[dst][asset].balance = dstCollateralNew;
updateAssetsIn(dst, assetInfo, dstCollateral, dstCollateralNew);
emit SupplyCollateral(from, dst, asset, amount);
}
/**
* @notice ERC20 transfer an amount of base token to dst
* @param dst The recipient address
* @param amount The quantity to transfer
* @return true
*/
function transfer(address dst, uint amount) override external returns (bool) {
transferInternal(msg.sender, msg.sender, dst, baseToken, amount);
return true;
}
/**
* @notice ERC20 transfer an amount of base token from src to dst, if allowed
* @param src The sender address
* @param dst The recipient address
* @param amount The quantity to transfer
* @return true
*/
function transferFrom(address src, address dst, uint amount) override external returns (bool) {
transferInternal(msg.sender, src, dst, baseToken, amount);
return true;
}
/**
* @notice Transfer an amount of asset to dst
* @param dst The recipient address
* @param asset The asset to transfer
* @param amount The quantity to transfer
*/
function transferAsset(address dst, address asset, uint amount) override external {
return transferInternal(msg.sender, msg.sender, dst, asset, amount);
}
/**
* @notice Transfer an amount of asset from src to dst, if allowed
* @param src The sender address
* @param dst The recipient address
* @param asset The asset to transfer
* @param amount The quantity to transfer
*/
function transferAssetFrom(address src, address dst, address asset, uint amount) override external {
return transferInternal(msg.sender, src, dst, asset, amount);
}
/**
* @dev Transfer either collateral or base asset, depending on the asset, if operator is allowed
*/
function transferInternal(address operator, address src, address dst, address asset, uint amount) internal {
if (isTransferPaused()) revert Paused();
if (!hasPermission(src, operator)) revert Unauthorized();
if (src == dst) revert NoSelfTransfer();
if (asset == baseToken) {
return transferBase(src, dst, safe104(amount));
} else {
return transferCollateral(src, dst, asset, safe128(amount));
}
}
/**
* @dev Transfer an amount of base asset from src to dst, borrowing if possible/necessary
*/