feat(erc1155): add custom ERC1155 contract for airdrop

contracts/erc1155/MintableERC1155.sol

@@ -0,0 +1,61 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.0;
+
+import "@openzeppelin/contracts/access/Ownable.sol";
+import "@openzeppelin/contracts/token/ERC1155/ERC1155.sol";
+
+/**
+ * @title MintableERC1155
+ * @notice Ownable contract enabling owner to airdrop many recipients the same token ID at once
+ */
+contract MintableERC1155 is ERC1155, Ownable {
+    // Maps `tokenId` to metadata URI `tokenURI`
+    mapping(uint256 => string) public _tokenURIs;
+
+    event Airdrop(address caller, uint256 tokenId, address[] recipients, uint256 amount);
+
+    // We are passing an empty string as the `baseURI` because we use `_tokenURIs` instead
+    // to allow for IPFS URIs.
+    // solhint-disable-next-line
+    constructor() ERC1155("") {}
+
+    /**
+     * @notice Creates `amount` new tokens for `recipients` of token type `tokenId`.
+     * @dev Call might run out of gas if `recipients` arg too long. Might need to chunk up the list.
+     * @param recipients List of airdrop recipients.
+     * @param tokenId Token type to airdrop.
+     * @param amount Amount of token types to airdrop.
+     */
+    function airdrop(
+        uint256 tokenId,
+        address[] memory recipients,
+        uint256 amount
+    ) public onlyOwner {
+        for (uint256 i = 0; i < recipients.length; i++) {
+            _mint(recipients[i], tokenId, amount, "");
+        }
+        emit Airdrop(_msgSender(), tokenId, recipients, amount);
+    }
+
+    /**
+     * @notice Sets the URI for token of type `tokenId` to `tokenURI`.
+     * @param tokenId Token type to set `tokenURI` for.
+     * @param tokenURI URI of token metadata.
+     */
+    function setTokenURI(uint256 tokenId, string memory tokenURI) external onlyOwner {
+        require(bytes(_tokenURIs[tokenId]).length == 0, "uri already set");
+
+        _tokenURIs[tokenId] = tokenURI;
+        emit URI(tokenURI, tokenId);
+    }
+
+    /**
+     * @notice Returns metadata URI of token type `tokenId`.
+     * @dev Instead of returning the same URI for *all* token types, we return the uri set by
+     * `setTokenURI` to allow IPFS URIs for all token types.
+     * @param tokenId Token type to retrieve metadata URI for.
+     */
+    function uri(uint256 tokenId) public view override returns (string memory) {
+        return _tokenURIs[tokenId];
+    }
+}

deploy/021_deploy_erc1155.ts

@@ -0,0 +1,19 @@
+import "hardhat-deploy";
+import { HardhatRuntimeEnvironment } from "hardhat/types/runtime";
+
+const func = async function (hre: HardhatRuntimeEnvironment) {
+  const { deployments, getNamedAccounts } = hre;
+  const { deploy } = deployments;
+
+  const { deployer } = await getNamedAccounts();
+
+  await deploy("MintableERC1155", {
+    from: deployer,
+    log: true,
+    skipIfAlreadyDeployed: true,
+    args: [],
+  });
+};
+
+module.exports = func;
+func.tags = ["MintableERC1155"];

deployments/deployments.json

@@ -52,6 +52,7 @@
   "288": { "SpokePool": { "address": "0xBbc6009fEfFc27ce705322832Cb2068F8C1e0A58", "blockNumber": 619993 } },
   "42161": { "SpokePool": { "address": "0xB88690461dDbaB6f04Dfad7df66B7725942FEb9C", "blockNumber": 12741972 } },
   "80001": {
+    "MintableERC1155": { "address": "0xe377d7C510fEbc64525f480e33306b21b30066F7", "blockNumber": 33352305 },
     "PolygonTokenBridger": { "address": "0x97f102f2f73717e203f964Ad9940e4C2e79b8597", "blockNumber": 26276246 },
     "SpokePool": { "address": "0x45fF03629D024b7763275e732a2d80202c18b31C", "blockNumber": 26276253 }
   },