diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 6588d522f3b69..41bb28ee93173 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -21751,6 +21751,11 @@
     github = "sei40kr";
     githubId = 11665236;
   };
+  seiarotg = {
+    name = "SEIAROTg";
+    github = "SEIAROTg";
+    githubId = 3611446;
+  };
   seineeloquenz = {
     name = "Alexander Linder";
     github = "SeineEloquenz";
diff --git a/pkgs/by-name/go/goshs/package.nix b/pkgs/by-name/go/goshs/package.nix
new file mode 100644
index 0000000000000..890f9eb471067
--- /dev/null
+++ b/pkgs/by-name/go/goshs/package.nix
@@ -0,0 +1,50 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  gitUpdater,
+  stdenv,
+  versionCheckHook,
+  lib,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "goshs";
+  version = "1.0.2";
+
+  src = fetchFromGitHub {
+    owner = "patrickhener";
+    repo = "goshs";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-xq9BqWhUZfk4p5C6d5Eqh98bs0ZDTjpy5KnvhV/9Jew=";
+  };
+
+  vendorHash = "sha256-ECh0K3G6VAAJihqzzlWaEQclfXa0Wp/eFL16ABa7r+0=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+  checkFlags = lib.optionals stdenv.hostPlatform.isDarwin [
+    # utils_test.go:62: route ip+net: no such network interface
+    # does not work in sandbox even with __darwinAllowLocalNetworking
+    "-skip=^TestGetIPv4Addr$"
+  ];
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = {
+    description = "Simple, yet feature-rich web server written in Go";
+    homepage = "https://goshs.de";
+    changelog = "https://github.com/patrickhener/goshs/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      fab
+      matthiasbeyer
+      seiarotg
+    ];
+    mainProgram = "goshs";
+  };
+})