Added example project

Author: kraifpatrik

README.md

@@ -16,7 +16,7 @@ See file [yamc.gml](utils/yamc.gml) for simple utility functions. The
 custom ones. If you are not familiar with shaders, you can also draw the models
 using GameMaker's built-in shaders with [lighting](https://manual.yoyogames.com/GameMaker_Language/GML_Reference/Drawing/Lighting/Lighting.htm),
 [fog](https://manual.yoyogames.com/GameMaker_Language/GML_Reference/Drawing/GPU_Control/gpu_set_fog.htm)
-etc.
+etc. See [examples](examples) folder for little example projects.
 
 # Features
 * Convert static model into a binary file, easily loadable using functions `buffer_load` and `vertex_create_buffer_from_buffer`.

examples/.gitkeep

@@ -0,0 +1,13 @@
+{
+  "FolderOrderSettings": [],
+  "ResourceOrderSettings": [
+    {"name":"OModelViewer","order":16,"path":"objects/OModelViewer/OModelViewer.yy",},
+    {"name":"yamc","order":17,"path":"scripts/yamc/yamc.yy",},
+    {"name":"SprSpecular","order":20,"path":"sprites/SprSpecular/SprSpecular.yy",},
+    {"name":"ShBasic","order":18,"path":"shaders/ShBasic/ShBasic.yy",},
+    {"name":"SprNormal","order":19,"path":"sprites/SprNormal/SprNormal.yy",},
+    {"name":"SprGloss","order":21,"path":"sprites/SprGloss/SprGloss.yy",},
+    {"name":"SprDiffuse","order":22,"path":"sprites/SprDiffuse/SprDiffuse.yy",},
+    {"name":"Room1","order":15,"path":"rooms/Room1/Room1.yy",},
+  ],
+}

examples/ModelViewer/ModelViewer.resource_order

@@ -0,0 +1 @@
+https://polyhaven.com/a/cardboard_box_01

examples/ModelViewer/ModelViewer.yyp

@@ -0,0 +1 @@
+https://kenney.nl/assets/car-kit

examples/ModelViewer/datafiles/cardboard_box/cardboard_box.bin

@@ -0,0 +1,2 @@
+camera_destroy(camera);
+FreeModelAndSprites();

examples/ModelViewer/datafiles/cardboard_box/cardboard_box.fbx

@@ -0,0 +1,168 @@
+display_set_gui_maximize(1, 1);
+
+// The camera used when rendering the 3D model
+camera = camera_create();
+
+// This object's (camera's) position on z axis
+z = 0;
+
+// Camera's horizontal direction
+direction = -45;
+
+// Camera's vertical direction
+directionUp = 25;
+
+// Camera's distance from 0, 0, 0
+zoom = 1;
+
+// Mouse X position from previous frame
+mouseLastX = 0;
+
+// Mouse Y position from previous frame
+mouseLastY = 0;
+
+// The loaded vertex buffer or undefined
+model = undefined;
+
+// The model's diffuse texture
+spriteDiffuse = undefined;
+
+// The model's normal map texture
+spriteNormal = undefined;
+
+// The model's specular color texture
+spriteSpecular = undefined;
+
+// The model's glossiness texture (0 = rough, 255 = smooth)
+spriteGloss = undefined;
+
+// Use true to enable texture filtering
+textureFilter = true;
+
+// Cache the identity matrix just so we dont make a new one every frame
+matrixIdentity = matrix_build_identity();
+
+// The model's transformation matrix
+matrix = matrixIdentity;
+
+// Open file dialog path
+openPath = working_directory;
+
+// Frees memory after loaded models and sprites
+FreeModelAndSprites = function ()
+{
+	if (model != undefined)
+	{
+		vertex_delete_buffer(model);
+		model = undefined;
+	}
+
+	if (spriteDiffuse != undefined)
+	{
+		sprite_delete(spriteDiffuse);
+		spriteDiffuse = undefined;
+	}
+
+	if (spriteNormal != undefined)
+	{
+		sprite_delete(spriteNormal);
+		spriteNormal = undefined;
+	}
+
+	if (spriteSpecular != undefined)
+	{
+		sprite_delete(spriteSpecular);
+		spriteSpecular = undefined;
+	}
+
+	if (spriteGloss != undefined)
+	{
+		sprite_delete(spriteGloss);
+		spriteGloss = undefined;
+	}
+};
+
+// Frees current model and sprites from memory and loads a new model
+LoadModel = function (_path)
+{
+	FreeModelAndSprites();
+	var _buffer = buffer_load(_path);
+	model = vertex_create_buffer_from_buffer(_buffer, vertex_format_pnuct);
+
+	// Compute model's bounding box
+	var _xmin = undefined;
+	var _xmax = undefined;
+	var _ymin = undefined;
+	var _ymax = undefined;
+	var _zmin = undefined;
+	var _zmax = undefined;
+	var _position = 0;
+	var _stride = (3 * 4) + (3 * 4) + (2 * 4) + 4 + (4 * 4); // pnuct
+
+	repeat (vertex_get_number(model))
+	{
+		var _x = buffer_peek(_buffer, _position + 0, buffer_f32);
+		var _y = buffer_peek(_buffer, _position + 4, buffer_f32);
+		var _z = buffer_peek(_buffer, _position + 8, buffer_f32);
+
+		_xmin = min(_xmin ?? _x, _x);
+		_xmax = max(_xmax ?? _x, _x);
+		_ymin = min(_ymin ?? _y, _y);
+		_ymax = max(_ymax ?? _y, _y);
+		_zmin = min(_zmin ?? _z, _z);
+		_zmax = max(_zmax ?? _z, _z);
+
+		_position += _stride;
+	}
+
+	// Scale down the model and center it around 0, 0, 0
+	var _scale = 1 / max(_xmax - _xmin, _ymax - _ymin, _zmax - _zmin);
+
+	matrix = matrix_build(
+		-((_xmin + _xmax) / 2) * _scale,
+		-((_ymin + _ymax) / 2) * _scale,
+		-((_zmin + _zmax) / 2) * _scale,
+		0, 0, 0,
+		_scale, _scale, _scale);
+
+	vertex_freeze(model);
+	buffer_delete(_buffer);
+};
+
+LoadDiffuse = function (_path)
+{
+	if (spriteDiffuse != undefined)
+	{
+		sprite_delete(spriteDiffuse)
+	}
+	spriteDiffuse = sprite_add(_path, 1, false, true, 0, 0);
+};
+
+LoadNormal = function (_path)
+{
+	if (spriteNormal != undefined)
+	{
+		sprite_delete(spriteNormal);
+	}
+	spriteNormal = sprite_add(_path, 1, false, true, 0, 0);
+};
+
+LoadSpecular = function (_path)
+{
+	if (spriteSpecular != undefined)
+	{
+		sprite_delete(spriteSpecular);
+	}
+	spriteSpecular = sprite_add(_path, 1, false, true, 0, 0);
+};
+
+LoadGloss = function (_path)
+{
+	if (spriteGloss != undefined)
+	{
+		sprite_delete(spriteGloss);
+	}
+	spriteGloss = sprite_add(_path, 1, false, true, 0, 0);
+};
+
+LoadModel("firetruck/firetruck.bin");

examples/ModelViewer/datafiles/cardboard_box/diffuse.jpeg

@@ -0,0 +1,38 @@
+draw_clear(#202020);
+
+// We don't need to do anything if there's no model loaded
+if (model == undefined)
+{
+	exit;
+}
+
+// Apply our 3D camera
+camera_apply(camera);
+
+// Change GPU settings to enable 3D
+gpu_push_state();
+gpu_set_zwriteenable(true);
+gpu_set_ztestenable(true);
+gpu_set_tex_mip_enable(mip_on);
+gpu_set_tex_filter(textureFilter);
+
+// Use the basic shader
+shader_set(ShBasic);
+shader_set_uniform_f(shader_get_uniform(ShBasic, "u_vCamera"), x, y, z);
+texture_set_stage(shader_get_sampler_index(ShBasic, "u_texNormal"),
+	sprite_get_texture(spriteNormal ?? SprNormal, 0));
+texture_set_stage(shader_get_sampler_index(ShBasic, "u_texSpecular"),
+	sprite_get_texture(spriteSpecular ?? SprSpecular, 0));
+texture_set_stage(shader_get_sampler_index(ShBasic, "u_texGloss"),
+	sprite_get_texture(spriteGloss ?? SprGloss, 0));
+
+// Draw the model with its transform matrix applied
+matrix_set(matrix_world, matrix);
+vertex_submit(model, pr_trianglelist, sprite_get_texture(spriteDiffuse ?? SprDiffuse, 0));
+matrix_set(matrix_world, matrixIdentity);
+
+// Unset shader
+shader_reset();
+
+// Restore previous GPU settings
+gpu_pop_state();

examples/ModelViewer/datafiles/cardboard_box/gloss.jpeg

@@ -0,0 +1,8 @@
+draw_text(8, 8,
+	  "Ctrl+L - Load model (pnuct format)\n"
+	+ "Ctrl+D - Load diffuse texture\n"
+	+ "Ctrl+N - Load normal texture\n"
+	+ "Ctrl+S - Load specular color texture\n"
+	+ "Ctrl+G - Load glossiness texture\n"
+	+ "Ctrl+F - Toggle texture filtering\n"
+	);