Added session manager; Added clojure support

Author: alexdong

autoload/vimclojure.vim

@@ -0,0 +1,89 @@
+" Part of Vim filetype plugin for Clojure
+" Language:     Clojure
+" Maintainer:   Meikel Brandmeyer <[email protected]>
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! vimclojure#util#SynIdName()
+	return synIDattr(synID(line("."), col("."), 0), "name")
+endfunction
+
+function! vimclojure#util#WithSaved(closure)
+	let v = a:closure.save()
+	try
+		let r = a:closure.f()
+	finally
+		call a:closure.restore(v)
+	endtry
+	return r
+endfunction
+
+function! vimclojure#util#WithSavedPosition(closure)
+	function a:closure.save() dict
+		let [ _b, l, c, _o ] = getpos(".")
+		let b = bufnr("%")
+		return [b, l, c]
+	endfunction
+
+	function a:closure.restore(value) dict
+		let [b, l, c] = a:value
+
+		if bufnr("%") != b
+			execute b "buffer!"
+		endif
+		call setpos(".", [0, l, c, 0])
+	endfunction
+
+	return vimclojure#util#WithSaved(a:closure)
+endfunction
+
+function! vimclojure#util#WithSavedRegister(reg, closure)
+	let a:closure._register = a:reg
+
+	function a:closure.save() dict
+		return [getreg(self._register, 1), getregtype(self._register)]
+	endfunction
+
+	function a:closure.restore(value) dict
+		call call(function("setreg"), [self._register] + a:value)
+	endfunction
+
+	return vimclojure#util#WithSaved(a:closure)
+endfunction
+
+function! vimclojure#util#WithSavedOption(option, closure)
+	let a:closure._option = a:option
+
+	function a:closure.save() dict
+		return eval("&" . self._option)
+	endfunction
+
+	function a:closure.restore(value) dict
+		execute "let &" . self._option . " = a:value"
+	endfunction
+
+	return vimclojure#util#WithSaved(a:closure)
+endfunction
+
+function! vimclojure#util#Yank(r, how)
+	let closure = {'reg': a:r, 'yank': a:how}
+
+	function closure.f() dict
+		silent execute self.yank
+		return getreg(self.reg)
+	endfunction
+
+	return vimclojure#util#WithSavedRegister(a:r, closure)
+endfunction
+
+function! vimclojure#util#MoveBackward()
+	call search('\S', 'Wb')
+endfunction
+
+function! vimclojure#util#MoveForward()
+	call search('\S', 'W')
+endfunction
+
+" Epilog
+let &cpo = s:save_cpo

autoload/vimclojure/util.vim

