build.gradle

plugins {
    id "architectury-plugin" version "3.4.+"
    id "dev.architectury.loom" version "1.7.+" apply false
}

tasks.register("printEnv") {
    doLast {
        def envFile = new File(System.getenv("GITHUB_ENV"))
        envFile.append("MOD_VERSION=$mod_version\n")
        envFile.append("RELEASE_NAME=$archives_base_name-$mod_version\n")
        envFile.append("GAME_VERSIONS=$minecraft_version\n")
    }
}

architectury {
    minecraft = minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    repositories {
        maven { url = "https://maven.parchmentmc.org" } // Parchment mappings

        // mavens used on both forge and fabric
        maven { url = "https://maven.blamejared.com/" } // JEI
        maven { url = "https://maven.tterrag.com/" } // Flywheel on both, Create and Registrate on forge
        maven { url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/" } // Fuzs Mod Resources
    }

    dependencies {
        minecraft "com.mojang:minecraft:$minecraft_version"
        mappings loom.officialMojangMappings()
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    base.archivesName = archives_base_name
    group = maven_group

    // Formats the mod version to include the loader, Minecraft version, and build number (if present)
    // example: 1.0.0+fabric-1.18.2-build.100
    String buildNumber = System.getenv("GITHUB_RUN_NUMBER")
    version = "$mod_version+$project.name-$minecraft_version" + (buildNumber != null ? "-build.$buildNumber" : "")

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
    }

    java {
        withSourcesJar()
    }
}