test: add integration tests for 'bootc switch --apply'

Signed-off-by: Robert Sturla <[email protected]>

Author: p5

tmt/plans/integration.fmf

@@ -54,3 +54,11 @@ execute:
     test:
         - /tmt/tests/bootc-install-provision
         - /tmt/tests/test-23-install-outside-container
+
+/test-24-local-upgrade-reboot:
+  summary: Execute local upgrade tests with automated reboot
+  discover:
+    how: fmf
+    test:
+        - /tmt/tests/bootc-install-provision
+        - /tmt/tests/test-24-local-upgrade-reboot

tmt/tests/booted/test-image-upgrade-reboot.nu

@@ -0,0 +1,73 @@
+# This test does:
+# bootc image copy-to-storage
+# podman build <from that image>
+# bootc switch <into that image> --apply
+# Verify we boot into the new image
+#
+use std assert
+use tap.nu
+
+const kargsv0 = ["testarg=foo", "othertestkarg", "thirdkarg=bar"]
+
+# This code runs on *each* boot.
+# Here we just capture information.
+bootc status
+let st = bootc status --json | from json
+let booted = $st.status.booted.image
+
+# Parse the kernel commandline into a list.
+# This is not a proper parser, but good enough
+# for what we need here.
+def parse_cmdline []  {
+    open /proc/cmdline | str trim | split row " "
+}
+
+# Run on the first boot
+def initial_build [] {
+    tap begin "local image push + pull + upgrade"
+
+    bootc image copy-to-storage
+    let img = podman image inspect localhost/bootc | from json
+
+    mkdir usr/lib/bootc/kargs.d
+    { kargs: $kargsv0 } | to toml | save usr/lib/bootc/kargs.d/05-testkargs.toml
+    # A simple derived container that adds a file, but also injects some kargs
+    "FROM localhost/bootc
+COPY usr/ /usr/
+" | save Dockerfile
+    # Build it
+    podman build -t localhost/bootc-derived .
+
+    let orig_root_mtime = ls -Dl /ostree/bootc | get modified
+
+    # Now, switch into the new image
+    bash -c $"bootc switch --apply --transport containers-storage localhost/bootc-derived"
+
+    # We cannot perform any other checks here since the system will be automatically rebooted
+}
+
+# Check we have the updated image
+def second_boot [] {
+    print "verifying second boot"
+    assert equal $booted.image.transport containers-storage
+    assert equal $booted.image.image localhost/bootc-derived
+
+    # Verify we have updated kargs
+    let cmdline = parse_cmdline
+    print $"cmdline=($cmdline)"
+    for x in $kargsv0 {
+        print $"Verifying karg ($x)"
+        assert ($x in $cmdline)
+    }
+
+    tap ok
+}
+
+def main [] {
+    # See https://tmt.readthedocs.io/en/stable/stories/features.html#reboot-during-test
+    match $env.TMT_REBOOT_COUNT? {
+        null | "0" => initial_build,
+        "1" => second_boot,
+        $o => { error make { msg: $"Invalid TMT_REBOOT_COUNT ($o)" } },
+    }
+}

tmt/tests/test-24-local-upgrade-reboot.fmf

@@ -0,0 +1,3 @@
+summary: Execute local upgrade tests
+test: nu booted/test-image-pushpull-upgrade-reboot.nu
+duration: 30m