@@ -0,0 +1,24 @@
+# Miscellaneous auto-load Vim scripts
+
+The git repository at <https://github.com/xolox/vim-misc> contains Vim scripts that are used by most of the [Vim plug-ins I've written] [plugins] yet don't really belong with any single one. I include this repository as a subdirectory of my plug-in repositories using the following commands:
+
+    $ git remote add -f vim-misc https://github.com/xolox/vim-misc.git
+    $ git merge -s ours --no-commit vim-misc/master
+    $ git read-tree --prefix=autoload/xolox/misc/ -u vim-misc/master
+    $ git commit -m "Merge vim-misc repository as subdirectory"
+
+To update a plug-in repository to the latest versions of the miscellaneous auto-load scripts I execute the following command:
+
+    $ git pull -s subtree vim-misc master
+
+## Contact
+
+If you have questions, bug reports, suggestions, etc. the author can be contacted at <[email protected]>. The latest version is available at <http://peterodding.com/code/vim/misc> and <https://github.com/xolox/vim-misc>.
+
+## License
+
+This software is licensed under the [MIT license](http://en.wikipedia.org/wiki/MIT_License).  
+© 2011 Peter Odding &lt;<[email protected]>&gt;.
+
+
+[plugins]: http://peterodding.com/code/vim/

autoload/xolox/misc/README.md

@@ -0,0 +1,37 @@
+" Vim auto-load script
+" Author: Peter Odding <[email protected]>
+" Last Change: September 4, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+function! xolox#misc#buffer#is_empty()
+  " Check if the current buffer is an empty, unchanged buffer which can be reused.
+  return !&modified && expand('%') == '' && line('$') <= 1 && getline(1) == ''
+endfunction
+
+function! xolox#misc#buffer#prepare(bufname)
+  let bufname = '[' . a:bufname . ']'
+  let buffers = tabpagebuflist()
+  call map(buffers, 'fnamemodify(bufname(v:val), ":t:r")')
+  let idx = index(buffers, bufname)
+  if idx >= 0
+    execute (idx + 1) . 'wincmd w'
+  elseif !(xolox#misc#buffer#is_empty() || expand('%:t') == bufname)
+    vsplit
+  endif
+  silent execute 'edit' fnameescape(bufname)
+  lcd " clear working directory
+  setlocal buftype=nofile bufhidden=hide noswapfile
+  let &l:statusline = bufname
+  call xolox#misc#buffer#unlock()
+  silent %delete
+endfunction
+
+function! xolox#misc#buffer#lock()
+  " Lock a special buffer so it can no longer be edited.
+  setlocal readonly nomodifiable nomodified
+endfunction
+
+function! xolox#misc#buffer#unlock()
+  " Unlock a special buffer so that its content can be updated.
+  setlocal noreadonly modifiable
+endfunction

autoload/xolox/misc/buffer.vim

@@ -0,0 +1,18 @@
+" Vim auto-load script
+" Author: Peter Odding <[email protected]>
+" Last Change: March 15, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+" Keyword completion from the current buffer for user defined commands.
+
+function! xolox#misc#complete#keywords(arglead, cmdline, cursorpos)
+  let words = {}
+  for line in getline(1, '$')
+    for word in split(line, '\W\+')
+      let words[word] = 1
+    endfor
+  endfor
+  return sort(keys(filter(words, 'v:key =~# a:arglead')))
+endfunction
+
+" vim: ts=2 sw=2 et

autoload/xolox/misc/complete.vim

@@ -0,0 +1,46 @@
+" Vim auto-load script
+" Author: Peter Odding <[email protected]>
+" Last Change: November 21, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+" Convert a string into a :substitute pattern that matches the string literally.
+
+function! xolox#misc#escape#pattern(string)
+  if type(a:string) == type('')
+    let string = escape(a:string, '^$.*\~[]')
+    return substitute(string, '\n', '\\n', 'g')
+  endif
+  return ''
+endfunction
+
+" Convert a string into a :substitute replacement that inserts the string literally.
+
+function! xolox#misc#escape#substitute(string)
+  if type(a:string) == type('')
+    let string = escape(a:string, '\&~%')
+    return substitute(string, '\n', '\\r', 'g')
+  endif
+  return ''
+endfunction
+
+" Convert a string into a quoted command line argument. I was going to add a
+" long rant here about &shellslash, but really, it won't make any difference.
+" Let's just suffice to say that I have yet to encounter a single person out
+" there who uses this option for its intended purpose (running a UNIX-style
+" shell on Windows).
+
+function! xolox#misc#escape#shell(string)
+  if xolox#misc#os#is_win()
+    try
+      let ssl_save = &shellslash
+      set noshellslash
+      return shellescape(a:string)
+    finally
+      let &shellslash = ssl_save
+    endtry
+  else
+    return shellescape(a:string)
+  endif
+endfunction
+
+" vim: ts=2 sw=2 et

autoload/xolox/misc/escape.vim

@@ -0,0 +1,49 @@
+" Vim auto-load script
+" Author: Peter Odding <[email protected]>
+" Last Change: August 31, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+" Remove duplicate values from {list} in-place (preserves order).
+
+function! xolox#misc#list#unique(list)
+  call reverse(a:list)
+  call filter(a:list, 'count(a:list, v:val) == 1')
+  return reverse(a:list)
+endfunction
+
+" Binary insertion (more efficient than calling sort() after each insertion).
+
+function! xolox#misc#list#binsert(list, value, ...)
+  let idx = s:binsert_r(a:list, 0, len(a:list), a:value, exists('a:1') && a:1)
+  return insert(a:list, a:value, idx)
+endfunction
+
+function! s:binsert_r(list, low, high, value, ignorecase)
+  let mid = a:low + (a:high - a:low) / 2
+  if a:low == a:high
+    return a:low
+  elseif a:ignorecase ? a:value >? a:list[mid] : a:value > a:list[mid]
+    return s:binsert_r(a:list, mid + 1, a:high, a:value, a:ignorecase)
+  elseif a:ignorecase ? a:value <? a:list[mid] : a:value < a:list[mid]
+    return s:binsert_r(a:list, a:low, mid, a:value, a:ignorecase)
+  else
+    return mid
+  endif
+endfunction
+
+if 0
+  " Tests for xolox#misc#list#binsert().
+  let s:list = ['a', 'B', 'e']
+  function! s:test(value, expected)
+    call xolox#misc#list#binsert(s:list, a:value, 1)
+    if s:list != a:expected
+      call xolox#misc#msg#warn("list.vim: Test failed! Expected %s, got %s",
+            \ string(a:expected), string(s:list))
+    endif
+  endfunction
+  call s:test('c', ['a', 'B', 'c', 'e'])
+  call s:test('D', ['a', 'B', 'c', 'D', 'e'])
+  call s:test('f', ['a', 'B', 'c', 'D', 'e', 'f'])
+endif
+
+" vim: ts=2 sw=2 et

autoload/xolox/misc/list.vim

@@ -0,0 +1,83 @@
+" Vim auto-load script
+" Author: Peter Odding <[email protected]>
+" Last Change: March 15, 2011
+" URL: http://peterodding.com/code/vim/misc/
+
+if !exists('g:xolox_message_buffer')
+  " For when I lose my :messages history :-\
+  let g:xolox_message_buffer = 100
+endif
+
+if !exists('g:xolox_messages')
+  let g:xolox_messages = []
+endif
+
+" Show a formatted informational message to the user.
+
+function! xolox#misc#msg#info(...)
+  call s:show_message('title', a:000)
+endfunction
+
+" Show a formatted warning message to the user.
+
+function! xolox#misc#msg#warn(...)
+  call s:show_message('warningmsg', a:000)
+endfunction
+
+" Show a formatted debugging message to the user?
+
+function! xolox#misc#msg#debug(...)
+  if &vbs >= 1
+    call s:show_message('question', a:000)
+  endif
+endfunction
+
+" The implementation of info() and warn().
+
+function! s:show_message(hlgroup, args)
+  let nargs = len(a:args)
+  if nargs == 1
+    let message = a:args[0]
+  elseif nargs >= 2
+    let message = call('printf', a:args)
+  endif
+  if exists('message')
+    try
+      " Temporarily disable Vim's |hit-enter| prompt and mode display.
+      if !exists('s:more_save')
+        let s:more_save = &more
+        let s:ruler_save = &ruler
+        let s:smd_save = &showmode
+      endif
+      set nomore noshowmode
+      if winnr('$') == 1 | set noruler | endif
+      augroup PluginXoloxHideMode
+        autocmd! CursorHold,CursorHoldI * call s:clear_message()
+      augroup END
+      execute 'echohl' a:hlgroup
+      " Redraw to avoid |hit-enter| prompt.
+      redraw | echomsg message
+      if g:xolox_message_buffer > 0
+        call add(g:xolox_messages, message)
+        if len(g:xolox_messages) > g:xolox_message_buffer
+          call remove(g:xolox_messages, 0)
+        endif
+      endif
+    finally
+      " Always clear message highlighting, even when interrupted by Ctrl-C.
+      echohl none
+    endtry
+  endif
+endfunction
+
+function! s:clear_message()
+  echo ''
+  let &more = s:more_save
+  let &showmode = s:smd_save
+  let &ruler = s:ruler_save
+  unlet s:more_save s:ruler_save s:smd_save
+  autocmd! PluginXoloxHideMode
+  augroup! PluginXoloxHideMode
+endfunction
+
+" vim: ts=2 sw=2 et