diff --git a/nixos/modules/services/desktops/telepathy.nix b/nixos/modules/services/desktops/telepathy.nix
index cfab2c3a413f7..d4aac1aa0c26f 100644
--- a/nixos/modules/services/desktops/telepathy.nix
+++ b/nixos/modules/services/desktops/telepathy.nix
@@ -41,6 +41,7 @@
     # Enable runtime optional telepathy in gnome-shell
     services.xserver.desktopManager.gnome.sessionPath = with pkgs; [
       telepathy-glib
+      telepathy-logger
     ];
   };
 
diff --git a/pkgs/by-name/te/telepathy-logger/package.nix b/pkgs/by-name/te/telepathy-logger/package.nix
new file mode 100644
index 0000000000000..ff8d80cf311e9
--- /dev/null
+++ b/pkgs/by-name/te/telepathy-logger/package.nix
@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  dbus-glib,
+  libxml2,
+  sqlite,
+  telepathy-glib,
+  python3,
+  pkg-config,
+  dconf,
+  makeWrapper,
+  intltool,
+  libxslt,
+  gobject-introspection,
+  dbus,
+  fetchpatch,
+  darwin,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "telepathy-logger";
+  version = "0.8.2";
+
+  src = fetchurl {
+    url = "https://telepathy.freedesktop.org/releases/telepathy-logger/telepathy-logger-${version}.tar.bz2";
+    sha256 = "1bjx85k7jyfi5pvl765fzc7q2iz9va51anrc2djv7caksqsdbjlg";
+  };
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/archlinux/svntogit-packages/raw/2b5bdbb4739d3517f5e7300edc8dab775743b96d/trunk/0001-tools-Fix-the-build-with-Python-3.patch";
+      hash = "sha256-o1lfdZIIqaxn7ntQZnoOMqquc6efTHgSIxB5dpFWRgg=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    makeWrapper
+    pkg-config
+    intltool
+    libxslt
+    gobject-introspection
+    python3
+  ];
+  buildInputs =
+    [
+      dbus-glib
+      libxml2
+      sqlite
+      telepathy-glib
+      dbus
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      darwin.apple_sdk.frameworks.AppKit
+      darwin.apple_sdk.frameworks.Foundation
+    ];
+
+  env.CFLAGS = "-Wno-error=incompatible-pointer-types";
+
+  configureFlags = [ "--enable-call" ];
+
+  preFixup = ''
+    wrapProgram "$out/libexec/telepathy-logger" \
+      --prefix GIO_EXTRA_MODULES : "${lib.getLib dconf}/lib/gio/modules" \
+      --prefix XDG_DATA_DIRS : "$GSETTINGS_SCHEMAS_PATH"
+  '';
+
+  meta = with lib; {
+    description = "Logger service for Telepathy framework";
+    homepage = "https://telepathy.freedesktop.org/components/telepathy-logger/";
+    license = licenses.lgpl21Plus;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/pkgs/top-level/aliases.nix b/pkgs/top-level/aliases.nix
index 64052c41fd930..4dbdb62aa5572 100644
--- a/pkgs/top-level/aliases.nix
+++ b/pkgs/top-level/aliases.nix
@@ -1730,7 +1730,6 @@ mapAliases {
   teamspeak5_client = teamspeak6-client; # Added 2025-01-29
   teck-programmer = throw "teck-programmer was removed because it was broken and unmaintained"; # added 2024-08-23
   telepathy-gabble = throw "'telepathy-gabble' has been removed as it was unmaintained, unused, broken and used outdated libraries"; # Added 2025-04-20
-  telepathy-logger = throw "'telepathy-logger' has been removed as it was unmaintained, unused and broken"; # Added 2025-04-20
   teleport_13 = throw "teleport 13 has been removed as it is EOL. Please upgrade to Teleport 14 or later"; # Added 2024-05-26
   teleport_14 = throw "teleport 14 has been removed as it is EOL. Please upgrade to Teleport 15 or later"; # Added 2024-10-18
   teleport_15 = throw "teleport 15 has been removed as it is EOL. Please upgrade to Teleport 16 or later"; # Added 2025-03-28