build.gradle

// Apply the java plugin to add support for Java
buildscript {
	repositories {
		mavenCentral()
		maven { url "http://maven.xol.io/repository/public/" }
		//maven { url 'https://jitpack.io' }
	}

	dependencies {
		//classpath 'com.github.johni0702:gradle-ecj-plugin:795736c7bd085c6ff3a5fbd3f5d2913c94fe589e'
		classpath 'de.johni0702.gradle:gradle-ecj-plugin:1.1-JAVA9'
	}
}

plugins {
    id "com.github.hierynomus.license" version "0.14.0"
}


apply plugin: 'java'
apply plugin: 'java-library'
apply plugin: 'maven'

repositories {
	mavenLocal()
	mavenCentral()
	jcenter()
	maven {
		url "http://maven.xol.io/repository/public/"
	}
}

description = 'The base content chunkstories is built on.'
group = 'io.xol.chunkstories'
version = '127'

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

ext {
	apiRevisionBuiltAgainst = '119'
	useEclipseCompiler = true
}

dependencies {
	compile group: 'io.xol.chunkstories', name: 'api', version: apiRevisionBuiltAgainst
	compile group: 'io.xol.enklume', name: 'enklume', version: 100
}

if(ext.useEclipseCompiler) {
	apply plugin: 'de.johni0702.ecj'
	println "Using ECJ compiler"
}

license {
    header rootProject.file('codequality/header-include-notice.txt')
    strictCheck true
	
	mapping {
        java='DOUBLESLASH_STYLE'
    }
}


task buildContentPack(type: Zip) {
	//Require Gradle to build the content jar first
	dependsOn jar
	
	//Include all resources, but don't bundle any project file from content authoring tools
	//Keeping those in the repo is fine, but users don't need it!
	from('res/'){
		exclude("**/*.pdn")
		exclude("**/*.ps")
		exclude("**/*.xcf")
		exclude("**/*.aup")
	}
	
	//We want the final archive to bear our mod name
	archiveName = "core_content.zip";
	//archiveName = "${rootProject.name}.zip"
}

jar {
	destinationDir = file("$rootDir/res")
	version = null
}

clean {
	delete configurations.runtime.allArtifacts.files
}

artifacts {
	archives jar
	archives buildContentPack
}

configurations {
	deployerJars
}

dependencies {
	deployerJars "org.apache.maven.wagon:wagon-ssh:3.0.0"
}

//Create a properties.gradle with login credentials to use this.
//Watch out: wagon-ssh is an old mess and WILL NOT TAKE EdDSA host keys
//You MUST ask the server for one of those and replace whatever you had for it in known_hosts
if(hasProperty('uploadUsername')) {
	println 'Login credentials found'
	uploadArchives {
		repositories {
				mavenDeployer {
       				configuration = configurations.deployerJars	
					
					if(project.hasProperty('uploadPrivateKey')) {
						println 'Found private key'
						repository(url: "scp://xol.io/home/maven-user/maven-repo") {				
							authentication(userName: uploadUsername, privateKey: uploadPrivateKey)
		    				}
					}
					else {
						println 'Found password'
						repository(url: "scp://xol.io/home/maven-user/maven-repo") {				
							authentication(userName: uploadUsername, password: uploadPassword)
		    				}
					}
				}
		}
	}
}