build.gradle

plugins {
    id 'application'
    id 'java'
    id "edu.sc.seis.macAppBundle" version "2.3.0"
    id 'edu.sc.seis.launch4j' version '2.5.0'
}
mainClassName = 'goistreamtoolredux.Main'
project.version = '1.1.0'

repositories {
    mavenCentral()
    jcenter()
    maven {
        url 'https://apisite.crmyers.dev/maven'
    }
}

dependencies {
    implementation(
            'com.jfoenix:jfoenix:8.0.10',
            'org.controlsfx:controlsfx:8.40.18',
            group: 'de.jensd', name: 'fontawesomefx', version: '8.9', // https://mvnrepository.com/artifact/de.jensd/fontawesomefx
    )

    testImplementation(
            "org.testfx:testfx-core:4.0.16-alpha",
            'org.junit.jupiter:junit-jupiter:5.6.0',
            'org.testfx:testfx-junit5:4.0.16-alpha',
    )
}

macAppBundle {
    mainClassName = "goistreamtoolredux.Main"
    icon = "app-icon.png"
    appName = "GoICasterCompanion"
    volumeName = "GoICC Install"
    dmgName = "GoICC v1.1.0"
    bundleJRE = false
//    backgroundImage = "doc/macbackground.png"
}

launch4j {
    outfile = 'GoICasterCompanion.exe'
    mainClassName = 'goistreamtoolredux.Main'
    icon = "${projectDir}/splash-cropped-256x256.ico"
}



test {
    useJUnitPlatform()
}

jar {
    manifest {
        attributes 'Main-Class': mainClassName
    }
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    exclude 'META-INF/*.RSA'
    exclude 'META-INF/*.SF'
    exclude 'META-INF/*.DSA'
}

task nonFatJar(type: Jar) {
    manifest {
        attributes 'Main-Class': mainClassName
    }
}