-
Notifications
You must be signed in to change notification settings - Fork 63
/
MatRing.jl
185 lines (155 loc) · 5.7 KB
/
MatRing.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
###############################################################################
#
# MatRing.jl : Generic nxn matrices over rings
#
###############################################################################
###############################################################################
#
# Data type and parent object methods
#
###############################################################################
parent_type(::Type{MatRingElem{T}}) where T <: NCRingElement = MatRing{T}
elem_type(::Type{MatRing{T}}) where {T <: NCRingElement} = MatRingElem{T}
base_ring(a::MatRing{T}) where {T <: NCRingElement} = a.base_ring::parent_type(T)
@doc raw"""
parent(a::MatRingElem{T}) where T <: NCRingElement
Return the parent object of the given matrix.
"""
parent(a::MatRingElem{T}) where T <: NCRingElement = MatRing{T}(base_ring(a), size(a.entries)[1])
is_exact_type(::Type{MatRingElem{T}}) where T <: NCRingElement = is_exact_type(T)
is_domain_type(::Type{MatRingElem{T}}) where T <: NCRingElement = false
###############################################################################
#
# Transpose
#
###############################################################################
function transpose(x::MatRingElem{T}) where T <: NCRingElement
arr = permutedims(x.entries, [2, 1])
z = MatRingElem{T}(base_ring(x), arr)
return z
end
###############################################################################
#
# Solve
#
###############################################################################
function _can_solve_with_solution_lu(M::MatRingElem{T}, B::MatRingElem{T}) where {T <: RingElement}
check_parent(M, B)
R = base_ring(M)
MS = MatSpaceElem{T}(R, M.entries) # convert to ordinary matrix
BS = MatSpaceElem{T}(R, B.entries)
flag, S = _can_solve_with_solution_lu(MS, BS)
SA = MatRingElem{T}(R, S.entries)
return flag, SA
end
function _can_solve_with_solution_fflu(M::MatRingElem{T}, B::MatRingElem{T}) where {T <: RingElement}
check_parent(M, B)
R = base_ring(M)
MS = MatSpaceElem{T}(R, M.entries) # convert to ordinary matrix
BS = MatSpaceElem{T}(R, B.entries)
flag, S, d = _can_solve_with_solution_fflu(MS, BS)
SA = MatRingElem{T}(R, S.entries)
return flag, SA, d
end
###############################################################################
#
# Minimal polynomial
#
###############################################################################
@doc raw"""
minpoly(S::Ring, M::MatRingElem{T}, charpoly_only::Bool = false) where {T <: RingElement}
Return the minimal polynomial $p$ of the matrix $M$. The polynomial ring $S$
of the resulting polynomial must be supplied and the matrix must be square.
"""
function minpoly(S::Ring, M::MatRingElem{T}, charpoly_only::Bool = false) where {T <: RingElement}
MS = MatSpaceElem{T}(base_ring(M), M.entries) # convert to ordinary matrix
return minpoly(S, MS, charpoly_only)
end
function minpoly(M::MatRingElem{T}, charpoly_only::Bool = false) where {T <: RingElement}
R = base_ring(M)
Rx, x = polynomial_ring(R; cached=false)
return minpoly(Rx, M, charpoly_only)
end
###############################################################################
#
# Unsafe operators
#
###############################################################################
function add!(A::MatRingElem{T}, B::MatRingElem{T}) where T <: NCRingElement
A.entries .+= B.entries
return A
end
###############################################################################
#
# Promotion rules
#
###############################################################################
promote_rule(::Type{S}, ::Type{S}) where {T <: NCRingElement, S <: MatRingElem{T}} = MatRingElem{T}
function promote_rule(::Type{S}, ::Type{U}) where {T <: NCRingElement, S <: MatRingElem{T}, U <: NCRingElement}
promote_rule(T, U) == T ? MatRingElem{T} : Union{}
end
###############################################################################
#
# Parent object call overload
#
###############################################################################
function (a::MatRing{T})() where {T <: NCRingElement}
R = base_ring(a)
entries = Matrix{T}(undef, a.n, a.n)
for i = 1:a.n
for j = 1:a.n
entries[i, j] = zero(R)
end
end
z = MatRingElem{T}(R, entries)
return z
end
function (a::MatRing{T})(b::S) where {S <: NCRingElement, T <: NCRingElement}
R = base_ring(a)
entries = Matrix{T}(undef, a.n, a.n)
rb = R(b)
for i = 1:a.n
for j = 1:a.n
if i != j
entries[i, j] = zero(R)
else
entries[i, j] = rb
end
end
end
z = MatRingElem{T}(R, entries)
return z
end
function (a::MatRing{T})(b::MatRingElem{T}) where {T <: NCRingElement}
parent(b) != a && error("Unable to coerce matrix")
return b
end
function (a::MatRing{T})(b::Matrix{S}) where {S <: NCRingElement, T <: NCRingElement}
R = base_ring(a)
_check_dim(a.n, a.n, b)
entries = Matrix{T}(undef, a.n, a.n)
for i = 1:a.n
for j = 1:a.n
entries[i, j] = R(b[i, j])
end
end
z = MatRingElem{T}(R, entries)
return z
end
function (a::MatRing{T})(b::Vector{S}) where {S <: NCRingElement, T <: NCRingElement}
_check_dim(a.n, a.n, b)
b = Matrix{S}(transpose(reshape(b, a.n, a.n)))
z = a(b)
return z
end
###############################################################################
#
# MatRing constructor
#
###############################################################################
function matrix_ring(R::AbstractAlgebra.NCRing, n::Int; cached::Bool = true)
# TODO: the 'cached' argument is ignored and mainly here for backwards compatibility
# (and perhaps future compatibility, in case we need it again)
T = elem_type(R)
return MatRing{T}(R, n)
end