-
Notifications
You must be signed in to change notification settings - Fork 40
/
Reprojucer.cmake
6831 lines (6049 loc) · 239 KB
/
Reprojucer.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# Copyright (C) 2016-2024 Alain Martin
# Copyright (C) 2017 Matthieu Talbot
# Copyright (C) 2018-2019 Scott Wheeler
# Copyright (C) 2022 Thiébaud Fuchs
#
# This file is part of FRUT.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
if(CMAKE_VERSION VERSION_LESS 3.4)
message(FATAL_ERROR "Reprojucer.cmake requires at least CMake version 3.4")
endif()
if(CMAKE_SYSTEM_NAME STREQUAL "iOS" AND CMAKE_VERSION VERSION_LESS 3.14)
message(FATAL_ERROR
"Reprojucer.cmake requires at least CMake version 3.14 for iOS support"
)
endif()
if(IOS AND NOT CMAKE_GENERATOR STREQUAL "Xcode")
message(FATAL_ERROR "Reprojucer.cmake only supports iOS when using the Xcode generator."
" You must call `cmake -G Xcode`."
)
endif()
set(Reprojucer.cmake_DIR "${CMAKE_CURRENT_LIST_DIR}")
set(Reprojucer_data_DIR "${Reprojucer.cmake_DIR}/data")
set(Reprojucer_supported_exporters
"Xcode (macOS)"
"Xcode (iOS)"
"Visual Studio 2022"
"Visual Studio 2019"
"Visual Studio 2017"
"Visual Studio 2015"
"Visual Studio 2013"
"Linux Makefile"
"Code::Blocks (Windows)"
"Code::Blocks (Linux)"
)
set(Reprojucer_supported_exporters_conditions
"APPLE\;AND\;NOT\;IOS"
"IOS"
"MSVC_VERSION\;GREATER\;1929\;AND\;MSVC_VERSION\;LESS\;1950"
"MSVC_VERSION\;GREATER\;1919\;AND\;MSVC_VERSION\;LESS\;1930"
"MSVC_VERSION\;GREATER\;1909\;AND\;MSVC_VERSION\;LESS\;1920"
"MSVC_VERSION\;EQUAL\;1900"
"MSVC_VERSION\;EQUAL\;1800"
"CMAKE_HOST_SYSTEM_NAME\;STREQUAL\;Linux\;AND\;NOT\;CMAKE_EXTRA_GENERATOR\;STREQUAL\;CodeBlocks"
"WIN32\;AND\;NOT\;MSVC"
"CMAKE_HOST_SYSTEM_NAME\;STREQUAL\;Linux\;AND\;CMAKE_EXTRA_GENERATOR\;STREQUAL\;CodeBlocks"
)
function(jucer_project_begin)
set(single_value_keywords
"JUCER_FORMAT_VERSION"
"JUCER_VERSION"
"PROJECT_FILE"
"PROJECT_ID"
)
_FRUT_parse_arguments("${single_value_keywords}" "" "${ARGN}")
if(DEFINED _JUCER_FORMAT_VERSION)
set(JUCER_FORMAT_VERSION "${_JUCER_FORMAT_VERSION}" PARENT_SCOPE)
endif()
if(DEFINED _JUCER_VERSION)
set(JUCER_VERSION "${_JUCER_VERSION}" PARENT_SCOPE)
endif()
if(DEFINED _PROJECT_FILE)
get_filename_component(abs_project_file "${_PROJECT_FILE}" ABSOLUTE)
if(NOT EXISTS "${abs_project_file}")
message(FATAL_ERROR
"No such JUCE project file: \"${_PROJECT_FILE}\" (\"${abs_project_file}\")"
)
endif()
get_filename_component(project_dir "${abs_project_file}" DIRECTORY)
set(JUCER_PROJECT_DIR "${project_dir}" PARENT_SCOPE)
else()
set(JUCER_PROJECT_DIR "${CMAKE_CURRENT_SOURCE_DIR}" PARENT_SCOPE)
endif()
if(DEFINED _PROJECT_ID)
set(JUCER_PROJECT_ID "${_PROJECT_ID}" PARENT_SCOPE)
endif()
endfunction()
function(jucer_project_settings)
set(single_value_keywords
"PROJECT_NAME"
"PROJECT_VERSION"
"COMPANY_NAME"
"COMPANY_COPYRIGHT"
"COMPANY_WEBSITE"
"COMPANY_EMAIL"
"USE_GLOBAL_APPCONFIG_HEADER"
"ADD_USING_NAMESPACE_JUCE_TO_JUCE_HEADER"
"REPORT_JUCE_APP_USAGE"
"DISPLAY_THE_JUCE_SPLASH_SCREEN"
"SPLASH_SCREEN_COLOUR"
"PROJECT_TYPE"
"BUNDLE_IDENTIFIER"
"BINARYDATACPP_SIZE_LIMIT"
"INCLUDE_BINARYDATA"
"BINARYDATA_NAMESPACE"
"CXX_LANGUAGE_STANDARD"
"POST_EXPORT_SHELL_COMMAND_MACOS_LINUX"
"POST_EXPORT_SHELL_COMMAND_WINDOWS"
)
set(multi_value_keywords "PREPROCESSOR_DEFINITIONS" "HEADER_SEARCH_PATHS")
_FRUT_parse_arguments("${single_value_keywords}" "${multi_value_keywords}" "${ARGN}")
if(NOT DEFINED _PROJECT_NAME)
message(FATAL_ERROR "Missing PROJECT_NAME argument")
endif()
if(DEFINED _PROJECT_VERSION)
string(REGEX MATCH ".+\\..+\\..+(\\..+)?" version_match "${_PROJECT_VERSION}")
if(NOT _PROJECT_VERSION STREQUAL version_match)
message(WARNING "The PROJECT_VERSION doesn't seem to be in the format"
" major.minor.point[.point]"
)
endif()
_FRUT_version_to_hex("${_PROJECT_VERSION}" hex_value)
set(JUCER_PROJECT_VERSION_AS_HEX "${hex_value}" PARENT_SCOPE)
endif()
if(NOT DEFINED _PROJECT_TYPE)
message(FATAL_ERROR "Missing PROJECT_TYPE argument")
endif()
set(project_types "GUI Application" "Console Application" "Static Library"
"Dynamic Library" "Audio Plug-in"
)
if(NOT _PROJECT_TYPE IN_LIST project_types)
message(FATAL_ERROR "Unsupported project type: \"${_PROJECT_TYPE}\"\n"
"Supported project types: ${project_types}"
)
endif()
if(DEFINED _BINARYDATACPP_SIZE_LIMIT)
set(size_limit_descs "Default" "20.0 MB" "10.0 MB" "6.0 MB" "2.0 MB" "1.0 MB"
"512.0 KB" "256.0 KB" "128.0 KB" "64.0 KB"
)
set(size_limits 10240 20480 10240 6144 2048 1024 512 256 128 64)
list(FIND size_limit_descs "${_BINARYDATACPP_SIZE_LIMIT}" size_limit_index)
if(size_limit_index EQUAL -1)
message(FATAL_ERROR "Unsupported value for BINARYDATACPP_SIZE_LIMIT:"
" \"${_BINARYDATACPP_SIZE_LIMIT}\"\nSupported values: ${size_limit_descs}"
)
endif()
list(GET size_limits ${size_limit_index} _BINARYDATACPP_SIZE_LIMIT)
endif()
if(DEFINED _CXX_LANGUAGE_STANDARD)
set(cxx_lang_standard_descs "C++11" "C++14" "C++17" "C++20" "Use Latest")
set(cxx_lang_standards "11" "14" "17" "20" "latest")
list(FIND cxx_lang_standard_descs "${_CXX_LANGUAGE_STANDARD}" cxx_lang_standard_index)
if(cxx_lang_standard_index EQUAL -1)
message(FATAL_ERROR "Unsupported value for CXX_LANGUAGE_STANDARD:"
" \"${_CXX_LANGUAGE_STANDARD}\"\nSupported values: ${cxx_lang_standard_descs}"
)
endif()
list(GET cxx_lang_standards ${cxx_lang_standard_index} _CXX_LANGUAGE_STANDARD)
endif()
if(DEFINED _POST_EXPORT_SHELL_COMMAND_MACOS_LINUX
OR DEFINED _POST_EXPORT_SHELL_COMMAND_WINDOWS)
option(JUCER_RUN_POST_EXPORT_SHELL_COMMANDS
"If ON, run Post-Export Shell Commands of JUCE projects"
)
endif()
foreach(keyword IN LISTS single_value_keywords multi_value_keywords)
if(DEFINED _${keyword})
set(JUCER_${keyword} "${_${keyword}}" PARENT_SCOPE)
endif()
endforeach()
endfunction()
function(jucer_audio_plugin_settings)
set(plugin_formats_keywords
"BUILD_VST"
"BUILD_VST3"
"BUILD_AUDIOUNIT"
"BUILD_AUDIOUNIT_V3"
"BUILD_RTAS"
"BUILD_AAX"
"BUILD_STANDALONE_PLUGIN"
"BUILD_UNITY_PLUGIN"
"ENABLE_INTER_APP_AUDIO"
)
set(plugin_characteristics_keywords
"PLUGIN_IS_A_SYNTH"
"PLUGIN_MIDI_INPUT"
"PLUGIN_MIDI_OUTPUT"
"MIDI_EFFECT_PLUGIN"
"KEY_FOCUS"
)
set(single_value_keywords
${plugin_formats_keywords}
"PLUGIN_NAME"
"PLUGIN_DESCRIPTION"
"PLUGIN_MANUFACTURER"
"PLUGIN_MANUFACTURER_CODE"
"PLUGIN_CODE"
"PLUGIN_CHANNEL_CONFIGURATIONS"
${plugin_characteristics_keywords}
"PLUGIN_AAX_IDENTIFIER"
"PLUGIN_AU_EXPORT_PREFIX"
"PLUGIN_AU_MAIN_TYPE"
"PLUGIN_AU_IS_SANDBOX_SAFE"
"PLUGIN_VST_NUM_MIDI_INPUTS"
"PLUGIN_VST_NUM_MIDI_OUTPUTS"
"PLUGIN_VST_LEGACY_CATEGORY"
"PLUGIN_VST_CATEGORY"
"VST_CATEGORY"
)
set(multi_value_keywords
"PLUGIN_FORMATS"
"PLUGIN_CHARACTERISTICS"
"PLUGIN_VST3_CATEGORY"
"PLUGIN_RTAS_CATEGORY"
"PLUGIN_AAX_CATEGORY"
)
_FRUT_parse_arguments("${single_value_keywords}" "${multi_value_keywords}" "${ARGN}")
if(DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.0.0)
if(DEFINED _BUILD_STANDALONE_PLUGIN)
message(WARNING "BUILD_STANDALONE_PLUGIN is a JUCE 5 feature only")
endif()
if(DEFINED _ENABLE_INTER_APP_AUDIO)
message(WARNING "ENABLE_INTER_APP_AUDIO is a JUCE 5 feature only")
endif()
endif()
if(DEFINED _PLUGIN_FORMATS)
set(plugin_formats_vars ${plugin_formats_keywords} "BUILD_VST")
set(plugin_formats_values "VST" "VST3" "AU" "AUv3" "RTAS" "AAX" "Standalone"
"Unity" "Enable IAA" "VST (Legacy)"
)
foreach(index RANGE 9)
list(GET plugin_formats_vars ${index} format_var)
if(NOT DEFINED _${format_var})
list(GET plugin_formats_values ${index} format_value)
if(format_value IN_LIST _PLUGIN_FORMATS)
set(_${format_var} ON)
endif()
endif()
endforeach()
endif()
if(DEFINED _PLUGIN_CHARACTERISTICS)
set(extra_rtas_aax_keywords
"PLUGIN_RTAS_DISABLE_BYPASS"
"PLUGIN_AAX_DISABLE_BYPASS"
"PLUGIN_RTAS_DISABLE_MULTI_MONO"
"PLUGIN_AAX_DISABLE_MULTI_MONO"
)
list(APPEND single_value_keywords ${extra_rtas_aax_keywords})
set(plugin_characteristics_vars
${plugin_characteristics_keywords}
${extra_rtas_aax_keywords}
)
set(plugin_characteristics_values
"Plugin is a Synth"
"Plugin MIDI Input"
"Plugin MIDI Output"
"MIDI Effect Plugin"
"Plugin Editor Requires Keyboard Focus"
"Disable RTAS Bypass"
"Disable AAX Bypass"
"Disable RTAS Multi-Mono"
"Disable AAX Multi-Mono"
)
foreach(index RANGE 8)
list(GET plugin_characteristics_vars ${index} characteristic_var)
if(NOT DEFINED _${characteristic_var})
list(GET plugin_characteristics_values ${index} characteristic_value)
if(characteristic_value IN_LIST _PLUGIN_CHARACTERISTICS)
set(_${characteristic_var} ON)
endif()
endif()
endforeach()
endif()
if(DEFINED _VST_CATEGORY)
if(NOT (DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.3.1))
message(WARNING "VST_CATEGORY is deprecated. Use PLUGIN_VST_CATEGORY instead.")
endif()
endif()
foreach(keyword IN LISTS single_value_keywords multi_value_keywords)
if(DEFINED _${keyword})
set(JUCER_${keyword} "${_${keyword}}" PARENT_SCOPE)
endif()
endforeach()
endfunction()
function(jucer_project_files source_group_name)
function(_FRUT_jucer_project_files_assert_x_or_dot input row_number property)
if(NOT input STREQUAL "x" AND NOT input STREQUAL ".")
message(FATAL_ERROR "Expected \"x\" or \".\" token for \"${property}\", got"
" \"${input}\" instead (row ${row_number})"
)
endif()
endfunction()
set(files "")
set(compiler_flag_schemes "")
unset(compile)
unset(xcode_resource)
unset(binary_resource)
unset(path)
set(row 1)
foreach(argument IN LISTS ARGN)
if(NOT DEFINED compile)
_FRUT_jucer_project_files_assert_x_or_dot("${argument}" ${row} "Compile")
set(compile "${argument}")
elseif(NOT DEFINED xcode_resource)
_FRUT_jucer_project_files_assert_x_or_dot("${argument}" ${row} "Xcode Resource")
set(xcode_resource "${argument}")
elseif(NOT DEFINED binary_resource)
_FRUT_jucer_project_files_assert_x_or_dot("${argument}" ${row} "Binary Resource")
set(binary_resource "${argument}")
elseif(NOT DEFINED path)
if(argument STREQUAL "x" OR argument STREQUAL ".")
message(FATAL_ERROR
"Expected path for \"File\", got \"${argument}\" instead (row ${row})"
)
endif()
set(path "${argument}")
_FRUT_abs_path_based_on_jucer_project_dir(path "${path}")
if(compile STREQUAL "x" OR xcode_resource STREQUAL ".")
list(APPEND files "${path}")
elseif(xcode_resource STREQUAL "x")
list(APPEND JUCER_PROJECT_XCODE_RESOURCES "${path}")
endif()
if(binary_resource STREQUAL "x")
list(APPEND JUCER_PROJECT_RESOURCES "${path}")
endif()
get_filename_component(file_extension "${path}" EXT)
if((NOT file_extension STREQUAL ".h" AND compile STREQUAL ".")
OR (file_extension STREQUAL ".mm" AND NOT APPLE))
set_source_files_properties("${path}" PROPERTIES HEADER_FILE_ONLY TRUE)
endif()
else()
if(argument STREQUAL "x" OR argument STREQUAL ".")
set(compile "${argument}")
else()
set(scheme "${argument}")
list(APPEND compiler_flag_schemes "${scheme}")
list(APPEND JUCER_COMPILER_FLAG_SCHEME_${scheme}_FILES "${path}")
unset(compile)
endif()
unset(xcode_resource)
unset(binary_resource)
unset(path)
math(EXPR row "${row} + 1")
endif()
endforeach()
string(REPLACE "/" "\\" source_group_name ${source_group_name})
source_group(${source_group_name} FILES ${files})
list(APPEND JUCER_PROJECT_FILES ${files})
set(JUCER_PROJECT_FILES "${JUCER_PROJECT_FILES}" PARENT_SCOPE)
set(JUCER_PROJECT_RESOURCES "${JUCER_PROJECT_RESOURCES}" PARENT_SCOPE)
set(JUCER_PROJECT_XCODE_RESOURCES "${JUCER_PROJECT_XCODE_RESOURCES}" PARENT_SCOPE)
list(APPEND JUCER_COMPILER_FLAG_SCHEMES "${compiler_flag_schemes}")
list(REMOVE_DUPLICATES JUCER_COMPILER_FLAG_SCHEMES)
set(JUCER_COMPILER_FLAG_SCHEMES "${JUCER_COMPILER_FLAG_SCHEMES}" PARENT_SCOPE)
foreach(scheme IN LISTS compiler_flag_schemes)
set(JUCER_COMPILER_FLAG_SCHEME_${scheme}_FILES
"${JUCER_COMPILER_FLAG_SCHEME_${scheme}_FILES}" PARENT_SCOPE
)
endforeach()
endfunction()
function(jucer_project_module module_name PATH_KEYWORD modules_folder)
if(NOT PATH_KEYWORD STREQUAL "PATH")
message(FATAL_ERROR "Invalid second argument. Expected \"PATH\" keyword, but got"
" \"${PATH_KEYWORD}\" instead."
)
endif()
_FRUT_abs_path_based_on_jucer_project_dir(modules_folder "${modules_folder}")
if(NOT IS_DIRECTORY "${modules_folder}")
message(FATAL_ERROR "No such directory: \"${modules_folder}\"")
endif()
set(module_dir "${modules_folder}/${module_name}")
foreach(extension IN ITEMS ".h" ".hpp" ".hxx")
set(module_header_file "${module_dir}/${module_name}${extension}")
if(EXISTS "${module_header_file}")
break()
endif()
endforeach()
if(NOT EXISTS "${module_header_file}")
message(FATAL_ERROR "\"${module_dir}/\" is not a valid JUCE module")
endif()
set(make_juce_code_browsable ON)
set(extra_keywords "")
unset(keyword)
foreach(argument IN LISTS ARGN)
if(NOT DEFINED keyword)
set(keyword "${argument}")
if(NOT keyword STREQUAL "ADD_SOURCE_TO_PROJECT")
list(APPEND extra_keywords "${keyword}")
endif()
else()
set(value "${argument}")
if(keyword STREQUAL "ADD_SOURCE_TO_PROJECT")
set(make_juce_code_browsable "${value}")
else()
set(extra_values_${keyword} "${value}")
endif()
unset(keyword)
endif()
endforeach()
foreach(keyword IN LISTS extra_keywords)
if(NOT DEFINED extra_values_${keyword})
message(WARNING "Keyword \"${keyword}\" doesn't have any associated value")
endif()
endforeach()
list(APPEND JUCER_PROJECT_MODULES ${module_name})
set(JUCER_PROJECT_MODULES "${JUCER_PROJECT_MODULES}" PARENT_SCOPE)
list(APPEND JUCER_PROJECT_MODULES_FOLDERS "${modules_folder}")
set(JUCER_PROJECT_MODULES_FOLDERS "${JUCER_PROJECT_MODULES_FOLDERS}" PARENT_SCOPE)
set(JUCER_PROJECT_MODULE_${module_name}_PATH "${modules_folder}" PARENT_SCOPE)
file(GLOB module_src_files
LIST_DIRECTORIES FALSE
"${module_dir}/${module_name}*.cpp"
"${module_dir}/${module_name}*.mm"
"${module_dir}/${module_name}*.r"
)
if(DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.0.0)
set(proxy_prefix "")
else()
set(proxy_prefix "include_")
endif()
if(DEFINED JUCER_USE_GLOBAL_APPCONFIG_HEADER AND NOT JUCER_USE_GLOBAL_APPCONFIG_HEADER)
set(appconfig_include "")
else()
set(appconfig_include "#include \"AppConfig.h\"\n")
endif()
set(can_build_vst3 FALSE)
if((APPLE AND NOT IOS) OR MSVC)
set(can_build_vst3 TRUE)
elseif(
NOT (DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 6.0.0)
AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Linux"
)
set(can_build_vst3 TRUE)
endif()
set(module_sources "")
foreach(src_file IN LISTS module_src_files)
unset(to_compile)
if( (src_file MATCHES "_AU[._]" AND NOT (JUCER_BUILD_AUDIOUNIT AND (APPLE AND NOT IOS)))
OR (src_file MATCHES "_AUv3[._]" AND NOT (JUCER_BUILD_AUDIOUNIT_V3 AND APPLE))
OR (src_file MATCHES "_AAX[._]" AND NOT (JUCER_BUILD_AAX AND ((APPLE AND NOT IOS) OR MSVC)))
OR (src_file MATCHES "_RTAS[._]" AND NOT (JUCER_BUILD_RTAS AND ((APPLE AND NOT IOS) OR MSVC)))
OR (src_file MATCHES "_VST2[._]" AND NOT (JUCER_BUILD_VST AND NOT IOS))
OR (src_file MATCHES "_VST3[._]" AND NOT (JUCER_BUILD_VST3 AND can_build_vst3))
)
set(to_compile FALSE)
endif()
if(DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.0.0)
if(src_file MATCHES "_Standalone[._]" AND NOT (JUCER_BUILD_AUDIOUNIT_V3 AND APPLE))
set(to_compile FALSE)
endif()
else()
if(src_file MATCHES "_Standalone[._]" AND NOT JUCER_BUILD_STANDALONE_PLUGIN)
set(to_compile FALSE)
endif()
endif()
if(NOT (DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.3.2))
if(src_file MATCHES "_Unity[._]" AND NOT JUCER_BUILD_UNITY_PLUGIN)
set(to_compile FALSE)
endif()
endif()
if(NOT DEFINED to_compile)
get_filename_component(src_file_extension "${src_file}" EXT)
if(src_file_extension STREQUAL ".mm")
if(APPLE)
set(to_compile TRUE)
endif()
elseif(APPLE)
string(REGEX REPLACE "${src_file_extension}$" ".mm" objcxx_src_file "${src_file}")
if(NOT objcxx_src_file IN_LIST module_src_files)
set(to_compile TRUE)
endif()
else()
set(to_compile TRUE)
endif()
endif()
if(to_compile)
get_filename_component(src_file_basename "${src_file}" NAME)
if(src_file_extension STREQUAL ".r")
set(proxied_src_file "${src_file_basename}")
else()
set(proxied_src_file "${module_name}/${src_file_basename}")
endif()
configure_file("${Reprojucer_data_DIR}/JuceLibraryCode-Wrapper.cpp.in"
"JuceLibraryCode/${proxy_prefix}${src_file_basename}" @ONLY
)
list(APPEND module_sources
"${CMAKE_CURRENT_BINARY_DIR}/JuceLibraryCode/${proxy_prefix}${src_file_basename}"
)
endif()
endforeach()
set(JUCER_PROJECT_MODULE_${module_name}_SOURCES "${module_sources}" PARENT_SCOPE)
file(STRINGS "${module_header_file}" config_flags_lines REGEX "/\\*\\* Config: ")
string(REPLACE "/** Config: " "" module_config_flags "${config_flags_lines}")
set(JUCER_${module_name}_CONFIG_FLAGS "${module_config_flags}" PARENT_SCOPE)
foreach(config_flag IN LISTS extra_keywords)
if(NOT config_flag IN_LIST module_config_flags)
message(WARNING "Unknown config flag ${config_flag} in module ${module_name}")
endif()
set(JUCER_FLAG_${config_flag} "${extra_values_${config_flag}}" PARENT_SCOPE)
endforeach()
unset(module_info_version)
set(module_info_searchpaths "")
set(module_info_OSXFrameworks "")
set(module_info_WeakOSXFrameworks "")
set(module_info_iOSFrameworks "")
set(module_info_WeakiOSFrameworks "")
set(module_info_linuxPackages "")
set(module_info_linuxLibs "")
set(module_info_mingwLibs "")
set(module_info_OSXLibs "")
set(module_info_iOSLibs "")
set(module_info_windowsLibs "")
unset(module_info_minimumCppStandard)
file(STRINGS "${module_header_file}" all_lines)
set(in_module_declaration FALSE)
foreach(line IN LISTS all_lines)
string(STRIP "${line}" stripped_line)
if(stripped_line MATCHES "^BEGIN_JUCE_MODULE_DECLARATION")
set(in_module_declaration TRUE)
continue()
elseif(stripped_line MATCHES "^END_JUCE_MODULE_DECLARATION")
break()
endif()
if(in_module_declaration)
string(FIND "${line}" ":" colon_pos)
if(NOT colon_pos EQUAL -1)
string(SUBSTRING "${line}" 0 ${colon_pos} key)
string(STRIP "${key}" key)
math(EXPR colon_pos_plus_one "${colon_pos} + 1")
string(SUBSTRING "${line}" ${colon_pos_plus_one} -1 value)
string(STRIP "${value}" value)
set(module_info_${key} "${value}")
endif()
endif()
endforeach()
set(JUCER_PROJECT_MODULE_${module_name}_VERSION "${module_info_version}" PARENT_SCOPE)
string(REGEX REPLACE "[ ,]+" ";" search_paths "${module_info_searchpaths}")
foreach(search_path IN LISTS search_paths)
list(APPEND JUCER_PROJECT_MODULES_INTERNAL_SEARCH_PATHS
"${module_dir}/${search_path}"
)
endforeach()
set(JUCER_PROJECT_MODULES_INTERNAL_SEARCH_PATHS
"${JUCER_PROJECT_MODULES_INTERNAL_SEARCH_PATHS}" PARENT_SCOPE
)
if(IOS)
string(REGEX REPLACE "[ ,]+" ";" xcode_frameworks "${module_info_iOSFrameworks}")
string(REGEX REPLACE "[ ,]+" ";" xcode_weak_frameworks "${module_info_WeakiOSFrameworks}")
else()
string(REGEX REPLACE "[ ,]+" ";" xcode_frameworks "${module_info_OSXFrameworks}")
string(REGEX REPLACE "[ ,]+" ";" xcode_weak_frameworks "${module_info_WeakOSXFrameworks}")
endif()
list(APPEND JUCER_PROJECT_XCODE_FRAMEWORKS ${xcode_frameworks})
set(JUCER_PROJECT_XCODE_FRAMEWORKS "${JUCER_PROJECT_XCODE_FRAMEWORKS}" PARENT_SCOPE)
list(APPEND JUCER_PROJECT_XCODE_WEAK_FRAMEWORKS ${xcode_weak_frameworks})
set(JUCER_PROJECT_XCODE_WEAK_FRAMEWORKS "${JUCER_PROJECT_XCODE_WEAK_FRAMEWORKS}" PARENT_SCOPE)
string(REGEX REPLACE "[ ,]+" ";" linux_packages "${module_info_linuxPackages}")
list(APPEND JUCER_PROJECT_LINUX_PACKAGES ${linux_packages})
set(JUCER_PROJECT_LINUX_PACKAGES "${JUCER_PROJECT_LINUX_PACKAGES}" PARENT_SCOPE)
string(REGEX REPLACE "[ ,]+" ";" linux_libs "${module_info_linuxLibs}")
list(APPEND JUCER_PROJECT_LINUX_LIBS ${linux_libs})
set(JUCER_PROJECT_LINUX_LIBS "${JUCER_PROJECT_LINUX_LIBS}" PARENT_SCOPE)
string(REGEX REPLACE "[ ,]+" ";" mingw_libs "${module_info_mingwLibs}")
list(APPEND JUCER_PROJECT_MINGW_LIBS ${mingw_libs})
set(JUCER_PROJECT_MINGW_LIBS "${JUCER_PROJECT_MINGW_LIBS}" PARENT_SCOPE)
if(IOS)
string(REGEX REPLACE "[ ,]+" ";" xcode_libs "${module_info_iOSLibs}")
else()
string(REGEX REPLACE "[ ,]+" ";" xcode_libs "${module_info_OSXLibs}")
endif()
list(APPEND JUCER_PROJECT_XCODE_LIBS ${xcode_libs})
set(JUCER_PROJECT_XCODE_LIBS "${JUCER_PROJECT_XCODE_LIBS}" PARENT_SCOPE)
string(REGEX REPLACE "[ ,]+" ";" windows_libs "${module_info_windowsLibs}")
list(APPEND JUCER_PROJECT_WINDOWS_LIBS ${windows_libs})
set(JUCER_PROJECT_WINDOWS_LIBS "${JUCER_PROJECT_WINDOWS_LIBS}" PARENT_SCOPE)
if(DEFINED module_info_minimumCppStandard)
unset(project_cxx_standard)
if(DEFINED JUCER_CXX_LANGUAGE_STANDARD)
set(project_cxx_standard "${JUCER_CXX_LANGUAGE_STANDARD}")
elseif(DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.1.0)
# "C++ Language Standard" didn't exist before JUCE version 5.1.0
elseif(DEFINED JUCER_VERSION AND JUCER_VERSION VERSION_LESS 5.2.1)
set(project_cxx_standard 11)
else()
set(project_cxx_standard 14)
endif()
if(DEFINED project_cxx_standard AND NOT (project_cxx_standard STREQUAL "latest")
AND (module_info_minimumCppStandard STREQUAL "latest"
OR module_info_minimumCppStandard GREATER project_cxx_standard))
message(WARNING "${module_name} has a higher C++ language standard requirement"
" (${module_info_minimumCppStandard}) than your project"
" (${project_cxx_standard}). To use this module you need to increase the C++"
" language standard of the project."
)
endif()
endif()
if(make_juce_code_browsable)
file(GLOB_RECURSE browsable_files "${module_dir}/*")
foreach(file_path IN LISTS browsable_files)
get_filename_component(file_dir "${file_path}" DIRECTORY)
string(REPLACE "${modules_folder}" "" rel_file_dir "${file_dir}")
string(REPLACE "/" "\\" sub_group_name "${rel_file_dir}")
source_group("JUCE Modules${sub_group_name}" FILES "${file_path}")
endforeach()
list(APPEND JUCER_PROJECT_MODULES_BROWSABLE_FILES ${browsable_files})
set(JUCER_PROJECT_MODULES_BROWSABLE_FILES "${JUCER_PROJECT_MODULES_BROWSABLE_FILES}"
PARENT_SCOPE
)
endif()
if(CMAKE_HOST_SYSTEM_NAME STREQUAL "Linux")
set(module_lib_dir "${module_dir}/libs/Linux")
elseif(WIN32 AND NOT MSVC)
set(module_lib_dir "${module_dir}/libs/MinGW")
elseif(IOS)
set(module_lib_dir "${module_dir}/libs/iOS")
elseif(APPLE)
set(module_lib_dir "${module_dir}/libs/MacOSX")
elseif(MSVC)
if(MSVC_VERSION GREATER 1929 AND MSVC_VERSION LESS 1940)
set(module_lib_dir "${module_dir}/libs/VisualStudio2022")
elseif(MSVC_VERSION GREATER 1919 AND MSVC_VERSION LESS 1930)
set(module_lib_dir "${module_dir}/libs/VisualStudio2019")
elseif(MSVC_VERSION GREATER 1909 AND MSVC_VERSION LESS 1920)
set(module_lib_dir "${module_dir}/libs/VisualStudio2017")
elseif(MSVC_VERSION EQUAL 1900)
set(module_lib_dir "${module_dir}/libs/VisualStudio2015")
elseif(MSVC_VERSION EQUAL 1800)
set(module_lib_dir "${module_dir}/libs/VisualStudio2013")
endif()
endif()
if(IS_DIRECTORY "${module_lib_dir}")
list(APPEND JUCER_PROJECT_MODULES_LIBRARY_SEARCH_PATHS "${module_lib_dir}")
set(JUCER_PROJECT_MODULES_LIBRARY_SEARCH_PATHS
"${JUCER_PROJECT_MODULES_LIBRARY_SEARCH_PATHS}" PARENT_SCOPE
)
endif()
endfunction()
function(jucer_appconfig_header USER_CODE_SECTION_KEYWORD user_code_section)
if(NOT USER_CODE_SECTION_KEYWORD STREQUAL "USER_CODE_SECTION")
message(FATAL_ERROR "Invalid second argument. Expected \"USER_CODE_SECTION\" keyword,"
" but got \"${USER_CODE_SECTION_KEYWORD}\" instead."
)
endif()
set(JUCER_APPCONFIG_USER_CODE_SECTION "${user_code_section}" PARENT_SCOPE)
endfunction()
function(jucer_export_target exporter)
if(exporter STREQUAL "Xcode (MacOSX)")
set(exporter "Xcode (macOS)")
endif()
if(NOT exporter IN_LIST Reprojucer_supported_exporters)
message(FATAL_ERROR "Unsupported exporter: ${exporter}\n"
"Supported exporters: ${Reprojucer_supported_exporters}"
)
endif()
list(APPEND JUCER_PROJECT_EXPORT_TARGETS "${exporter}")
set(JUCER_PROJECT_EXPORT_TARGETS "${JUCER_PROJECT_EXPORT_TARGETS}" PARENT_SCOPE)
list(FIND Reprojucer_supported_exporters "${exporter}" exporter_index)
list(GET Reprojucer_supported_exporters_conditions ${exporter_index} condition)
if(NOT (${condition}))
return()
endif()
set(single_value_keywords "TARGET_PROJECT_FOLDER" "ICON_SMALL" "ICON_LARGE")
set(multi_value_keywords
"EXTRA_PREPROCESSOR_DEFINITIONS"
"EXTRA_COMPILER_FLAGS"
"EXTRA_LINKER_FLAGS"
"EXTERNAL_LIBRARIES_TO_LINK"
)
if(exporter STREQUAL "Xcode (macOS)" OR exporter STREQUAL "Xcode (iOS)")
list(APPEND single_value_keywords
"USE_LEGACY_BUILD_SYSTEM"
"MICROPHONE_ACCESS"
"MICROPHONE_ACCESS_TEXT"
"CAMERA_ACCESS"
"CAMERA_ACCESS_TEXT"
"BLUETOOTH_ACCESS"
"BLUETOOTH_ACCESS_TEXT"
"IN_APP_PURCHASES_CAPABILITY"
"PUSH_NOTIFICATIONS_CAPABILITY"
"CUSTOM_PLIST"
"PLIST_PREPROCESS"
"PLIST_PREFIX_HEADER"
"SUPPRESS_AUDIOUNIT_PLIST_RESOURCE_USAGE_KEY"
"PREBUILD_SHELL_SCRIPT"
"POSTBUILD_SHELL_SCRIPT"
"EXPORTER_BUNDLE_IDENTIFIER"
"DEVELOPMENT_TEAM_ID"
"KEEP_CUSTOM_XCODE_SCHEMES"
"USE_HEADERMAP"
)
list(APPEND multi_value_keywords
"CUSTOM_XCODE_RESOURCE_FOLDERS"
"EXTRA_SYSTEM_FRAMEWORKS"
"EXTRA_FRAMEWORKS"
"FRAMEWORK_SEARCH_PATHS"
"EXTRA_CUSTOM_FRAMEWORKS"
"EMBEDDED_FRAMEWORKS"
"XCODE_SUBPROJECTS"
)
if(JUCER_PROJECT_TYPE STREQUAL "Audio Plug-in")
list(APPEND single_value_keywords "ADD_DUPLICATE_RESOURCES_FOLDER_TO_APP_EXTENSION")
endif()
endif()
if(exporter STREQUAL "Xcode (macOS)")
list(APPEND single_value_keywords
"VST3_SDK_FOLDER"
"AAX_SDK_FOLDER"
"RTAS_SDK_FOLDER"
"USE_APP_SANDBOX"
"APP_SANDBOX_INHERITANCE"
"USE_HARDENED_RUNTIME"
"SEND_APPLE_EVENTS"
"SEND_APPLE_EVENTS_TEXT"
)
list(APPEND multi_value_keywords
"VALID_ARCHITECTURES"
"APP_SANDBOX_OPTIONS"
"HARDENED_RUNTIME_OPTIONS"
)
if(JUCER_PROJECT_TYPE STREQUAL "GUI Application")
list(APPEND multi_value_keywords "DOCUMENT_FILE_EXTENSIONS")
endif()
endif()
if(exporter STREQUAL "Xcode (iOS)")
list(APPEND single_value_keywords
"CUSTOM_XCASSETS_FOLDER"
"CUSTOM_LAUNCH_STORYBOARD"
"DEVICE_FAMILY"
"FILE_SHARING_ENABLED"
"SUPPORT_DOCUMENT_BROWSER"
"STATUS_BAR_HIDDEN"
"REQUIRES_FULL_SCREEN"
"CONTENT_SHARING"
"AUDIO_BACKGROUND_CAPABILITY"
"BLUETOOTH_MIDI_BACKGROUND_CAPABILITY"
"APP_GROUPS_CAPABILITY"
"ICLOUD_PERMISSIONS"
)
list(APPEND multi_value_keywords
"IPHONE_SCREEN_ORIENTATION"
"IPAD_SCREEN_ORIENTATION"
"APP_GROUP_ID"
)
else()
list(APPEND single_value_keywords "VST_LEGACY_SDK_FOLDER" "VST_SDK_FOLDER")
endif()
if(exporter MATCHES "^Visual Studio 20(22|1[9753])$")
list(APPEND single_value_keywords
"VST3_SDK_FOLDER"
"AAX_SDK_FOLDER"
"RTAS_SDK_FOLDER"
"MANIFEST_FILE"
"PLATFORM_TOOLSET"
"USE_IPP_LIBRARY"
"USE_IPP_LIBRARY_ONE_API"
"USE_MKL_LIBRARY_ONE_API"
"WINDOWS_TARGET_PLATFORM"
)
if(exporter STREQUAL "Visual Studio 2017")
list(APPEND single_value_keywords "CXX_STANDARD_TO_USE")
endif()
else()
list(APPEND single_value_keywords "GNU_COMPILER_EXTENSIONS")
endif()
if(exporter STREQUAL "Linux Makefile")
list(APPEND single_value_keywords "CXX_STANDARD_TO_USE")
list(APPEND multi_value_keywords "PKGCONFIG_LIBRARIES")
endif()
if(exporter STREQUAL "Code::Blocks (Windows)")
list(APPEND single_value_keywords "TARGET_PLATFORM")
endif()
set(compiler_flags_for__prefixed_keywords "")
foreach(argument IN LISTS ARGN)
if(argument MATCHES "^COMPILER_FLAGS_FOR_([A-Za-z0-9_]+)$")
list(APPEND compiler_flags_for__prefixed_keywords "${argument}")
list(APPEND single_value_keywords "${argument}")
endif()
endforeach()
_FRUT_parse_arguments("${single_value_keywords}" "${multi_value_keywords}" "${ARGN}")
if(DEFINED _TARGET_PROJECT_FOLDER)
file(TO_CMAKE_PATH "${_TARGET_PROJECT_FOLDER}" project_folder)
_FRUT_abs_path_based_on_jucer_project_dir(project_folder "${project_folder}")
set(JUCER_TARGET_PROJECT_FOLDER "${project_folder}" PARENT_SCOPE)
endif()
if(DEFINED _VST_LEGACY_SDK_FOLDER)
file(TO_CMAKE_PATH "${_VST_LEGACY_SDK_FOLDER}" sdk_folder)
_FRUT_abs_path_based_on_jucer_project_dir(sdk_folder "${sdk_folder}")
set(JUCER_VST_LEGACY_SDK_FOLDER "${sdk_folder}" PARENT_SCOPE)
endif()
if(DEFINED _VST_SDK_FOLDER)
file(TO_CMAKE_PATH "${_VST_SDK_FOLDER}" sdk_folder)
_FRUT_abs_path_based_on_jucer_project_dir(sdk_folder "${sdk_folder}")
set(JUCER_VST_SDK_FOLDER "${sdk_folder}" PARENT_SCOPE)
endif()
if(DEFINED _VST3_SDK_FOLDER)
file(TO_CMAKE_PATH "${_VST3_SDK_FOLDER}" sdk_folder)
_FRUT_abs_path_based_on_jucer_project_dir(sdk_folder "${sdk_folder}")
set(JUCER_VST3_SDK_FOLDER "${sdk_folder}" PARENT_SCOPE)
endif()
if(DEFINED _AAX_SDK_FOLDER)
file(TO_CMAKE_PATH "${_AAX_SDK_FOLDER}" sdk_folder)
_FRUT_abs_path_based_on_jucer_project_dir(sdk_folder "${sdk_folder}")
set(JUCER_AAX_SDK_FOLDER "${sdk_folder}" PARENT_SCOPE)
endif()
if(DEFINED _RTAS_SDK_FOLDER)
file(TO_CMAKE_PATH "${_RTAS_SDK_FOLDER}" sdk_folder)
_FRUT_abs_path_based_on_jucer_project_dir(sdk_folder "${sdk_folder}")
set(JUCER_RTAS_SDK_FOLDER "${sdk_folder}" PARENT_SCOPE)
endif()
if(DEFINED _EXTRA_PREPROCESSOR_DEFINITIONS)
set(JUCER_EXTRA_PREPROCESSOR_DEFINITIONS "${_EXTRA_PREPROCESSOR_DEFINITIONS}"
PARENT_SCOPE
)
endif()
if(DEFINED _EXTRA_COMPILER_FLAGS)
set(JUCER_EXTRA_COMPILER_FLAGS "${_EXTRA_COMPILER_FLAGS}" PARENT_SCOPE)
endif()
foreach(keyword IN LISTS compiler_flags_for__prefixed_keywords)
if(DEFINED _${keyword})
set(JUCER_${keyword} "${_${keyword}}" PARENT_SCOPE)
endif()
endforeach()
if(DEFINED _EXTRA_LINKER_FLAGS)
set(JUCER_EXTRA_LINKER_FLAGS "${_EXTRA_LINKER_FLAGS}" PARENT_SCOPE)
endif()
if(DEFINED _EXTERNAL_LIBRARIES_TO_LINK)
set(JUCER_EXTERNAL_LIBRARIES_TO_LINK "${_EXTERNAL_LIBRARIES_TO_LINK}" PARENT_SCOPE)
endif()
if(DEFINED _GNU_COMPILER_EXTENSIONS)
set(JUCER_GNU_COMPILER_EXTENSIONS "${_GNU_COMPILER_EXTENSIONS}" PARENT_SCOPE)
endif()
if(DEFINED _ICON_SMALL)
if(NOT _ICON_SMALL STREQUAL "<None>")
_FRUT_abs_path_based_on_jucer_project_dir(small_icon "${_ICON_SMALL}")
if(NOT EXISTS "${small_icon}")
message(FATAL_ERROR
"No such file (ICON_SMALL): \"${_ICON_SMALL}\" (\"${small_icon}\")"
)
endif()
set(JUCER_SMALL_ICON "${small_icon}" PARENT_SCOPE)
endif()
endif()
if(DEFINED _ICON_LARGE)
if(NOT _ICON_LARGE STREQUAL "<None>")
_FRUT_abs_path_based_on_jucer_project_dir(large_icon "${_ICON_LARGE}")
if(NOT EXISTS "${large_icon}")
message(FATAL_ERROR
"No such file (ICON_LARGE): \"${_ICON_LARGE}\" (\"${large_icon}\")"
)
endif()
set(JUCER_LARGE_ICON "${large_icon}" PARENT_SCOPE)
endif()
endif()
if(DEFINED _CUSTOM_XCASSETS_FOLDER)
set(JUCER_CUSTOM_XCASSETS_FOLDER "${_CUSTOM_XCASSETS_FOLDER}" PARENT_SCOPE)
endif()
if(DEFINED _CUSTOM_LAUNCH_STORYBOARD)
_FRUT_abs_path_based_on_jucer_project_dir(storyboard "${_CUSTOM_LAUNCH_STORYBOARD}")
if(NOT EXISTS "${storyboard}")
message(FATAL_ERROR "No such file (CUSTOM_LAUNCH_STORYBOARD):"
" \"${_CUSTOM_LAUNCH_STORYBOARD}\" (\"${storyboard}\")"
)
endif()
set(JUCER_CUSTOM_LAUNCH_STORYBOARD "${storyboard}" PARENT_SCOPE)
endif()
if(DEFINED _CUSTOM_XCODE_RESOURCE_FOLDERS)
set(resource_folders "")
foreach(folder IN LISTS _CUSTOM_XCODE_RESOURCE_FOLDERS)
_FRUT_abs_path_based_on_jucer_project_dir(abs_folder "${folder}")