JadeMatrix-CMake-ModulesConfigVersion.cmake.in

# This file was modified from the output of
# `WRITE_BASIC_PACKAGE_VERSION_FILE( ... COMPATIBILITY AnyNewerVersion )` to
# support backwards-only compatibility between minor package versions.


CMAKE_MINIMUM_REQUIRED( VERSION 3.7 FATAL_ERROR #[[
    Requiring 3.7+:
        IF( ... VERSION_LESS_EQUAL ... )
]] )


SET( PACKAGE_VERSION "@PROJECT_VERSION@" )

IF( PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION )
    SET( PACKAGE_VERSION_COMPATIBLE FALSE )
ELSE()
    IF( "@PROJECT_VERSION@" MATCHES "^([0-9]+)\\." )
        SET( VERSION_MAJOR "${CMAKE_MATCH_1}" )
    ELSE()
        SET( VERSION_MAJOR "@PROJECT_VERSION@" )
    ENDIF()
    
    IF(
        PACKAGE_FIND_VERSION_MAJOR STREQUAL VERSION_MAJOR
        AND PACKAGE_FIND_VERSION VERSION_LESS_EQUAL PACKAGE_VERSION
    )
        SET( PACKAGE_VERSION_COMPATIBLE TRUE )
    ELSE()
        SET( PACKAGE_VERSION_COMPATIBLE FALSE )
    ENDIF()
    
    IF( PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION )
        SET( PACKAGE_VERSION_EXACT TRUE )
    ENDIF()
ENDIF()