build.gradle

buildscript {
    repositories {
        mavenCentral()
        // Needed only for SNAPSHOT versions
        maven { url "http://oss.sonatype.org/content/repositories/snapshots/" }
    }
    dependencies {
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.11.0"
    }
}

version = '0.6.1-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'osgi'
apply plugin: 'io.codearte.nexus-staging'

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'org.gradle.api.plugins:gradle-nexus-plugin:0.7.1'
    }
}

repositories {
    mavenCentral()
    jcenter()
}

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

group = 'org.fxmisc.flowless'
project.archivesBaseName = 'flowless'

dependencies {
    compile 'org.reactfx:reactfx:2.0-M5'
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile "org.testfx:testfx-core:4.0.11-alpha"
    testCompile ("org.testfx:testfx-junit:4.0.11-alpha") {
        exclude(group: "junit", module: "junit")
    }
    testCompile "org.testfx:openjfx-monocle:8u76-b04"
}

javadoc {
    // ignore missing Javadoc comments or tags
    options.addStringOption('Xdoclint:all,-missing', '-quiet')

    // support for JavaFX properties
    options.addBooleanOption('javafx', true)

    options.links = [
            // resolve links to Java and JavaFX Javadocs
            'http://docs.oracle.com/javase/8/docs/api/',
            'http://docs.oracle.com/javase/8/javafx/api/',

            // resolve links to ReactFX
            'http://www.reactfx.org/javadoc/2.0-M5/'
    ]
}

task fatJar(type: Jar, dependsOn: classes) {
    appendix = 'fat'
    from sourceSets.main.output
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
}

assemble.dependsOn fatJar

task getVersion {
    doLast {
        println version
    }
}

nexusStaging {
    packageGroup = "org.fxmisc.flowless"
}