build.gradle

plugins {
  id 'eclipse'
  id 'idea'
  id 'java-library'
  id 'maven-publish'
  id 'com.github.johnrengelman.shadow' version '8.1.1'
  id 'net.neoforged.moddev' version '1.0.0'
}

group = "com.lovetropics"
archivesBaseName = "love-accessibility"

ext.buildnumber = 0

if (System.getenv('GITHUB_RUN_NUMBER')) {
    project.buildnumber = System.getenv('GITHUB_RUN_NUMBER')
    version = "${mod_version}+${buildnumber}-gha"
} else {
    version = "${mod_version}"
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

neoForge {
  version = project.neo_version

  parchment {
    minecraftVersion = minecraft_version
    mappingsVersion = parchment_version
  }

  runs {
    client {
      client()
      programArguments.addAll '--username', 'Dev###'
    }

    server {
      server()
      programArgument '--nogui'
    }

    data {
      data()
      programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
    }

    configureEach {
      logLevel = org.slf4j.event.Level.INFO
    }
  }

  mods {
    "${project.mod_id}" {
      sourceSet sourceSets.main
      sourceSet sourceSets.test
    }
  }
}

configurations {
  shade
  library
  implementation.extendsFrom library
}

repositories {
  maven { url = 'https://maven.gegy.dev' }
}

dependencies {
  final def nvda_controller = 'dev.gegy:nvda-controller-client-java:1.0.0'
  library nvda_controller
  shade(nvda_controller) {
    transitive = false
  }
}

tasks.withType(ProcessResources).configureEach {
  var replaceProperties = [
          mod_version: mod_version,
  ]
  inputs.properties replaceProperties

  filesMatching(['META-INF/neoforge.mods.toml']) {
    expand replaceProperties
  }
}

shadowJar {
  configurations = [project.configurations.shade]
  archiveClassifier.set('')
}

build.dependsOn shadowJar

idea {
  module {
    downloadSources = true
    downloadJavadoc = true
  }
}

jar {
  archiveClassifier.set('slim')
}