forked from PaddlePaddle/Paddle2ONNX
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCMakeLists.txt
249 lines (225 loc) · 8.85 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
cmake_minimum_required(VERSION 3.16)
project(paddle2onnx C CXX)
# ONNX 1.16 requires C++ 17
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
# Build the libraries with - fPIC
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
# Always link with libstdc++ fs.a when using GCC 8.
link_libraries(
"$<$<AND:$<CXX_COMPILER_ID:GNU>,$<VERSION_LESS:$<CXX_COMPILER_VERSION>,9.0>>:-lstdc++fs>"
)
option(WITH_STATIC "Compile Paddle2ONNX with STATIC" OFF)
option(PADDLE2ONNX_DEBUG "If open the debug log while converting model" OFF)
option(MSVC_STATIC_CRT "Compile Paddle2ONNX with MSVC STATIC CRT" OFF)
if(MSVC)
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
add_definitions(-DPADDLE_WITH_TESTING)
endif()
if(PADDLE2ONNX_DEBUG)
add_definitions(-DPADDLE2ONNX_DEBUG)
endif()
# Set max opset version for onnx if you build from other version of onnx this
# should be modified.
add_definitions(-DMAX_ONNX_OPSET_VERSION=23)
add_definitions(-DPADDLE2ONNX_LIB)
# Internal flags for convert.h.in
set(WITH_PADDLE2ONNX_STATIC_INTERNAL OFF)
if(WITH_STATIC)
set(WITH_PADDLE2ONNX_STATIC_INTERNAL
ON
CACHE BOOL "" FORCE)
add_definitions(-DWITH_PADDLE2ONNX_STATIC_INTERNAL_AT_COMPILING)
endif()
include(utils)
configure_file(${PROJECT_SOURCE_DIR}/paddle2onnx/mappers_registry.h.in
${PROJECT_SOURCE_DIR}/paddle2onnx/mappers_registry.h)
# Third dependency : onnx
if(NOT TARGET onnx_proto)
if(NOT ONNX_NAMESPACE)
set(ONNX_NAMESPACE "onnx")
endif()
add_definitions("-DONNX_NAMESPACE=${ONNX_NAMESPACE}")
add_subdirectory(${PROJECT_SOURCE_DIR}/third_party/onnx)
endif()
# generate Paddle2ONNX proto files
add_subdirectory(${PROJECT_SOURCE_DIR}/paddle2onnx/proto)
include_directories(${PROJECT_SOURCE_DIR})
include_directories(${CMAKE_CURRENT_BINARY_DIR})
include_directories(${PROJECT_SOURCE_DIR}/third_party/optimizer)
file(GLOB_RECURSE ALL_SRCS ${PROJECT_SOURCE_DIR}/paddle2onnx/*.cc
${PROJECT_SOURCE_DIR}/third_party/optimizer/onnxoptimizer/*.cc)
list(REMOVE_ITEM ALL_SRCS ${PROJECT_SOURCE_DIR}/paddle2onnx/cpp2py_export.cc)
list(REMOVE_ITEM ALL_SRCS
${PROJECT_SOURCE_DIR}/third_party/optimizer/onnxoptimizer/cpp2py_export.cc)
file(READ "${PROJECT_SOURCE_DIR}/VERSION_NUMBER" PADDLE2ONNX_VERSION)
string(STRIP "${PADDLE2ONNX_VERSION}" PADDLE2ONNX_VERSION)
if(WITH_STATIC)
# Here, we use a dummy target (paddle2onnx_dummy) to form a build dependency
# tree for paddle2onnx_static lib.
add_library(paddle2onnx_dummy STATIC ${ALL_SRCS})
if(APPLE)
set_target_properties(paddle2onnx_dummy PROPERTIES COMPILE_FLAGS
"-fvisibility=hidden")
elseif(MSVC)
message("------ BUILD WITH MSVC --------")
else()
set_target_properties(paddle2onnx_dummy PROPERTIES COMPILE_FLAGS
"-fvisibility=hidden")
endif()
target_link_libraries(paddle2onnx_dummy p2o_paddle_proto onnx)
# Bundle paddle2onnx static lib here
bundle_static_library(paddle2onnx_dummy paddle2onnx_static bundle_paddle2onnx)
else()
add_library(paddle2onnx SHARED ${ALL_SRCS})
# add pybind11
add_subdirectory(third_party/pybind11)
# add glog
add_subdirectory(third_party/glog)
# find Python site-packages dir
execute_process(
COMMAND ${PYTHON_EXECUTABLE} -c
"import site;print(site.getsitepackages()[0])"
OUTPUT_VARIABLE PYTHON_SITE_PACKAGES
OUTPUT_STRIP_TRAILING_WHITESPACE)
message(STATUS "Python site-packages directory: ${PYTHON_SITE_PACKAGES}")
if(MSVC)
include(external/paddle)
# add paddle include dir
set(PADDLE_INCLUDE_DIR ${LIBPADDLE_INCLUDE_DIR})
set(PADDLE_LIB ${LIBPADDLE_BASE_LIBRARY})
set(COMMON_LIB ${LIBPADDLE_COMMON_LIBRARY})
else()
set(PADDLE_LIB "${PYTHON_SITE_PACKAGES}/paddle/base/libpaddle.so")
if(EXISTS ${PADDLE_LIB})
message(STATUS "Found libpaddle.so : ${PADDLE_LIB}.")
else()
message(
FATAL_ERROR
"Can not found libpaddle.so at ${PYTHON_SITE_PACKAGES}/paddle/base!")
endif()
# add paddle include dir
set(PADDLE_INCLUDE_DIR ${PYTHON_SITE_PACKAGES}/paddle/include/)
endif()
include_directories(${PADDLE_INCLUDE_DIR})
if(APPLE)
set_target_properties(paddle2onnx PROPERTIES LINK_FLAGS
"-undefined dynamic_lookup")
elseif(MSVC)
message("------ BUILD WITH MSVC --------")
# remove `interface` macro defined in MSVC
# target_compile_options(paddle2onnx PRIVATE /Uinterface)
else()
set_target_properties(paddle2onnx PROPERTIES COMPILE_FLAGS
"-fvisibility=hidden")
set_target_properties(paddle2onnx PROPERTIES LINK_FLAGS
"-Wl,--exclude-libs,ALL")
set_target_properties(paddle2onnx PROPERTIES LINK_FLAGS_RELEASE -s)
endif()
set_target_properties(paddle2onnx PROPERTIES VERSION ${PADDLE2ONNX_VERSION})
target_link_libraries(
paddle2onnx
${PADDLE_LIB}
${COMMON_LIB}
p2o_paddle_proto
onnx
pybind11::embed
glog::glog)
endif()
if(WIN32)
install(
TARGETS paddle2onnx
LIBRARY DESTINATION lib
ARCHIVE DESTINATION lib
RUNTIME DESTINATION lib)
else()
if(WITH_STATIC)
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libpaddle2onnx_static.a
DESTINATION lib)
else()
install(TARGETS paddle2onnx LIBRARY DESTINATION lib)
endif()
endif()
install(FILES ${PROJECT_SOURCE_DIR}/paddle2onnx/converter.h
${PROJECT_SOURCE_DIR}/paddle2onnx/mappers_registry.h
DESTINATION include/paddle2onnx)
if(BUILD_PADDLE2ONNX_PYTHON)
if(APPLE)
find_program(INSTALL_NAME_TOOL_EXECUTABLE install_name_tool)
if(NOT INSTALL_NAME_TOOL_EXECUTABLE)
message(FATAL_ERROR "install_name_tool not found, please check.\n")
endif()
endif()
if("${PY_EXT_SUFFIX}" STREQUAL "")
if(MSVC)
set(PY_EXT_SUFFIX ".pyd")
else()
set(PY_EXT_SUFFIX ".so")
endif()
endif()
add_library(paddle2onnx_cpp2py_export MODULE
${PROJECT_SOURCE_DIR}/paddle2onnx/cpp2py_export.cc ${ALL_SRCS})
set_target_properties(paddle2onnx_cpp2py_export PROPERTIES PREFIX "")
set_target_properties(paddle2onnx_cpp2py_export
PROPERTIES COMPILE_FLAGS "-fvisibility=hidden")
set_target_properties(paddle2onnx_cpp2py_export PROPERTIES SUFFIX
${PY_EXT_SUFFIX})
set_target_properties(paddle2onnx_cpp2py_export
PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
target_include_directories(
paddle2onnx_cpp2py_export
PRIVATE $<BUILD_INTERFACE:${ONNX_ROOT}>
$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
$<INSTALL_INTERFACE:include>
${PYTHON_INCLUDE_DIR}
${PADDLE_INCLUDE_DIR})
if(EXISTS
${PROJECT_SOURCE_DIR}/third_party/pybind11/include/pybind11/pybind11.h)
target_include_directories(
paddle2onnx_cpp2py_export
PUBLIC ${PROJECT_SOURCE_DIR}/third_party/pybind11/include)
else()
message(FATAL_ERROR "cannot find pybind")
endif()
if(APPLE)
set_target_properties(paddle2onnx_cpp2py_export
PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
target_link_libraries(paddle2onnx_cpp2py_export
PRIVATE -Wl,-force_load,$<TARGET_FILE:onnx>)
elseif(MSVC)
# In MSVC, we will add whole archive in default
target_link_libraries(paddle2onnx_cpp2py_export
PRIVATE -WHOLEARCHIVE:$<TARGET_FILE:onnx>)
else()
# Assume everything else is like gcc
target_link_libraries(
paddle2onnx_cpp2py_export
PRIVATE "-Wl,--whole-archive" $<TARGET_FILE:onnx>
"-Wl,--no-whole-archive")
set_target_properties(paddle2onnx_cpp2py_export
PROPERTIES LINK_FLAGS "-Wl,--exclude-libs,ALL")
endif()
target_link_libraries(
paddle2onnx_cpp2py_export PRIVATE ${PADDLE_LIB} ${COMMON_LIB}
p2o_paddle_proto onnx glog::glog)
if(MSVC)
target_link_libraries(paddle2onnx_cpp2py_export PRIVATE ${PYTHON_LIBRARIES})
target_compile_options(
paddle2onnx_cpp2py_export
PRIVATE /MP
/wd4244 # 'argument': conversion from 'google::protobuf::uint64'
# to 'int', possible loss of data
/wd4267 # Conversion from 'size_t' to 'int', possible loss of data
/wd4996 # The second parameter is ignored.
${EXTRA_FLAGS})
if(ONNX_USE_PROTOBUF_SHARED_LIBS)
target_compile_options(
onnx_cpp2py_export
PRIVATE /wd4251 # 'identifier' : class 'type1' needs to have
# dll-interface to be used by clients of class 'type2'
)
endif()
add_msvc_runtime_flag(paddle2onnx_cpp2py_export)
add_onnx_global_defines(paddle2onnx_cpp2py_export)
endif()
endif()