Mantenimiento_Windows.bat

@echo Off
setlocal EnableExtensions
setlocal EnableDelayedExpansion
chcp 65001
set ver=0.20.3.2C
set url=https://raw.githubusercontent.com/Cantejito/WinMant/main/Mantenimiento_Windows.bat
set url.cgl=https://raw.githubusercontent.com/Cantejito/WinMant/main/WinMant_Changelog.txt
set tempmant=C:\Users\Default\AppData\Local\WinMant\Mantenimiento_Windows.bat
set changelog=C:\Users\Default\AppData\Local\WinMant\WinMant_Changelog.txt
set aviso=C:\Users\Default\AppData\Local\WinMant\Aviso
set winmant.data=C:\Users\Default\AppData\Local\WinMant
if not exist %winmant.data% mkdir %winmant.data%
title WinMant - Versión: %ver%
NET SESSION >nul 2>& 1
if %ERRORLEVEL% == 0 goto UPDATE
MODE CON: COLS=82 LINES=12
COLOR 4F
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── ESTE SCRIPT REQUIERE SER EJECUTADO COMO ADMINISTRADOR
echo. & echo ───── (CLIC DERECHO EN EL ARCHIVO Y CLIC EN "EJECUTAR COMO ADMINISTRADOR")
echo.
echo. & echo ───── Pulse INTRO para salir
echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul & exit

