From 031afec17f6b20685687894203441fde26cfcb05 Mon Sep 17 00:00:00 2001
From: Claudio Bley <claudio.bley@gmail.com>
Date: Tue, 9 Apr 2024 18:00:35 +0200
Subject: [PATCH] paperjam: init at 1.2.1

Co-authored-by: Anderson Torres <torres.anderson.85@protonmail.com>
(cherry picked from commit e9bc776c6b774006440cb57f5ea26a865cf041cb)
---
 pkgs/by-name/pa/paperjam/package.nix | 50 ++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/pa/paperjam/package.nix

diff --git a/pkgs/by-name/pa/paperjam/package.nix b/pkgs/by-name/pa/paperjam/package.nix
new file mode 100644
index 0000000000000..f71bae04ae813
--- /dev/null
+++ b/pkgs/by-name/pa/paperjam/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  qpdf,
+  libiconv,
+  libpaper,
+  asciidoc,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "paperjam";
+  version = "1.2.1";
+
+  src = fetchurl {
+    url = "https://mj.ucw.cz/download/linux/paperjam-${finalAttrs.version}.tar.gz";
+    hash = "sha256-vTjtNTkBHwfoRDshmFu1zZfGVuEtk2NXH5JdA5Ekg5s=";
+  };
+
+  buildInputs = [
+    qpdf
+    libpaper
+    asciidoc
+  ] ++ lib.optional stdenv.hostPlatform.isDarwin libiconv;
+
+  makeFlags = [
+    "PREFIX=$(out)"
+    # prevent real build date which is impure
+    "BUILD_DATE=\<unknown\>"
+    "BUILD_COMMIT=\<unknown\>"
+  ];
+
+  # provide backward compatible PointerHolder, suppress deprecation warnings
+  env.NIX_CFLAGS_COMPILE = "-DPOINTERHOLDER_TRANSITION=1";
+  env.NIX_LDFLAGS = lib.optionalString stdenv.hostPlatform.isDarwin "-liconv";
+
+  meta = {
+    homepage = "https://mj.ucw.cz/sw/paperjam/";
+    description = "Program for transforming PDF files";
+    longDescription = ''
+      PaperJam is a program for transforming PDF files. It can re-arrange
+      pages, scale and rotate them, put multiple pages on a single sheet, draw
+      cropmarks, and many other tricks.
+    '';
+    license = lib.licenses.gpl2Plus;
+    mainProgram = "paperjam";
+    maintainers = with lib.maintainers; [ cbley ];
+    platforms = lib.platforms.all;
+  };
+})