Updated syntastic

Author: Alex Dong

autoload/syntastic/c.vim

@@ -128,7 +128,7 @@ function! syntastic#c#SearchHeaders()
     " search included headers
     for hfile in files
         if hfile != ''
-            let filename = expand('%:p:h') . ((has('win32') || has('win64')) ?
+            let filename = expand('%:p:h') . (has('win32') ?
                         \ '\' : '/') . hfile
             try
                 let lines = readfile(filename, '', 100)

doc/syntastic.txt

@@ -163,6 +163,20 @@ syntax errors: >
     let g:syntastic_enable_signs=1
 <
 
+                   *'syntastic_error_symbol'* *'syntastic_style_error_symbol'*
+               *'syntastic_warning_symbol'* *'syntastic_style_warning_symbol'*
+Use this option to control what the syntastic |:sign| text contains. Several
+error symobls can be customized:
+    syntastic_error_symbol - For syntax errors, defaults to '>>'
+    syntastic_style_error_symbol - For style errors, defaults to 'S>'
+    syntastic_warning_symbol - For syntax warnings, defaults to '>>'
+    syntastic_style_warning_symbol - For style warnings, defaults to 'S>'
+
+Example: >
+    let g:syntastic_error_symbol='✗'
+    let g:syntastic_warning_symbol='⚠'
+<
+
                                                  *'syntastic_enable_balloons'*
 Default: 1
 Use this option to tell syntastic whether to display error messages in balloons
@@ -340,7 +354,7 @@ The author of syntastic is a mighty wild stallion, hear him roar! >
 
 <
 He likes to trot around in the back yard reading his emails and sipping a
-scolding hot cup of Earl Grey. Email him at martin.grenfell at gmail dot com.
+scalding hot cup of Earl Grey. Email him at martin.grenfell at gmail dot com.
 He can also be found trolling the #vim channel on the freenode IRC network as
 scrooloose.
 

doc/tags

@@ -41,10 +41,14 @@
 'syntastic_enable_balloons'	syntastic.txt	/*'syntastic_enable_balloons'*
 'syntastic_enable_highlighting'	syntastic.txt	/*'syntastic_enable_highlighting'*
 'syntastic_enable_signs'	syntastic.txt	/*'syntastic_enable_signs'*
+'syntastic_error_symbol'	syntastic.txt	/*'syntastic_error_symbol'*
 'syntastic_loc_list_height'	syntastic.txt	/*'syntastic_loc_list_height'*
 'syntastic_mode_map'	syntastic.txt	/*'syntastic_mode_map'*
 'syntastic_quiet_warnings'	syntastic.txt	/*'syntastic_quiet_warnings'*
 'syntastic_stl_format'	syntastic.txt	/*'syntastic_stl_format'*
+'syntastic_style_error_symbol'	syntastic.txt	/*'syntastic_style_error_symbol'*
+'syntastic_style_warning_symbol'	syntastic.txt	/*'syntastic_style_warning_symbol'*
+'syntastic_warning_symbol'	syntastic.txt	/*'syntastic_warning_symbol'*
 ,b	camelcasemotion.txt	/*,b*
 ,e	camelcasemotion.txt	/*,e*
 ,w	camelcasemotion.txt	/*,w*

plugin/syntastic.vim

@@ -17,7 +17,7 @@ if exists("g:loaded_syntastic_plugin")
 endif
 let g:loaded_syntastic_plugin = 1
 
-let s:running_windows = has("win16") || has("win32") || has("win64")
+let s:running_windows = has("win16") || has("win32")
 
 if !s:running_windows
     let s:uname = system('uname')
@@ -26,6 +26,23 @@ endif
 if !exists("g:syntastic_enable_signs")
     let g:syntastic_enable_signs = 1
 endif
+
+if !exists("g:syntastic_error_symbol")
+    let g:syntastic_error_symbol = '>>'
+endif
+
+if !exists("g:syntastic_warning_symbol")
+    let g:syntastic_warning_symbol = '>>'
+endif
+
+if !exists("g:syntastic_style_error_symbol")
+    let g:syntastic_style_error_symbol = 'S>'
+endif
+
+if !exists("g:syntastic_style_warning_symbol")
+    let g:syntastic_style_warning_symbol = 'S>'
+endif
+
 if !has('signs')
     let g:syntastic_enable_signs = 0
 endif
@@ -115,9 +132,7 @@ function! s:UpdateErrors(auto_invoked)
         call s:CacheErrors()
     end
 
-    if s:BufHasErrorsOrWarningsToDisplay()
-        call setloclist(0, s:LocList())
-    endif
+    call setloclist(0, s:LocList())
 
     if g:syntastic_enable_balloons
         call s:RefreshBalloons()
@@ -185,6 +200,8 @@ function! s:CacheErrors()
         for ft in split(fts, '\.')
             if s:Checkable(ft)
                 let errors = SyntaxCheckers_{ft}_GetLocList()
+                "keep only lines that effectively match an error/warning
+                let errors = s:FilterLocList({'valid': 1}, errors)
                 "make errors have type "E" by default
                 call SyntasticAddToErrors(errors, {'type': 'E'})
                 call extend(s:LocList(), errors)
@@ -272,10 +289,10 @@ endfunction
 
 if g:syntastic_enable_signs
     "define the signs used to display syntax and style errors/warns
-    sign define SyntasticError text=>> texthl=error
-    sign define SyntasticWarning text=>> texthl=todo
-    sign define SyntasticStyleError text=S> texthl=error
-    sign define SyntasticStyleWarning text=S> texthl=todo
+    exe 'sign define SyntasticError text='.g:syntastic_error_symbol.' texthl=error'
+    exe 'sign define SyntasticWarning text='.g:syntastic_warning_symbol.' texthl=todo'
+    exe 'sign define SyntasticStyleError text='.g:syntastic_style_error_symbol.' texthl=error'
+    exe 'sign define SyntasticStyleWarning text='.g:syntastic_style_warning_symbol.' texthl=todo'
 endif
 
 "start counting sign ids at 5000, start here to hopefully avoid conflicting
@@ -346,6 +363,7 @@ endfunction
 "display the cached errors for this buf in the location list
 function! s:ShowLocList()
     if !empty(s:LocList())
+        call setloclist(0, s:LocList())
         let num = winnr()
         exec "lopen " . g:syntastic_loc_list_height
         if num != winnr()
@@ -470,6 +488,15 @@ function! s:LoadChecker(checker, ft)
     exec "runtime syntax_checkers/" . a:ft . "/" . a:checker . ".vim"
 endfunction
 
+"the script changes &shellpipe and &shell to stop the screen flicking when
+"shelling out to syntax checkers. Not all OSs support the hacks though
+function! s:OSSupportsShellpipeHack()
+    if !exists("s:os_supports_shellpipe_hack")
+        let s:os_supports_shellpipe_hack = !s:running_windows && (s:uname !~ "FreeBSD") && (s:uname !~ "OpenBSD")
+    endif
+    return s:os_supports_shellpipe_hack
+endfunction
+
 "return a string representing the state of buffer according to
 "g:syntastic_stl_format
 "
@@ -529,36 +556,36 @@ endfunction
 "   'subtype' - all errors will be assigned the given subtype
 function! SyntasticMake(options)
     let old_loclist = getloclist(0)
-    let old_makeprg = &makeprg
+    let old_makeprg = &l:makeprg
     let old_shellpipe = &shellpipe
     let old_shell = &shell
-    let old_errorformat = &errorformat
+    let old_errorformat = &l:errorformat
 
-    if !s:running_windows && (s:uname !~ "FreeBSD")
+    if s:OSSupportsShellpipeHack()
         "this is a hack to stop the screen needing to be ':redraw'n when
         "when :lmake is run. Otherwise the screen flickers annoyingly
         let &shellpipe='&>'
         let &shell = '/bin/bash'
     endif
 
     if has_key(a:options, 'makeprg')
-        let &makeprg = a:options['makeprg']
+        let &l:makeprg = a:options['makeprg']
     endif
 
     if has_key(a:options, 'errorformat')
-        let &errorformat = a:options['errorformat']
+        let &l:errorformat = a:options['errorformat']
     endif
 
     silent lmake!
     let errors = getloclist(0)
 
     call setloclist(0, old_loclist)
-    let &makeprg = old_makeprg
-    let &errorformat = old_errorformat
+    let &l:makeprg = old_makeprg
+    let &l:errorformat = old_errorformat
     let &shellpipe=old_shellpipe
     let &shell=old_shell
 
-    if !s:running_windows && s:uname =~ "FreeBSD"
+    if s:OSSupportsShellpipeHack()
         redraw!
     endif
 
@@ -611,7 +638,7 @@ function! SyntasticLoadChecker(checkers, ft)
 
     if exists(opt_name)
         let opt_val = {opt_name}
-        if index(a:checkers, opt_val) != -1 && executable(opt_val)
+        if index(a:checkers, opt_val) != -1
             call s:LoadChecker(opt_val, a:ft)
         else
             echoerr &ft . " syntax not supported or not installed."

syntax_checkers/ada.vim

@@ -0,0 +1,132 @@
+"============================================================================
+"File:        ada.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Alfredo Di Napoli <[email protected]>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. 
+"
+"============================================================================
+
+" in order to also check header files add this to your .vimrc:
+" (this usually creates a .gch file in your source directory)
+"
+"   let g:syntastic_ada_check_header = 1
+"
+" To disable the search of included header files after special
+" libraries like gtk and glib add this line to your .vimrc:
+"
+"   let g:syntastic_ada_no_include_search = 1
+"
+" In order to add some custom include directories that should be added to the
+" gcc command line you can add those to the global variable
+" g:syntastic_ada_include_dirs. This list can be used like this:
+"
+"   let g:syntastic_ada_include_dirs = [ 'includes', 'headers' ]
+"
+" To enable header files being re-checked on every file write add the
+" following line to your .vimrc. Otherwise the header files are checked only
+" one time on initially loading the file.
+" In order to force syntastic to refresh the header includes simply
+" unlet b:syntastic_ada_includes. Then the header files are being re-checked
+" on the next file write.
+"
+"   let g:syntastic_ada_auto_refresh_includes = 1
+"
+" Alternatively you can set the buffer local variable b:syntastic_ada_cflags.
+" If this variable is set for the current buffer no search for additional
+" libraries is done. I.e. set the variable like this:
+"
+"   let b:syntastic_ada_cflags = ' -I/usr/include/libsoup-2.4'
+"
+" Moreover it is possible to add additional compiler options to the syntax
+" checking execution via the variable 'g:syntastic_ada_compiler_options':
+"
+"   let g:syntastic_ada_compiler_options = ' -std=c++0x'
+"
+" Additionally the setting 'g:syntastic_ada_config_file' allows you to define
+" a file that contains additional compiler arguments like include directories
+" or CFLAGS. The file is expected to contain one option per line. If none is
+" given the filename defaults to '.syntastic_ada_config':
+"
+"   let g:syntastic_ada_config_file = '.config'
+"
+" Using the global variable 'g:syntastic_ada_remove_include_errors' you can
+" specify whether errors of files included via the
+" g:syntastic_ada_include_dirs' setting are removed from the result set:
+"
+"   let g:syntastic_ada_remove_include_errors = 1
+
+if exists('loaded_ada_syntax_checker')
+    finish
+endif
+let loaded_ada_syntax_checker = 1
+
+if !executable('gcc')
+    finish
+endif
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+if !exists('g:syntastic_ada_config_file')
+    let g:syntastic_ada_config_file = '.syntastic_ada_config'
+endif
+
+function! SyntaxCheckers_ada_GetLocList()
+    let makeprg = 'gcc -c -fsyntax-only '
+    let errorformat =  '%-G%f:%s:,%f:%l:%c: %m,%f:%l: %m'
+
+    if exists('g:syntastic_ada_compiler_options')
+        let makeprg .= g:syntastic_ada_compiler_options
+    endif
+
+    let makeprg .= ' ' . shellescape(expand('%')) .
+                \ ' ' . syntastic#c#GetIncludeDirs('ada')
+
+    if expand('%') =~? '\%(.h\|.hpp\|.hh\)$'
+        if exists('g:syntastic_ada_check_header')
+            let makeprg = 'g++ -c '.shellescape(expand('%')).
+                        \ ' ' . syntastic#c#GetIncludeDirs('ada')
+        else
+            return []
+        endif
+    endif
+
+    if !exists('b:syntastic_ada_cflags')
+        if !exists('g:syntastic_ada_no_include_search') ||
+                    \ g:syntastic_ada_no_include_search != 1
+            if exists('g:syntastic_ada_auto_refresh_includes') &&
+                        \ g:syntastic_ada_auto_refresh_includes != 0
+                let makeprg .= syntastic#c#SearchHeaders()
+            else
+                if !exists('b:syntastic_ada_includes')
+                    let b:syntastic_ada_includes = syntastic#c#SearchHeaders()
+                endif
+                let makeprg .= b:syntastic_ada_includes
+            endif
+        endif
+    else
+        let makeprg .= b:syntastic_ada_cflags
+    endif
+
+    " add optional config file parameters
+    let makeprg .= ' ' . syntastic#c#ReadConfig(g:syntastic_ada_config_file)
+
+    " process makeprg
+    let errors = SyntasticMake({ 'makeprg': makeprg,
+                \ 'errorformat': errorformat })
+
+    " filter the processed errors if desired
+    if exists('g:syntastic_ada_remove_include_errors') &&
+                \ g:syntastic_ada_remove_include_errors != 0
+        return filter(errors,
+                    \ 'has_key(v:val, "bufnr") && v:val["bufnr"]=='.bufnr(''))
+    else
+        return errors
+    endif
+endfunction
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set et sts=4 sw=4:

syntax_checkers/c.vim

@@ -58,6 +58,11 @@
 " setting are removed from the result set:
 "
 "   let g:syntastic_c_remove_include_errors = 1
+"
+" Use the variable 'g:syntastic_c_errorformat' to override the default error
+" format:
+"
+"   let g:syntastic_c_errorformat = '%f:%l:%c: %trror: %m'
 
 if exists('loaded_c_syntax_checker')
     finish
@@ -84,7 +89,13 @@ function! SyntaxCheckers_c_GetLocList()
     let errorformat = '%-G%f:%s:,%-G%f:%l: %#error: %#(Each undeclared '.
                \ 'identifier is reported only%.%#,%-G%f:%l: %#error: %#for '.
                \ 'each function it appears%.%#,%-GIn file included%.%#,'.
-               \ '%-G %#from %f:%l\,,%f:%l:%c: %m,%f:%l: %trror: %m,%f:%l: %m'
+               \ '%-G %#from %f:%l\,,%f:%l:%c: %trror: %m,%f:%l:%c: '.
+               \ '%tarning: %m,%f:%l:%c: %m,%f:%l: %trror: %m,'.
+               \ '%f:%l: %tarning: %m,%f:%l: %m'
+
+    if exists('g:syntastic_c_errorformat')
+        let errorformat = g:syntastic_c_errorformat
+    endif
 
     " add optional user-defined compiler options
     let makeprg .= g:syntastic_c_compiler_options
@@ -125,7 +136,7 @@ function! SyntaxCheckers_c_GetLocList()
     endif
 
     " add optional config file parameters
-    let makeprg .= syntastic#c#ReadConfig(g:syntastic_c_config_file)
+    let makeprg .= ' '.syntastic#c#ReadConfig(g:syntastic_c_config_file)
 
     " process makeprg
     let errors = SyntasticMake({ 'makeprg': makeprg,

syntax_checkers/co.vim

@@ -0,0 +1,27 @@
+"============================================================================
+"File:        co.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Andrew Kelley <[email protected]>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+if exists("loaded_co_syntax_checker")
+    finish
+endif
+let loaded_co_syntax_checker = 1
+
+"bail if the user doesnt have coco installed
+if !executable("coco")
+    finish
+endif
+
+function! SyntaxCheckers_co_GetLocList()
+    let makeprg = 'coco -c -o /tmp '.shellescape(expand('%'))
+    let errorformat = '%EFailed at: %f,%ZSyntax%trror: %m on line %l,%EFailed at: %f,%Z%trror: Parse error on line %l: %m'
+
+    return SyntasticMake({ 'makeprg': makeprg, 'errorformat': errorformat })
+endfunction