:UPDATE
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Buscando actualizaciones...
	curl -o %tempmant% --create-dirs %url% -s
		if errorlevel 1 (
			echo.
			echo ───── Error al descargar, redirigiendo...[97m
				timeout 3 >nul
					goto AVISO
		)
		
	findstr \C:"set ver=" %tempmant% > %tempmant%.new
		set /p ver_new=<"%tempmant%.new"
			for /f "tokens=2 delims==" %%a in ("!ver_new!") do set "ver_new=%%a"
				del "%tempmant%.new"
				
	if %ver% neq %ver_new% (
		del %aviso%
			move /y "%tempmant%" "%~dp0" > nul 2>&1
				start "" "%~dpnx0"
					exit
	)
	
:AVISO
MODE CON: COLS=82 LINES=37
if exist "%aviso%" (
	goto MENU
)
	echo > %aviso%
	
	:AVISO.CHECK
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ────────────────────────────────────IMPORTANTE────────────────────────────────────
echo. & echo ───── NO ME HAGO RESPONSABLE DE PÉRDIDA DE DATOS Y/O PROBLEMAS CAUSADOS
echo. & echo ───── REQUISITOS
echo. & echo ───── No usar si hay actualizaciones en curso
echo. & echo ───── Tener Windows completamente actualizado
echo. & echo ───── RECOMENDACIONES
echo. & echo ───── Cerrar todos los programas
echo. & echo ───── Desactivar el antivirus para mejorar la velocidad de trabajo
echo. & echo ───── Esperar a que se complete la operación antes de cerrar el script
echo. & echo ───── INFORMACIÓN
echo. & echo ───── Algunas funciones pueden tardar minutos e incluso horas en completarse
echo. & echo ────────────────────────────────────IMPORTANTE────────────────────────────────────
echo. & echo ───── Pulse INTRO si ha leído, entiende y acepta todo lo anterior
echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul
	
:MENU
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── MENÚ PRINCIPAL
	echo. & echo ───── 0   =   Salir
	echo. & echo ───── 1   =   Mantenimiento completo
	echo. & echo ───── 1.1 =   Verificar estado de Windows
	echo. & echo ───── 1.2 =   Limpieza de archivos temporales básicos
	echo. & echo ───── 2   =   Comprobar y reparar discos
	echo. & echo ───── 3   =   Ajustes de hibernación
	echo. & echo ───── 4   =   Reestablecer ajustes de red
	echo. & echo ───── 5   =   Análisis de memoria
	echo.
	echo. & echo ───── OP  =   Opciones
	echo.
	echo. & echo ───── DEV =   Menú experimental [NO USAR]
	
echo. & echo.
set /p MENU=───── Ejecutar... 
	if /i "%MENU%" == "" goto MENU
	if /i %MENU% == 0 exit
	if /i %MENU% == 1 (set MOD=COMPLETO) & (goto ESTADO)
	if /i %MENU% == 1.1 (set MOD=NO.COMPLETO) & (goto ESTADO)
	if /i %MENU% == 1.2 goto TEMP
	if /i %MENU% == 2 goto DISCOS
	if /i %MENU% == 3 goto HIBERNAR
	if /i %MENU% == 4 goto RED
	if /i %MENU% == 5 goto MEMORIA
	if /i %MENU% == OP goto OPCIONES
	if /i %MENU% == DEV goto MENU.DEV
	goto MENU
		
:OPCIONES
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── OPCIONES
	echo. & echo ───── 0   =   Volver al menú principal
	echo. & echo ───── 1   =   Comprobar actualizaciones
	echo. & echo ───── 2   =   Ver requisitos, recomendaciones e información
	echo. & echo ───── 3   =   Historial de actualizaciones
	
echo. & echo.
set /p OPCIONES=───── Ejecutar... 
	if /i "%OPCIONES%" == "" goto OPCIONES
	if /i %OPCIONES% == 0 goto MENU
	if /i %OPCIONES% == 1 goto UPDATE
	if /i %OPCIONES% == 2 goto AVISO.CHECK
	if /i %OPCIONES% == 3 goto CHANGELOG
	goto OPCIONES
	
:MENU.DEV
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── MENÚ EXPERIMENTAL [NO USAR]
	echo. & echo ───── 0   =   Volver al menú principal
	echo. & echo ───── 1   =   Limpieza de archivos temporales en profundidad
	echo. & echo ───── 1.1 =   Limpieza de archivos temporales avanzada
	echo. & echo ───── 2   =   Análisis automático Windows Defender
	echo. & echo ───── 3   =   Acceso a "WindowsApps"
			echo "C:\Program Files\WindowsApps" > nul 2>&1
			
echo. & echo.
set /p MENU.DEV=───── Ejecutar... 
	if /i "%MENU.DEV%" == "" goto MENU.DEV
	if /i %MENU.DEV% == 0 goto MENU
	if /i %MENU.DEV% == 1 goto TEMP.PRO
	if /i %MENU.DEV% == 1.1 goto TEMP.ADV
	if /i %MENU.DEV% == 2 goto DEFENDER
	if /i %MENU.DEV% == 3 goto WINDOWSAPPS
		goto MENU.DEV
		
:ESTADO
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Verificando estado de Windows...
	echo. & echo ───── Verificando estado de imágen...
		DISM.exe /Quiet /NoRestart /Online /Cleanup-Image /Scanhealth >nul || (
			echo. & echo ───── Error detectado, ejecutando reparaciones...[97m
				echo. & DISM.exe /Quiet /NoRestart /Online /Cleanup-Image /Restorehealth >nul	
					echo ───── Reverificando estado... & echo.
						DISM.exe /Quiet /NoRestart /Online /Cleanup-Image /Scanhealth >nul || (
							echo ───── No se pudo reparar
							echo. & echo ───── Vuelva al menú y ejecute "VERIFICAR ESTADO DE WINDOWS"
							echo. & echo ───── Se recomienda hacer una copia de seguridad
									echo ───── de todos los archivos importantes
							echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul
								goto MENU
						)
		)
			echo ───── Completado
			
	echo. & echo ───── Verificando estado de archivos...
		SFC /scannow >nul || (
			echo ───── Error detectado, ejecutando reparaciones...[97m
				SFC /scannow >nul || (
					echo. & echo ───── No se pudo reparar
					echo. & echo ───── Se recomienda hacer una copia de seguridad
							echo ───── de todos los archivos importantes
					echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul
						goto MENU
				)
		)
			echo ───── Completado
			
	if %MOD% equ COMPLETO (
		goto TEMP.COMPLETO
	) else (
		goto COMPLETADO.REINICIO
	)
	
:TEMP
CLS
echo ──────────────────────────────────────────────────────────────────────────────────

:TEMP.COMPLETO
echo. & echo ───── Limpiando archivos temporales básicos...
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.B=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	echo. & echo ───── Limpiando archivos temporales del usuario...
		cd %temp% & rd . /s /q > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando archivos temporales del disco local...
		cd C:\Temp > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando archivos temporales de Windows...
		cd C:\Windows\Temp & rd . /s /q > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando papelera...
		chcp 437 >nul 2>& 1
			PowerShell Clear-RecycleBin -Force -ErrorAction SilentlyContinue
				chcp 65001 >nul 2>& 1
					echo ───── Completado
					
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.A=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	set /a "Disk.D=(Disk.A - Disk.B)"
	
	echo. & echo.
	echo ───── Aproximadamente %Disk.D% GB liberados (libera más desactivando la hibernación)
		goto COMPLETADO.REINICIO
		
:TEMP.PRO
echo. & echo ───── Limpiando archivos temporales en profundidad...
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.B=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	echo. & echo ───── Limpiando WinSxS...
		DISM.exe /Quiet /NoRestart /Online /Cleanup-Image /StartComponentCleanup /ResetBase > nul 2>&1
			echo ───── Completado
			
	echo. & echo ───── Limpiando actualizaciones descargadas...
		cd C:\Windows\SoftwareDistribution\Download > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando archivos temporales de Chrome...
		cd %localappdata%\Google\Chrome\User Data\Default\Service Worker > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				rd . /s /q > nul 2>&1
				cd %localappdata%\Google\Chrome\User Data\Default\Cache > nul 2>&1
				rd . /s /q > nul 2>&1
				cd %localappdata%\Google\Chrome\User Data\Default\Code Cache > nul 2>&1
				rd . /s /q > nul 2>&1
				echo ───── Completado
			)
			
	echo. & echo ───── Limpiando caché DirectX de NVIDIA...
		cd %localappdata%\NVIDIA\DXCache > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.A=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	set /a "Disk.D=(Disk.A - Disk.B)"
	
	echo. & echo.
	echo ───── Aproximadamente %Disk.D% GB liberados (libera más desactivando la hibernación)
		goto COMPLETADO.REINICIO
		
:TEMP.ADV
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── ESTA FUNCIÓN PUEDE AFECTAR A LA INTEGRIDAD DEL EQUIPO
		echo ───── O CAUSAR PÉRDIDA DE DATOS
echo. & echo ─────  SE REQUIERE CERRAR TODOS LOS PROGRAMAS
	echo. & echo ───── M = Volver al menú
	echo. & echo ───── CONFIRMAR = Continuar
	echo. & echo.
		set /p T.A=───── Ejecutar... 
			if /i "%T.A%" == "" goto TEMP.ADV
			if /i %T.A% == M goto MENU
			if /i %T.A% == CONFIRMAR goto TEMP.ADV.CHECK
				goto TEMP.ADV
				
	:TEMP.ADV.CHECK
echo. & echo ───── Limpiando archivos temporales... [AVANZADO]
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.B=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	echo. & echo ───── Limpiando archivos precargados...
		cd C:\Windows\Prefetch > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando actualizaciones acumulativas...
		cd C:\Windows\servicing\LCU > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	echo. & echo ───── Limpiando servicios de red temporales...
		cd C:\Windows\ServiceProfiles\NetworkService\AppData\Local\Temp > nul 2>&1
			if errorlevel 1 (
				echo ───── Cancelado, ruta no encontrada
			) else (
				echo ───── Completado & rd . /s /q > nul 2>&1
			)
			
	chcp 437 >nul 2>& 1
		for /f "delims=" %%a in ('powershell -command "(Get-PSDrive -PSProvider FileSystem | Where-Object { $_.Root -eq 'C:\' }).Free/1GB"') do (
			set "Disk.A=%%a"
		)
			chcp 65001 >nul 2>& 1
			
	set /a "Disk.D=(Disk.A - Disk.B)"
	
	echo. & echo.
	echo ───── Aproximadamente %Disk.D% GB liberados (libera más desactivando la hibernación)
		goto COMPLETADO.REINICIO
		
:DISCOS
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Comprobando discos...
	echo.
	wmic diskdrive get status || (
		echo ───── Error detectado, ejecutando reparaciones...
			chkdsk /r /scan /perf >nul
				echo. & echo ───── Vuelva al menú y ejecute "COMPROBACIÓN Y REPARACION DE DISCOS"
				echo. & echo ───── Se recomienda hacer una copia de seguridad
						echo ───── de todos los archivos importantes
				echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul
					goto MENU
		)
			goto COMPLETADO
			
:HIBERNAR
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Obteniendo ajustes de hibernación...
	for /f "tokens=3" %%a in ('reg query HKLM\SYSTEM\ControlSet001\Control\Power\ ^|find /i "HibernateEnabled "') do if %%a==0x1 (
		echo. & echo.
		echo ───── Hibernación activada
		echo. & echo ───── 0 = Volver al menú
		echo. & echo ───── 1 = Desactivar
		
		echo. & echo.
		choice /C 01 /N /M "─────  Ejecutar... "
		if errorlevel 2 (
			powercfg.exe /h off > nul 2>&1 & echo.
				goto HIBERNAR
		)
			goto MENU
	)
		echo. & echo.
		echo ───── Hibernación desactivada
		echo. & echo ───── 0 = Volver al menú
		echo. & echo ───── 1 = Activar
		
		echo. & echo.
		choice /C 01 /N /M "─────  Ejecutar... "
		if errorlevel 2 (
			powercfg.exe /h on > nul 2>&1 & echo.
				goto HIBERNAR
		)
			goto MENU
			
:RED
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Reestableciendo red...
		echo. & echo.
		echo ───── Seguro que quiere continuar?
		echo. & echo ───── 0 = Volver al menú
		echo. & echo ───── 1 = Continuar
		echo. & echo.
		choice /C 01 /N /M "─────  Ejecutar... "
		if errorlevel 2 (
			netsh winsock reset
			netsh int ip reset
			ipconfig /release
			ipconfig /renew
			ipconfig /flushdns
			ipconfig /registerdns
				goto COMPLETADO.REINICIO
		)
			goto MENU
			
:MEMORIA
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Ejecutando programandor de análisis...
	mdsched.exe
		echo. & echo ───── La duración del análisis puede tardar varias horas
			goto COMPLETADO.REINICIO
			
:DEFENDER
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── ESTA FUNCIÓN PUEDE AFECTAR A LA INTEGRIDAD DEL EQUIPO
		echo ───── O CAUSAR PÉRDIDA DE DATOS
	echo.
	echo. & echo ───── 0 = Volver al menú
	echo. & echo ───── 1 = Continuar
	echo. & echo.
		choice /C 01 /N /M "─────  Ejecutar... "
			if errorlevel 2 (
				goto DEFENDER.CHECK
			)
				goto MENU
				
	:DEFENDER.CHECK
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── Obteniendo ajustes de análisis automático...
	for /f "tokens=2 delims=:" %%a in ('schtasks /query /tn "Microsoft\Windows\Windows Defender\Windows Defender Scheduled Scan" /fo list ^| find "Estado"') do set "status=%%a"
		set "status=%status: =%"
		if /i "%status%"=="Deshabilitado" goto DEFENDER.OFF
			echo. & echo.
			echo ───── Estado actual: Activado
			echo.
			echo. & echo ───── 0 = Volver al menú
			echo. & echo ───── 1 = Desactivar
			echo. & echo.
				choice /C 01 /N /M "─────  Ejecutar... "
				if errorlevel 2 (
					schtasks /Change /Disable /TN "Microsoft\Windows\Windows Defender\Windows Defender Scheduled Scan" >nul
						goto DEFENDER.CHECK
				)
					goto MENU
					
	:DEFENDER.OFF
			echo. & echo.		
			echo ───── Estado actual: Desactivado
			echo.
			echo. & echo ───── 0 = Volver al menú
			echo. & echo ───── 1 = Activar
			echo. & echo.	
				choice /C 01 /N /M "─────  Ejecutar... "
				if errorlevel 2 (
					schtasks /Change /Enable /TN "Microsoft\Windows\Windows Defender\Windows Defender Scheduled Scan" >nul
						goto DEFENDER.CHECK
				)
					goto MENU
					
:WINDOWSAPPS
CLS
echo ──────────────────────────────────────────────────────────────────────────────────
echo. & echo ───── ESTA FUNCIÓN PUEDE AFECTAR A LA INTEGRIDAD DEL EQUIPO
		echo ───── O CAUSAR PÉRDIDA DE DATOS
	echo.
	echo. & echo ───── 0 = Volver al menú
	echo. & echo ───── 1 = Continuar
	echo. & echo.
		choice /C 01 /N /M "─────  Ejecutar... "
			if errorlevel 2 (
				goto WINDOWSAPPS.CHECK
			)
				goto MENU
				
	:WINDOWSAPPS.CHECK
echo.
echo. & echo ───── Otorgando permisos en C:\Program Files\WindowsApps...
	takeown /f "C:\Program Files\WindowsApps" /r >nul
		icacls "C:\Program Files\WindowsApps" /reset /t >nul
			start explorer.exe "C:\Program Files\WindowsApps" >nul
				goto COMPLETADO
				
:CHANGELOG
curl -o %changelog% --create-dirs %url.cgl% -s
	if errorlevel 1 (
		echo.
		echo ───── Error al descargar, redirigiendo...
			timeout 3 >nul
				goto MENU
	)

start %changelog%
	goto MENU
	
:COMPLETADO
echo 
echo. & echo ───── Completado
echo. & echo ───── Pulse INTRO para volver al menú
echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul & goto MENU

:COMPLETADO.REINICIO
echo 
echo. & echo ───── Completado (se recomienda reiniciar)
echo. & echo ───── Pulse INTRO para volver al menú
echo. & echo ────────────────────────────────────────────────────────────────────────────────── & pause >nul & goto MENU